commit: 9259ad9bdd0876d7b3fac486bf8d6f5bfde7ce59
Author: Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 11 10:44:30 2015 +0000
Commit: Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Sun Oct 11 11:24:29 2015 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9259ad9b
dev-python/cython: Add python3.5 support
Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>
dev-python/cython/cython-0.23.3-r1.ebuild | 62 +++++++++++++++++++++++++++++++
1 file changed, 62 insertions(+)
diff --git a/dev-python/cython/cython-0.23.3-r1.ebuild
b/dev-python/cython/cython-0.23.3-r1.ebuild
new file mode 100644
index 0000000..1a85940
--- /dev/null
+++ b/dev-python/cython/cython-0.23.3-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1 flag-o-matic toolchain-funcs
+
+MY_PN="Cython"
+MY_P="${MY_PN}-${PV/_/}"
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="http://www.cython.org/ https://pypi.python.org/pypi/Cython";
+SRC_URI="http://www.cython.org/release/${MY_P}.tar.gz";
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux
~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+
+RDEPEND=""
+# On testing, setuptools invokes an error in running the testsuite cited in a
number of recent bugs
+# spanning several packages. This bug has been fixed in the recent release of
version 9.1
+DEPEND="${RDEPEND}
+ >=dev-python/setuptools-9.1[${PYTHON_USEDEP}]
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? ( dev-python/numpy[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_PN}-${PV%_*}"
+
+python_compile() {
+ if ! python_is_python3; then
+ local CFLAGS="${CFLAGS}"
+ local CXXFLAGS="${CXXFLAGS}"
+ append-flags -fno-strict-aliasing
+ fi
+
+ # Python gets confused when it is in sys.path before build.
+ local PYTHONPATH=
+ export PYTHONPATH
+
+ distutils-r1_python_compile
+}
+
+python_compile_all() {
+ use doc && unset XDG_CONFIG_HOME && emake -C docs html
+}
+
+python_test() {
+ tc-export CC
+ "${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ local DOCS=( CHANGES.rst README.txt ToDo.txt USAGE.txt )
+ use doc && local HTML_DOCS=( docs/build/html/. )
+ use examples && local EXAMPLES=( Demos/. )
+ distutils-r1_python_install_all
+}
