voyageur 15/08/03 07:58:28
Modified: ChangeLog
Added: owncloud-client-1.8.4.ebuild
Removed: owncloud-client-1.7.0.ebuild
owncloud-client-1.7.1.ebuild
Log:
Version bump, drop some old versions
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key
00F7AB331B0F097F)
Revision Changes Path
1.26 net-misc/owncloud-client/ChangeLog
file :
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?rev=1.26&view=markup
plain:
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?rev=1.26&content-type=text/plain
diff :
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?r1=1.25&r2=1.26
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog 26 Jun 2015 23:01:36 -0000 1.25
+++ ChangeLog 3 Aug 2015 07:58:27 -0000 1.26
@@ -1,6 +1,13 @@
# ChangeLog for net-misc/owncloud-client
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.25
2015/06/26 23:01:36 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.26
2015/08/03 07:58:27 voyageur Exp $
+
+*owncloud-client-1.8.4 (03 Aug 2015)
+
+ 03 Aug 2015; Bernard Cafarelli <[email protected]>
+ -owncloud-client-1.7.0.ebuild, -owncloud-client-1.7.1.ebuild,
+ +owncloud-client-1.8.4.ebuild:
+ Version bump, drop some old versions
26 Jun 2015; Bernard Cafarelli <[email protected]>
owncloud-client-1.8.3.ebuild:
1.1 net-misc/owncloud-client/owncloud-client-1.8.4.ebuild
file :
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.8.4.ebuild?rev=1.1&view=markup
plain:
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.8.4.ebuild?rev=1.1&content-type=text/plain
Index: owncloud-client-1.8.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:
/var/cvsroot/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.8.4.ebuild,v
1.1 2015/08/03 07:58:27 voyageur Exp $
EAPI=5
inherit cmake-utils
DESCRIPTION="Synchronize files from ownCloud Server with your computer"
HOMEPAGE="http://owncloud.org/";
SRC_URI="http://download.owncloud.com/desktop/stable/${P/-}.tar.xz";
LICENSE="CC-BY-3.0 GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc nautilus samba +sftp test qt4 +qt5"
REQUIRED_USE="^^ ( qt4 qt5 )"
RDEPEND=">=dev-db/sqlite-3.4:3
sys-fs/inotify-tools
virtual/libiconv
nautilus? ( dev-python/nautilus-python )
qt4? (
dev-libs/qtkeychain[qt4]
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
dev-qt/qtsql:4
dev-qt/qtwebkit:4
net-libs/neon[ssl]
)
qt5? (
dev-libs/qtkeychain[qt5]
dev-qt/linguist-tools:5
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtdbus:5
>=dev-qt/qtnetwork-5.4:5
dev-qt/qtgui:5
dev-qt/qtquickcontrols:5
dev-qt/qtsql:5
dev-qt/qtwebkit:5[printsupport]
)
samba? ( >=net-fs/samba-3.5 )
sftp? ( >=net-libs/libssh-0.5 )
!net-misc/ocsync"
DEPEND="${RDEPEND}
doc? (
dev-python/sphinx
dev-texlive/texlive-latexextra
virtual/latex-base
)
test? (
dev-util/cmocka
qt4? ( dev-qt/qttest:4 )
qt5? ( dev-qt/qttest:5 )
)"
S=${WORKDIR}/${P/-}
src_prepare() {
# Keep tests in ${T}
sed -i -e "s#\"/tmp#\"${T}#g" test/test*.h || die "sed failed"
use nautilus || sed -i -e "s/add_subdirectory(nautilus)//" \
shell_integration/CMakeLists.txt || die "sed failed"
}
src_configure() {
local mycmakeargs=(
-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
-DWITH_ICONV=ON
$(cmake-utils_use_with doc DOC)
$(cmake-utils_use test UNIT_TESTING)
$(cmake-utils_use_find_package samba Libsmbclient)
$(cmake-utils_use_find_package sftp LibSSH)
$(cmake-utils_use_build qt4 WITH_QT4)
)
cmake-utils_src_configure
}
src_test() {
# 1 test needs an existing ${HOME}/.config directory
mkdir "${T}"/.config
export HOME="${T}"
cmake-utils_src_test
}
pkg_postinst() {
if ! use doc ; then
elog "Documentation and man pages not installed"
elog "Enable doc USE-flag to generate them"
fi
}
