commit: f46288404048c1abae9459633fa8c93bee8d9eb7
Author: Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun May 3 21:30:55 2015 +0000
Commit: Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun May 3 21:54:50 2015 +0000
URL: https://gitweb.gentoo.org/proj/gnome.git/commit/?id=f4628840
media-sound/gnome-music: 3.14.3.1 → 3.16.1
media-sound/gnome-music/gnome-music-3.16.1.ebuild | 60 +++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/media-sound/gnome-music/gnome-music-3.16.1.ebuild
b/media-sound/gnome-music/gnome-music-3.16.1.ebuild
new file mode 100644
index 0000000..b2f22fc
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.16.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python{3_3,3_4} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="http://wiki.gnome.org/Apps/Music";
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+# Let people emerge this by default, bug #472932
+IUSE+=" +python_single_target_python3_3 python_single_target_python3_4"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+ ${PYTHON_DEPS}
+ >=dev-libs/glib-2.28:2
+ >=dev-libs/gobject-introspection-1.35.9
+ >=media-libs/grilo-0.2.6:0.2[introspection]
+ media-libs/libmediaart:2.0
+ >=x11-libs/gtk+-3.13.2:3[introspection]
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${COMMON_DEPEND}
+ app-misc/tracker[introspection(+)]
+ || (
+ app-misc/tracker[gstreamer]
+ app-misc/tracker[ffmpeg]
+ )
+ dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ media-libs/gstreamer:1.0[introspection]
+ media-libs/gst-plugins-base:1.0[introspection]
+ media-plugins/gst-plugins-meta:1.0
+ media-plugins/grilo-plugins:0.2[tracker]
+ x11-misc/xdg-user-dirs
+"
+DEPEND="${COMMON_DEPEND}
+ >=dev-util/intltool-0.26
+ virtual/pkgconfig
+"
+
+src_configure() {
+ gnome2_src_configure ITSTOOL="$(type -P true)"
+}
+
+src_install() {
+ gnome2_src_install
+ python_fix_shebang "${ED}"
+}
