commit: 4360d13a248d242811ffcea4bb079d25ec81b39e
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 6 04:32:45 2026 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Mar 6 04:52:40 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4360d13a
dev-python/trimesh: Bump to 4.11.3
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/trimesh/Manifest | 1 +
dev-python/trimesh/trimesh-4.11.3.ebuild | 88 ++++++++++++++++++++++++++++++++
2 files changed, 89 insertions(+)
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index e5374419ccf5..21b9b4b937e2 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1,2 +1,3 @@
DIST trimesh-4.11.1.gh.tar.gz 13707913 BLAKE2B
210748520e8d99a93a07eab8c89df720a2845a0eacded90c0d2651481acf494f23272e9b6ecaee444e5350f7bc66d3779f90904d88dfb254ae170f641654b985
SHA512
68d58a365ad7c3ee4e23b569a1594f13ef9e5ecaf3dd5f17a67c476909b31988fa4d3cf58ede5ea507f9e3e12e67260aed2e3511419f85f6c7ff87afb52baf07
DIST trimesh-4.11.2.gh.tar.gz 13707855 BLAKE2B
8f38cd10fa2910c21c521eaec04e860853d61e2b5d0ce8a3d66056ac53ff2985943dea82d9bcb6c913c00e05b9fe28d5173dff5c981b36b2812c9ecbd28a8335
SHA512
4b76a85f2fc27a2fabbe5a1f284d39a7edd8df5d2e085e7a42ea5b5d1484c17c02d1b774416fb31d81a963b06003d5c4847881f9ed5653bb1921cefa0ae78c8d
+DIST trimesh-4.11.3.gh.tar.gz 13708539 BLAKE2B
8d14a609eff6ffe4b876e4fe7ad94fab78929cd9096cca99ef7259c596b0cd3de409c1ade316911934fd77e5384146d2ca18f9063042cfa4eb5e5e8f1c7c3b26
SHA512
0481a7ac870da163633c0a51ccaa804d0c0f660cec92765d56af916ebe121a93d5363915b27db40898c03bcc7b6afbe86efd03c76c8eac66ddf1cfb538ec4e3f
diff --git a/dev-python/trimesh/trimesh-4.11.3.ebuild
b/dev-python/trimesh/trimesh-4.11.3.ebuild
new file mode 100644
index 000000000000..748d91d237fb
--- /dev/null
+++ b/dev-python/trimesh/trimesh-4.11.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+ https://trimesh.org/
+ https://github.com/mikedh/trimesh/
+ https://pypi.org/project/trimesh/
+"
+SRC_URI="
+ https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+ dev-python/charset-normalizer[${PYTHON_USEDEP}]
+ dev-python/colorlog[${PYTHON_USEDEP}]
+ dev-python/httpx[${PYTHON_USEDEP}]
+ dev-python/jsonschema[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/networkx[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pycollada[${PYTHON_USEDEP}]
+ dev-python/pyglet[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ >=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+ dev-python/svg-path[${PYTHON_USEDEP}]
+ dev-python/sympy[${PYTHON_USEDEP}]
+ dev-python/xxhash[${PYTHON_USEDEP}]
+ dev-python/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/mapbox-earcut[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_DESELECT=(
+ # requires manifold3d
+ tests/test_boolean.py::test_multiple_difference
+ # timing nonsense
+ tests/test_bounds.py::BoundsTest::test_obb_mesh_large
+)
+EPYTEST_IGNORE=(
+ # require pyinstrument
+ tests/test_sweep.py
+)
+
+EPYTEST_PLUGINS=()
+: ${EPYTEST_TIMEOUT:=300}
+EPYTEST_RERUNS=3
+EPYTEST_XDIST=1
+
+distutils_enable_tests pytest
+
+python_test() {
+ # We run tests in parallel, so avoid having n^2 threads in lapack
+ # tests.
+ local -x BLIS_NUM_THREADS=1
+ local -x MKL_NUM_THREADS=1
+ local -x OMP_NUM_THREADS=1
+ local -x OPENBLAS_NUM_THREADS=1
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature_header "${PN} functionality can be extended by installing
the following packages:"
+ optfeature "making GUI applications with 3D stuff" dev-python/glooey
+ optfeature "2D triangulations of polygons" dev-python/mapbox-earcut
+ optfeature "loading a number of additional mesh formats"
dev-python/meshio
+ optfeature "figuring out how much memory we have" dev-python/psutil
+ optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}
