commit: cab89775af96125534667f1f1214a5e9a62d335d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 8 03:12:59 2026 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Feb 8 03:37:48 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cab89775
dev-python/pyftpdlib: Bump to 2.2.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pyftpdlib/Manifest | 1 +
dev-python/pyftpdlib/pyftpdlib-2.2.0.ebuild | 57 +++++++++++++++++++++++++++++
2 files changed, 58 insertions(+)
diff --git a/dev-python/pyftpdlib/Manifest b/dev-python/pyftpdlib/Manifest
index aabdb0514566..b8d58e60fb2b 100644
--- a/dev-python/pyftpdlib/Manifest
+++ b/dev-python/pyftpdlib/Manifest
@@ -1 +1,2 @@
DIST pyftpdlib-2.1.0.tar.gz 205767 BLAKE2B
c6a6987edbd9d7ea2860f85ff7adc264dc5e92cfed053095ceecc5dfdd417e9ea3d2791d347e6d2249edd89f68e006fc07f21daa9c2f8ed365ac0e8cc969fbd5
SHA512
2c624f60cce1c34c2fe953bda635060b3b6215189215f427989a6c97daf0e51bd9920e4ddd943e624de70d8d732a65b3c16f4f8809860999065ad2db891bc154
+DIST pyftpdlib-2.2.0.tar.gz 189150 BLAKE2B
783f2218103b7a1b50e05f1f26bc69782b3ae0656aba8ee28a46c09daabf6492caa0da5cde582c225696aa3f4a38c90c4801e4e12d531e979ddceb7866d44854
SHA512
28dda9db61e53fd06a7b1e5ea393790ad346c89f7157e92cc0671be5452af61ed554d93a6919e1a6a5cc26c21622765f6775d2a1a4ec0e0d53a5ed0882703ffd
diff --git a/dev-python/pyftpdlib/pyftpdlib-2.2.0.ebuild
b/dev-python/pyftpdlib/pyftpdlib-2.2.0.ebuild
new file mode 100644
index 000000000000..d9a4aa93162a
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-2.2.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="
+ https://github.com/giampaolo/pyftpdlib/
+ https://pypi.org/project/pyftpdlib/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="examples ssl"
+
+RDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pyasynchat[${PYTHON_USEDEP}]
+ dev-python/pyasyncore[${PYTHON_USEDEP}]
+ ' 3.12 3.13 3.14)
+ ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+ test? (
+ dev-python/psutil[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+
+python_test() {
+ rm -rf pyftpdlib || die
+ # Tests fail with TZ=GMT, see https://bugs.gentoo.org/666623
+ local -x TZ=UTC+1
+ # Skips some shoddy tests plus increases timeouts
+ local -x TRAVIS=1
+ epytest -o addopts= tests
+}
+
+python_install_all() {
+ if use examples; then
+ docinto examples
+ dodoc -r demo/.
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+ distutils-r1_python_install_all
+}
