[gentoo-commits] repo/gentoo:master commit in: dev-util/blueprint-compiler/

[Maciej Barć]

commit:     92bf8227e0ca0bd7d75da4811fa0f95f40ba54c0
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 22 20:24:53 2026 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu Jan 22 22:06:23 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=92bf8227

dev-util/blueprint-compiler: bump to 0.19.0

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-util/blueprint-compiler/Manifest               |  1 +
 .../blueprint-compiler-0.19.0.ebuild               | 82 ++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/dev-util/blueprint-compiler/Manifest 
b/dev-util/blueprint-compiler/Manifest
index 952e1b50b4d9..70a3d70dd79a 100644
--- a/dev-util/blueprint-compiler/Manifest
+++ b/dev-util/blueprint-compiler/Manifest
@@ -1 +1,2 @@
 DIST blueprint-compiler-0.18.0.tar.xz 106160 BLAKE2B 
c7e898075a9cac8153e50eca1a6de5b3f5b65e0b901af997ea000ac0155bd6ac683238fe6730599d1e1282802d6c22f5d25abe3b766ea591361429d26ee758a3
 SHA512 
0f15a0e997ec8edced82053f345abbfa4a77ca77dd5976d39e135c3b8af137f712ce2cb5b33abba7450ff440fb48dcb136186e2e0b7d54d0393d5778e8b19142
+DIST blueprint-compiler-0.19.0.tar.xz 117100 BLAKE2B 
86429dec8e6076e1ca7b97a822118a74158a08ffe318faeecaf660df3b54a7e11bb51f7d554049d3cc6428718d7b14c6ee31b17afb0fd800e1922f0f5cb1cfdd
 SHA512 
e32b8c9b2ccea16ce0f32c903da4dcf75a4b84031f357ed55332be1902d72adfbecd571c9274faea11a6f2f246574fb85191208c9b0727685869e81580d093f4

diff --git a/dev-util/blueprint-compiler/blueprint-compiler-0.19.0.ebuild 
b/dev-util/blueprint-compiler/blueprint-compiler-0.19.0.ebuild
new file mode 100644
index 000000000000..0da7b6dabc78
--- /dev/null
+++ b/dev-util/blueprint-compiler/blueprint-compiler-0.19.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit edo meson python-single-r1 virtualx
+
+DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
+HOMEPAGE="https://gnome.pages.gitlab.gnome.org/blueprint-compiler/
+       https://gitlab.gnome.org/GNOME/blueprint-compiler/";
+
+if [[ "${PV}" == *9999 ]] ; then
+       inherit git-r3
+
+       EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/${PN}.git";
+else
+       inherit gnome.org
+
+       KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+IUSE="doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       $(python_gen_cond_dep '
+               dev-python/pygobject:3[${PYTHON_USEDEP}]
+       ')
+"
+BDEPEND="
+       ${RDEPEND}
+       doc? (
+               $(python_gen_cond_dep '
+                       dev-python/furo[${PYTHON_USEDEP}]
+                       dev-python/sphinx[${PYTHON_USEDEP}]
+               ')
+       )
+       test? (
+               gui-libs/gtk:4[introspection]
+               gui-libs/libadwaita:1[introspection]
+       )
+"
+
+DOCS=( CONTRIBUTING.md MAINTENANCE.md NEWS.md README.md )
+
+src_prepare() {
+       default
+
+       rm ./tests/test_deprecations.py || die
+       rm ./tests/test_samples.py || die  # Fails on CI, bug #947156
+}
+
+src_configure() {
+       local -a emesonargs=(
+               $(meson_use doc docs)
+       )
+       meson_src_configure
+}
+
+src_compile() {
+       meson_src_compile
+
+       if use doc ; then
+               build_sphinx docs
+       fi
+}
+
+src_test() {
+       virtx edo "${EPYTHON}" -m unittest
+}
+
+src_install() {
+       meson_src_install
+       python_fix_shebang "${ED}/usr/bin"
+       python_optimize
+}