[gentoo-commits] repo/gentoo:master commit in: dev-python/nbdime/

[Michał Górny]

commit:     76dca79470914ba34ef3b6e2d979a90f8c40d4a4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 17 07:31:31 2026 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 17 07:31:31 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=76dca794

dev-python/nbdime: Bump to 4.0.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nbdime/Manifest            |  1 +
 dev-python/nbdime/nbdime-4.0.3.ebuild | 67 +++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-python/nbdime/Manifest b/dev-python/nbdime/Manifest
index 96a1d40b1247..f065417a8b48 100644
--- a/dev-python/nbdime/Manifest
+++ b/dev-python/nbdime/Manifest
@@ -1 +1,2 @@
 DIST nbdime-4.0.2.tar.gz 9452967 BLAKE2B 
c9c390f9165d0b8b3277c7bd93e5a90f4ac23cf0d084ed8ba166254bfbfe9cc0e9f0bc35c2a86b39d84167e78639cb2ed69f6cda5da02bb113f7323a86d745a6
 SHA512 
1e923b7f719d6a33f1dc06e06511a6d48bb8bfef7d8f7676da2520edd2914014eb88f70eaaeec27af6b03f1cefbd9a3e6854a7c0dec7f76f211d750b3fd90894
+DIST nbdime-4.0.3.tar.gz 9453461 BLAKE2B 
f2d3254155c8b00a246a232da201a13ceb2656e8b9d98a0701bfebc6ca37c5b8bc97a46831c3cbc0218c90d1e71e848f9deffedb7899f58407b6db475ec771dd
 SHA512 
b94a1684bca3585fa68611b330c3e7626e198c6b619d0714921324bf623a4b80ba474d808177ebeebd43d95eb0439cb01a7c6b47247ae4ffe15ea65bd5dc72ab

diff --git a/dev-python/nbdime/nbdime-4.0.3.ebuild 
b/dev-python/nbdime/nbdime-4.0.3.ebuild
new file mode 100644
index 000000000000..14d8e9532cb8
--- /dev/null
+++ b/dev-python/nbdime/nbdime-4.0.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Diff and merge of Jupyter Notebooks"
+HOMEPAGE="
+       https://jupyter.org/
+       https://github.com/jupyter/nbdime/
+       https://pypi.org/project/nbdime/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+       dev-python/colorama[${PYTHON_USEDEP}]
+       dev-python/gitpython[${PYTHON_USEDEP}]
+       dev-python/jinja2[${PYTHON_USEDEP}]
+       dev-python/jupyter-server[${PYTHON_USEDEP}]
+       dev-python/jupyter-server-mathjax[${PYTHON_USEDEP}]
+       dev-python/nbformat[${PYTHON_USEDEP}]
+       dev-python/pygments[${PYTHON_USEDEP}]
+       dev-python/requests[${PYTHON_USEDEP}]
+       dev-python/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               dev-python/jsonschema[${PYTHON_USEDEP}]
+               dev-python/notebook[${PYTHON_USEDEP}]
+               dev-python/tabulate[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_sphinx docs/source \
+       dev-python/recommonmark \
+       dev-python/sphinx-rtd-theme
+EPYTEST_PLUGINS=( pytest-timeout )
+distutils_enable_tests pytest
+
+src_test() {
+       # user.email and user.name are not configured in the sandbox
+       git config --global user.email "la...@gentoo.org" || die
+       git config --global user.name "Larry the Cow" || die
+
+       distutils-r1_src_test
+}
+
+python_test() {
+       local EPYTEST_IGNORE=(
+               # require pytest-tornado
+               nbdime/tests/test_web.py
+       )
+
+       epytest -o tmp_path_retention_policy=all
+}
+
+src_install() {
+       distutils-r1_src_install
+       mv "${ED}"{/usr,}/etc || die
+}