commit: 0953e0fe2af22467d6e613df5981f246ef599b9c
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 9 06:47:51 2026 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jan 9 07:29:54 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0953e0fe
dev-python/build: Bump to 1.4.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/build/Manifest | 1 +
dev-python/build/build-1.4.0.ebuild | 75 +++++++++++++++++++++++++++++++++++++
2 files changed, 76 insertions(+)
diff --git a/dev-python/build/Manifest b/dev-python/build/Manifest
index d2b8071ad660..6b489749ca88 100644
--- a/dev-python/build/Manifest
+++ b/dev-python/build/Manifest
@@ -1 +1,2 @@
DIST build-1.3.0.gh.tar.gz 50871 BLAKE2B
0ca200c92e3bfa3ee91643cb140e4e6e90b01cdf820576a4b36e828ae5ed981075e22f0882b3ef6e2032a7f3cab3810a12c2b68503fccae89060b7cff8da9164
SHA512
f34450ffc92a434af2614f4341b38c8feed18ce9a799196bff3f735afc52334cacb34d2a831c3264bbfaacda642a5e4defe3842f8010cd687d47e2d018a191d0
+DIST build-1.4.0.gh.tar.gz 52372 BLAKE2B
f7dac4752e908eee7e3f31af1da4c8854d5d1e3ac5210ea8acd1b306fa25a95b26ed68a7990782afc27e69b65f9719b8f914852ce2ac7989a89e77c06dd354bc
SHA512
aad08af8a163c914671c1b149306061ea93fc1fb5f066dda5a351ddec4b7b374160bf657d30b0eccc498c4f53950307646d792b58cb0efb91975b2541e111d88
diff --git a/dev-python/build/build-1.4.0.ebuild
b/dev-python/build/build-1.4.0.ebuild
new file mode 100644
index 000000000000..bb833b9369e2
--- /dev/null
+++ b/dev-python/build/build-1.4.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_TESTED=( python3_{11..14} pypy3_11 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_{13,14}t )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="A simple, correct PEP517 package builder"
+HOMEPAGE="
+ https://pypi.org/project/build/
+ https://github.com/pypa/build/
+"
+SRC_URI="
+ https://github.com/pypa/build/archive/${PV/_p/.post}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="test test-rust"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+ dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/setuptools-scm-6[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ $(python_gen_cond_dep '
+ >=dev-python/filelock-3[${PYTHON_USEDEP}]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ >=dev-python/pytest-mock-2[${PYTHON_USEDEP}]
+ >=dev-python/pytest-rerunfailures-9.1[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-1.34[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-56.0.0[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20.0.35[${PYTHON_USEDEP}]
+ >=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
+ test-rust? (
+ !s390? ( !sparc? ( >=dev-python/uv-0.1.18 ) )
+ )
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+
+python_test() {
+ if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
+ einfo "Skipping tests on ${EPYTHON}"
+ return
+ fi
+
+ local EPYTEST_DESELECT=(
+ # broken by uv being installed outside venv
+ tests/test_env.py::test_external_uv_detection_success
+ )
+
+ if ! has_version "dev-python/uv"; then
+ EPYTEST_DESELECT+=(
+ tests/test_env.py::test_uv_impl_install_cmd_well_formed
+ 'tests/test_env.py::test_venv_creation[uv-venv+uv-None]'
+ )
+ fi
+
+ local EPYTEST_PLUGINS=( pytest-{mock,rerunfailures} )
+ local EPYTEST_XDIST=1
+ epytest -m "not network"
+}
