commit: 141415cc9deb6ef8ba06bc6966c7f28ae061b595
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 8 03:20:33 2026 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jan 8 03:34:41 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=141415cc
dev-python/trimesh: Bump to 4.11.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/trimesh/Manifest | 1 +
dev-python/trimesh/trimesh-4.11.0.ebuild | 88 ++++++++++++++++++++++++++++++++
2 files changed, 89 insertions(+)
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 486624bead4d..e33f98db83ee 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1,2 +1,3 @@
DIST trimesh-4.10.0.gh.tar.gz 13703201 BLAKE2B
e1e4905204de24037f10d891016999ee86be44848ae9c944fa53be6b28b3c9cc93afef38fb61c8e2b136c49e093eba8dcb09bc6ee35404f9eca81082d13c6235
SHA512
4ac86659b62ee9793877fb0cb080c14bbf0e6864ba4fd69a9761864c055721648fcd3fbd672647bf0e268891f423287b371eb14a963ee38da0f96b04703995ad
DIST trimesh-4.10.1.gh.tar.gz 13705595 BLAKE2B
3bc4308f69c767988ce0d4e6df7e07892373bcc276002c5425379a04cdd561031a171be8fb4b08ede6a55aa4a89eb9cbb8631fb5bb7c2a33ae2abcc123a60eec
SHA512
28ce90a55f93dd2a6af38d576e7531457f80b22007eb76dee96c9691ab60c6cefb9980f67bb6c0f859de43d142b124a54c55c80822dddf367be90f414e01a49e
+DIST trimesh-4.11.0.gh.tar.gz 13708336 BLAKE2B
fe8becf5f5b8e581649eb9e3ca387a28371849019f8a5654b68c3df994ec49fd9de107f1f8388ccbd30daf4bab146b9441d98696bac947a2c9cadc3df6617aad
SHA512
5783b6b4e57de23d5020b2b062ab97363aafc90fecc3fb34b405ffee0efd9c831193f6ca0f7be81eb85a4c0231ef7fb6faa5cd43ed078188d1e8c47f0735ab4e
diff --git a/dev-python/trimesh/trimesh-4.11.0.ebuild
b/dev-python/trimesh/trimesh-4.11.0.ebuild
new file mode 100644
index 000000000000..7663c8452552
--- /dev/null
+++ b/dev-python/trimesh/trimesh-4.11.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+ https://trimesh.org/
+ https://github.com/mikedh/trimesh/
+ https://pypi.org/project/trimesh/
+"
+SRC_URI="
+ https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+ dev-python/charset-normalizer[${PYTHON_USEDEP}]
+ dev-python/colorlog[${PYTHON_USEDEP}]
+ dev-python/httpx[${PYTHON_USEDEP}]
+ dev-python/jsonschema[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/networkx[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pycollada[${PYTHON_USEDEP}]
+ dev-python/pyglet[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ >=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+ dev-python/svg-path[${PYTHON_USEDEP}]
+ dev-python/sympy[${PYTHON_USEDEP}]
+ dev-python/xxhash[${PYTHON_USEDEP}]
+ dev-python/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/mapbox-earcut[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_DESELECT=(
+ # requires manifold3d
+ tests/test_boolean.py::test_multiple_difference
+ # timing nonsense
+ tests/test_bounds.py::BoundsTest::test_obb_mesh_large
+)
+EPYTEST_IGNORE=(
+ # require pyinstrument
+ tests/test_sweep.py
+)
+
+EPYTEST_PLUGINS=()
+: ${EPYTEST_TIMEOUT:=300}
+EPYTEST_RERUNS=3
+EPYTEST_XDIST=1
+
+distutils_enable_tests pytest
+
+python_test() {
+ # We run tests in parallel, so avoid having n^2 threads in lapack
+ # tests.
+ local -x BLIS_NUM_THREADS=1
+ local -x MKL_NUM_THREADS=1
+ local -x OMP_NUM_THREADS=1
+ local -x OPENBLAS_NUM_THREADS=1
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature_header "${PN} functionality can be extended by installing
the following packages:"
+ optfeature "making GUI applications with 3D stuff" dev-python/glooey
+ optfeature "2D triangulations of polygons" dev-python/mapbox-earcut
+ optfeature "loading a number of additional mesh formats"
dev-python/meshio
+ optfeature "figuring out how much memory we have" dev-python/psutil
+ optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}
