commit: 158f1d0d1a5865c3d424716c7328c5af25f44c50
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 2 21:42:56 2026 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 2 21:51:54 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=158f1d0d
dev-util/pkgcheck: add 0.10.38
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-util/pkgcheck/Manifest | 1 +
dev-util/pkgcheck/pkgcheck-0.10.38.ebuild | 99 +++++++++++++++++++++++++++++++
2 files changed, 100 insertions(+)
diff --git a/dev-util/pkgcheck/Manifest b/dev-util/pkgcheck/Manifest
index 6b5c904dcb13..fded2b6deb8a 100644
--- a/dev-util/pkgcheck/Manifest
+++ b/dev-util/pkgcheck/Manifest
@@ -1 +1,2 @@
DIST pkgcheck-0.10.37.tar.gz 388402 BLAKE2B
8e93290da49ed9d8231550a7602300c93d16f2dc4be040f88690bf4cf996b51f8aac3cb26b2478345b10dfb1faddc185d6316810d5bac091fc5cae504ced459d
SHA512
84c1717fad6a7f41dcc069dbdb68e73062606d7e0497286cba7255e415e8b317cb4aa396d9bc46f873712a65fa0e3cd95216df368ca73381f81c160308329f15
+DIST pkgcheck-0.10.38.tar.gz 402397 BLAKE2B
5804a60681390b6f317f3bbb3a4eb4c31bf5b083dbcbcf44c9fbcaef9ac9652a9ac2d391b822a31145e4c4a07e37d011be627a874b61ff297dd48f6db0a13ccf
SHA512
a2e6d37496fa6e8bc80a141e7f09f28d847a5734e7bc1c1a84f1b21e614d196736e6d6e3c392508ce7827f4c49f1421ffc59b0eb109e33b13a0513ab7b3186b0
diff --git a/dev-util/pkgcheck/pkgcheck-0.10.38.ebuild
b/dev-util/pkgcheck/pkgcheck-0.10.38.ebuild
new file mode 100644
index 000000000000..37c83fe5ac47
--- /dev/null
+++ b/dev-util/pkgcheck/pkgcheck-0.10.38.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{11..14} )
+inherit elisp-common distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+ EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgcheck.git
+ https://github.com/pkgcore/pkgcheck.git";
+ inherit git-r3
+else
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~x64-macos"
+ inherit pypi
+fi
+
+DESCRIPTION="pkgcore-based QA utility for ebuild repos"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck";
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="emacs"
+
+if [[ ${PV} == *9999 ]]; then
+ RDEPEND="
+ ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+ ~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+ RDEPEND="
+ >=dev-python/snakeoil-0.11.0[${PYTHON_USEDEP}]
+ >=sys-apps/pkgcore-0.12.31[${PYTHON_USEDEP}]"
+fi
+RDEPEND+="
+ app-arch/zstd
+ >=dev-libs/tree-sitter-bash-0.25.1[python,${PYTHON_USEDEP}]
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/pathspec[${PYTHON_USEDEP}]
+ >=dev-python/tree-sitter-0.25.2[${PYTHON_USEDEP}]
+ emacs? (
+ >=app-editors/emacs-24.1:*
+ app-emacs/ebuild-mode
+ app-emacs/flycheck
+ )
+"
+BDEPEND="${RDEPEND}
+ >=dev-python/flit-core-3.8[${PYTHON_USEDEP}]
+ test? (
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-vcs/git
+ )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+EPYTEST_PLUGINS=( pkgcore )
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin dependencies
+ sed -i -e 's:~=:>=:' pyproject.toml || die
+}
+
+src_compile() {
+ distutils-r1_src_compile
+
+ if use emacs ; then
+ pushd "${S}"/contrib/emacs >/dev/null || die
+ elisp-compile *.el
+ popd >/dev/null || die
+ fi
+}
+
+python_install_all() {
+ local DOCS=( NEWS.rst )
+ [[ ${PV} == *9999 ]] || doman build/sphinx/man/*
+ distutils-r1_python_install_all
+
+ if use emacs ; then
+ elisp-install ${PN} "${S}"/contrib/emacs/*.el{,c}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ optfeature "Network check support" dev-python/requests
+ optfeature "Perl module version check support"
dev-perl/Gentoo-PerlMod-Version
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
