commit: 0c91778fdf6ba076840208319335d3d4db40f7ac
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 1 03:04:37 2026 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jan 1 03:47:52 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c91778f
dev-python/sphinx: Bump to 9.1.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sphinx/Manifest | 1 +
dev-python/sphinx/sphinx-9.1.0.ebuild | 103 ++++++++++++++++++++++++++++++++++
2 files changed, 104 insertions(+)
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 845ac3ca668a..47e98e669515 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,4 +1,5 @@
DIST sphinx-8.2.3.gh.tar.gz 8378376 BLAKE2B
ddfa406140bebcaa09299a56fedf1170db6504a9ce3807e20c555f5e088d81acbfd19f2621a824b91199713b301380fd2056cf2282ea81f4a0858dd714eb7e45
SHA512
23066d9e98f3e36ee34ac3bc5af45792762f858e1e670145b7d1db7e98fa9e9654d87a27b9316dd72704aeea75b53f73d07d22f723c915d23a95f59bbd4f6365
DIST sphinx-9.0.4.gh.tar.gz 8843746 BLAKE2B
4cae21fa2b980f529f58444c4cf793ec455f5a0ea43944fa44e9e99a3d03de48f88f170e6c7382dea99cd0bb895729ee0b43cafe2aef1e84a190ea244e4c08da
SHA512
8652e6a65060a81609275afa6301bb0eaccda939e2988f86d548796a215a86c923c9240422497abe77652a436479930e81dfdf43fba9722b63a50542d3ac9522
+DIST sphinx-9.1.0.gh.tar.gz 8840512 BLAKE2B
54f680ff84b43b3508c1c9208ff41dc9fba1ae8f8dd608287511fb16e28dc7fa72419165b41f556af266e00c737cd8cc23a6617776fa88f0dbb8379fbbf59397
SHA512
3b17a3d4123d19ed47c7ab7786edcbe7eb0566f298d9de22efb3f4f0476b6c0ddf858b57812f2dac718458d98ddc742a443b7c94771693a1ed3bf868850639b1
DIST sphinx-9.1.0rc1.gh.tar.gz 8833000 BLAKE2B
12d327d8a15aae35c3e9bae4dd812334c7bc05ab16b8662c72d22d1d9a5b05eda6fff0be6299fda83a5cd8b9b88af8e5d704f78bdfe177081e68ad141f958a01
SHA512
02c24534b9137972dc48bb88e1c033ffd081c2493cd4a58eddc817f0ef340e883e53ac8deafaf1bb34977f8350f8cdfeb1b12e10f388ecdf33a5e761d15ccc58
DIST sphinx-9.1.0rc2.gh.tar.gz 8837164 BLAKE2B
05330402efe451547dad1ce7bae15db7db71c4b2509527ba383d73e6b200b569c08aa15c671e8e2d35f40cd8e94c14927b7cbf4c73d86b4c00f2c47d44be4a5c
SHA512
a621967315886b0937a4d86fe5855bd362866b523bb1f9b580082c86ec9e82046ee320886fa4573db99852f5b28ca024b9aa1c3dc0cccbf22ec5dc1315bc10ff
diff --git a/dev-python/sphinx/sphinx-9.1.0.ebuild
b/dev-python/sphinx/sphinx-9.1.0.ebuild
new file mode 100644
index 000000000000..90efbb85c59c
--- /dev/null
+++ b/dev-python/sphinx/sphinx-9.1.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+ https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinx/
+ https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+ https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc
~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc latex"
+
+RDEPEND="
+ >=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+ >=dev-python/babel-2.13[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.23[${PYTHON_USEDEP}]
+ >=dev-python/docutils-0.21[${PYTHON_USEDEP}]
+ >=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+ >=dev-python/jinja2-3.1[${PYTHON_USEDEP}]
+ >=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+ >=dev-python/roman-numerals-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/snowballstemmer-2.2[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-applehelp-1.0.7[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-devhelp-1.0.6[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-htmlhelp-2.0.6[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-jsmath-1.0.1[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-qthelp-1.0.6[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+ latex? (
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )
+"
+BDEPEND="
+ >=dev-python/flit-core-3.11
+ doc? (
+ dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+ media-gfx/graphviz
+ )
+ test? (
+ app-text/dvipng
+ >=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+ >=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+ dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+ dev-texlive/texlive-fontsextra
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ virtual/imagemagick-tools[jpeg,png,svg]
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+)
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+# EPYTEST_XDIST breaks stuff
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # disable internet access
+ sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+ doc/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ # we can't use distutils_enable_sphinx because it would
+ # introduce a dep on itself
+ use doc && build_sphinx doc
+}
+
+python_test() {
+ mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+ local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+ epytest
+}
