[gentoo-commits] repo/gentoo:master commit in: dev-util/meld/

[Pacho Ramos]

commit:     b55242a2cd3fef9d9a48fde9614b7bad15cedcd0
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 20 09:04:43 2025 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Dec 20 09:07:35 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b55242a2

dev-util/meld: add 3.22.3

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-util/meld/Manifest           |  1 +
 dev-util/meld/meld-3.22.3.ebuild | 71 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-util/meld/Manifest b/dev-util/meld/Manifest
index 4510646f94d6..612ed0de8724 100644
--- a/dev-util/meld/Manifest
+++ b/dev-util/meld/Manifest
@@ -1 +1,2 @@
 DIST meld-3.22.2.tar.xz 676376 BLAKE2B 
5e592e378ac2c942dd98df6d9ac4f9af7a1eee552af1691aade2e0f453a5ddf649ca09c38191b2c2ffdb7b6fa165012b4d8372e9e99c33052f612e2ab8ca8670
 SHA512 
fd8b12567cd8dcf77f265d831c9ac9ba33d13fb78c95b01b496b016308ff4159963b4610a68f41d04a52cc5bcc13bb4568d24bbade5bd79246111e463e413284
+DIST meld-3.22.3.tar.xz 676560 BLAKE2B 
2dc1a81aeb9307cba060fee095b4c497e93a46ae4235b6d077f7030c2e69a5d678d7cabd24650afab5a736bcdb8c077cce89a98c6376960a010015df0274a9a9
 SHA512 
8ac4aa046b12f2d9a35ce455493eb0f0531ceb3d137d30650fb6f83f31bf6c19d45cbb8bd6cc3a7fba7e6adc89644b579370f27462a8cde312a6c3c7c8181fb8

diff --git a/dev-util/meld/meld-3.22.3.ebuild b/dev-util/meld/meld-3.22.3.ebuild
new file mode 100644
index 000000000000..3be7921c4bcd
--- /dev/null
+++ b/dev-util/meld/meld-3.22.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..14} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="A graphical diff and merge tool"
+HOMEPAGE="http://meldmerge.org/";
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       >=x11-libs/gtk+-3.20:3[introspection]
+       >=dev-libs/glib-2.48:2
+       >=x11-libs/gtksourceview-4.0.0:4[introspection]
+       $(python_gen_cond_dep '
+               >=dev-python/pygobject-3.30:3[cairo,${PYTHON_USEDEP}]
+       ')
+       gnome-base/gsettings-desktop-schemas
+       >=x11-libs/pango-1.34[introspection]
+       x11-themes/hicolor-icon-theme
+"
+DEPEND="${RDEPEND}
+       test? (
+               dev-util/desktop-file-utils
+               dev-libs/appstream-glib
+       )
+"
+BDEPEND="
+       dev-util/intltool
+       dev-util/itstool
+       sys-devel/gettext
+       $(python_gen_cond_dep 'dev-python/distro[${PYTHON_USEDEP}]')
+"
+
+pkg_setup() {
+       python-single-r1_pkg_setup
+}
+
+src_configure() {
+       local emesonargs=(
+               -Dprofile=''
+               -Dbyte-compile=false
+       )
+       meson_src_configure
+}
+
+src_install() {
+       meson_src_install
+       python_optimize
+       python_fix_shebang "${ED}"/usr/bin/meld
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+       gnome2_schemas_update
+}
+
+pkg_postrm() {
+       xdg_pkg_postrm
+       gnome2_schemas_update
+}