[gentoo-commits] repo/gentoo:master commit in: dev-ada/aunit/

[Alfredo Tupone]

commit:     7a8c689a8c44a64ff2bfa4ae211be37221ac3f53
Author:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 17 20:02:24 2025 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Wed Dec 17 20:03:21 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7a8c689a

dev-ada/aunit: add 26.0.0

Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>

 dev-ada/aunit/Manifest            |  1 +
 dev-ada/aunit/aunit-26.0.0.ebuild | 65 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-ada/aunit/Manifest b/dev-ada/aunit/Manifest
index d882f99a8fa9..e0b3152afe43 100644
--- a/dev-ada/aunit/Manifest
+++ b/dev-ada/aunit/Manifest
@@ -1 +1,2 @@
 DIST aunit-25.0.0.tar.gz 137452 BLAKE2B 
91672bbdd86cc502456b681e9418f04dfc7dfc380ed9f9f69af36afb5e3b5ce22852a4fa92049ee5d9fade1439a6a4508e3d6f63b1005ae6f0e1d5cbfaa70118
 SHA512 
080d61c1c3b0707c291dce476573e05a247c198c2bea4ae311677dcae826e7bf34571700711b28ac46bd021e93c252492bafcb4892b24b45c7396d6b7e7b5f2d
+DIST aunit-26.0.0.tar.gz 137452 BLAKE2B 
8ca7a0652e96c71d065bcb64597891d4b7c818c601d0473cf2abaa263414ef0c6e4dfe95e613d4b7d495a66981efb1700fec495bd7d0f119a675f325bdceb706
 SHA512 
955967e9b90ba4894c803a34c98d64c517fcc5eec5eb330f6ab04d537554550c60f180c078a9339f52839a2e0751c96364753d2094f5af0ad7a87f008b661851

diff --git a/dev-ada/aunit/aunit-26.0.0.ebuild 
b/dev-ada/aunit/aunit-26.0.0.ebuild
new file mode 100644
index 000000000000..5503f8b0b4d2
--- /dev/null
+++ b/dev-ada/aunit/aunit-26.0.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ADA_COMPAT=( gcc_{12..16} )
+PYTHON_COMPAT=( python3_{10..14} )
+inherit ada python-any-r1 multiprocessing
+
+DESCRIPTION="Ada unit testing framework"
+HOMEPAGE="https://github.com/AdaCore/aunit";
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+       -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${ADA_REQUIRED_USE}"
+
+RDEPEND="${ADA_DEPS}"
+DEPEND="${RDEPEND}
+       dev-ada/gprbuild[${ADA_USEDEP}]"
+BDEPEND="doc? (
+       $(python_gen_any_dep '
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+       ')
+)"
+
+python_check_deps() {
+       python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+       python_has_version "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use doc && python-any-r1_pkg_setup
+       ada_pkg_setup
+}
+
+src_prepare() {
+       default
+       sed -i \
+               -e "s|@PF@|${PF}|g" \
+               lib/gnat/aunit.gpr \
+               || die
+}
+
+src_compile() {
+       emake GPROPTS_EXTRA="-j$(makeopts_jobs) -v -cargs ${ADAFLAGS}"
+       use doc && emake -C doc aunit_cb.html
+}
+
+src_install() {
+       emake INSTALL="${D}"/usr install
+       DOCS="README"
+       use doc && HTML_DOCS="doc/build/aunit_cb/html/*"
+       einstalldocs
+       mv "${D}"/usr/share/examples "${D}"/usr/share/doc/${PF}/
+       rm -r "${D}"/usr/share/gpr/manifests || die
+}
+
+src_test() {
+       emake PROJECT_PATH_ARG="ADA_PROJECT_PATH=$(pwd)/lib/gnat" -C test
+}