commit: 778420913c339bf7e3c15e66c2509c79a4a9e37c
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 9 01:12:50 2025 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Dec 9 01:44:19 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=77842091
dev-qt/qtspeech: add 6.11.9999
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
dev-qt/qtspeech/qtspeech-6.11.9999.ebuild | 40 +++++++++++++++++++++++++++++++
1 file changed, 40 insertions(+)
diff --git a/dev-qt/qtspeech/qtspeech-6.11.9999.ebuild
b/dev-qt/qtspeech/qtspeech-6.11.9999.ebuild
new file mode 100644
index 000000000000..15c2e89ce96e
--- /dev/null
+++ b/dev-qt/qtspeech/qtspeech-6.11.9999.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# tests are kind of flaky, sometimes hang, and also fail with clang
+# (not that it's unusable with clang) -- may be worth revisiting
+# eventually given qtspeech is still somewhat new (added in 6.4.0)
+QT6_RESTRICT_TESTS=1
+
+inherit qt6-build
+
+DESCRIPTION="Text-to-speech library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="flite qml +speechd"
+# can build with neither, but then it is just mock tts and may be confusing
+REQUIRED_USE="|| ( flite speechd )"
+
+RDEPEND="
+ ~dev-qt/qtbase-${PV}:6
+ ~dev-qt/qtmultimedia-${PV}:6
+ flite? ( app-accessibility/flite )
+ qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
+ speechd? ( app-accessibility/speech-dispatcher )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package qml Qt6Qml)
+ $(qt_feature flite)
+ $(qt_feature speechd)
+ )
+
+ qt6-build_src_configure
+}
