commit: 7249a6a35d879f5fa6d2f381a2c653e96fac831f
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 9 01:12:44 2025 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Dec 9 01:44:17 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7249a6a3
dev-qt/qtquick3d: add 6.11.9999
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
dev-qt/qtquick3d/qtquick3d-6.11.9999.ebuild | 57 +++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
diff --git a/dev-qt/qtquick3d/qtquick3d-6.11.9999.ebuild
b/dev-qt/qtquick3d/qtquick3d-6.11.9999.ebuild
new file mode 100644
index 000000000000..0ae502e79761
--- /dev/null
+++ b/dev-qt/qtquick3d/qtquick3d-6.11.9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QT6_HAS_STATIC_LIBS=1
+inherit qt6-build
+
+DESCRIPTION="Qt module and API for defining 3D content in Qt QuickTools"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+elif [[ ${QT6_BUILD_TYPE} == live ]]; then
+ EGIT_SUBMODULES=() # skip qtquick3d-assimp
+fi
+
+IUSE="opengl vulkan"
+
+RDEPEND="
+ ~dev-qt/qtbase-${PV}:6[concurrent,gui,opengl=,vulkan=,widgets]
+ ~dev-qt/qtdeclarative-${PV}:6
+ ~dev-qt/qtquicktimeline-${PV}:6
+ ~dev-qt/qtshadertools-${PV}:6
+ media-libs/assimp:=
+ virtual/zlib:=
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( ~dev-qt/qtbase-${PV}:6[network] )
+ vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="
+ ~dev-qt/qtshadertools-${PV}:6
+"
+
+CMAKE_SKIP_TESTS=(
+ # needs off-by-default assimp[collada] that is masked on some profiles,
+ # not worth the extra trouble
+ tst_qquick3dassetimport
+)
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-6.6.2-gcc14.patch
+ "${FILESDIR}"/${PN}-6.6.2-x32abi.patch
+ "${FILESDIR}"/${PN}-6.9.2-assimp6.patch
+)
+
+src_configure() {
+ local mycmakeargs=(
+ # TODO: if someone wants it, openxr should likely have its own
+ # USE and be packaged rather than use the bundled copy (if use
+ # bundled, note need to setup python-any-r1)
+ -DQT_FEATURE_quick3dxr_openxr=OFF
+ )
+
+ qt6-build_src_configure
+}
