commit: af013b8e948d14265f7c7dff57fbf72b671f7883
Author: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Dec 7 15:28:10 2025 +0000
Commit: Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Sun Dec 7 15:32:20 2025 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=af013b8e
net-im/meowlnir: new package, add 25.11
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>
net-im/meowlnir/Manifest | 2 ++
net-im/meowlnir/files/meowlnir.initd | 16 ++++++++++
net-im/meowlnir/meowlnir-25.11.ebuild | 57 +++++++++++++++++++++++++++++++++++
net-im/meowlnir/metadata.xml | 12 ++++++++
4 files changed, 87 insertions(+)
diff --git a/net-im/meowlnir/Manifest b/net-im/meowlnir/Manifest
new file mode 100644
index 0000000000..fe9d399283
--- /dev/null
+++ b/net-im/meowlnir/Manifest
@@ -0,0 +1,2 @@
+DIST meowlnir-0.2511.0-vendor.tar.xz 3683168 BLAKE2B
94ea1458255a82215921bf254d7db95e0b4f9e47ab2d46aff4cbb76710e5b046c5800a9a560e90f918d3ad8d082566846503b382da20050b58f54f8914315701
SHA512
2f117557ae070a0560563049135102a52e96be76ab9e942c058567705cfed8faeee5d73c674cc69b56130a38560885514589e2aa621173cee3526458cb113944
+DIST meowlnir-25.11.tar.gz 77618 BLAKE2B
fab9ae01c7ffeb2a57fb7be76f50b9b0ca1fa059c138e8765ef2b41cb495e7977a5e5578a65e0760c180c6e9188049cb78a6eacf9a67d5ce9eaec13b1ec610ee
SHA512
1170071594809583d954ef0cf163d7ff04d7afc9b0e31ca323170762910900b568dd8db211e1ac3a3b7f487c0305d23f9d23365710f16dc689d6a893d32637ff
diff --git a/net-im/meowlnir/files/meowlnir.initd
b/net-im/meowlnir/files/meowlnir.initd
new file mode 100644
index 0000000000..1f80dfa09e
--- /dev/null
+++ b/net-im/meowlnir/files/meowlnir.initd
@@ -0,0 +1,16 @@
+#!/sbin/openrc-run
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+#
+# shellcheck shell=sh
+
+supervisor="supervise-daemon"
+command="/usr/bin/meowlnir"
+command_args="-c ${MEOWLNIR_CONF:-/etc/meowlnir/config.yaml} ${MEOWLNIR_ARGS}"
+command_user="meowlnir:meowlnir"
+pidfile="/run/${RC_SVCNAME}.pid"
+
+depend() {
+ use dns postgresql
+ need net
+}
diff --git a/net-im/meowlnir/meowlnir-25.11.ebuild
b/net-im/meowlnir/meowlnir-25.11.ebuild
new file mode 100644
index 0000000000..962ff49bfe
--- /dev/null
+++ b/net-im/meowlnir/meowlnir-25.11.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module
+
+MY_PV="0.$(ver_rs 1-2 '').0"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="Opinionated Matrix moderation bot"
+HOMEPAGE="https://github.com/maunium/meowlnir";
+SRC_URI="https://github.com/maunium/${PN}/archive/refs/tags/v${MY_PV}.tar.gz
-> ${P}.tar.gz
+
https://github.com/gentoo-golang-dist/meowlnir/releases/download/v${MY_PV}/${MY_P}-vendor.tar.xz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="AGPL-3+"
+# Go dependency licenses
+LICENSE+=" Apache-2.0 BSD GPL-3+ ISC MIT MPL-2.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ acct-user/meowlnir
+ dev-libs/olm
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( {CHANGELOG,README}.md )
+
+src_compile() {
+ local MAUTRIX_VERSION=$(awk '/maunium\.net\/go\/mautrix / { print $2 }'
go.mod)
+ local BUILD_TIME=$(date -Iseconds)
+ local go_ldflags=(
+ -X "main.Tag=v${MY_PV}"
+ -X "main.BuildTime=${BUILD_TIME}"
+ -X "maunium.net/go/mautrix.GoModVersion=${MAUTRIX_VERSION}"
+ )
+
+ local -x GOEXPERIMENT=jsonv2
+ ego build -ldflags "${go_ldflags[*]}" ./cmd/meowlnir
+}
+
+src_install() {
+ dobin meowlnir
+ newinitd "${FILESDIR}"/meowlnir.initd meowlnir
+ einstalldocs
+
+ insinto /etc/meowlnir
+ doins config/example-config.yaml
+
+ fowners -R meowlnir:meowlnir /etc/meowlnir
+ fperms 750 /etc/meowlnir
+
+ keepdir /var/lib/meowlnir
+ fowners -R meowlnir:meowlnir /var/lib/meowlnir
+}
diff --git a/net-im/meowlnir/metadata.xml b/net-im/meowlnir/metadata.xml
new file mode 100644
index 0000000000..8f635f1901
--- /dev/null
+++ b/net-im/meowlnir/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="person">
+ <email>[email protected]</email>
+ <name>Anna</name>
+ </maintainer>
+ <upstream>
+ <remote-id type="github">maunium/meowlnir</remote-id>
+ <doc>https://docs.mau.fi/meowlnir/</doc>
+ </upstream>
+</pkgmetadata>
