commit: 53927beb09f6e42164532825a129d783a08c34f9
Author: Marc Schiffbauer <mschiff <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 2 21:12:13 2025 +0000
Commit: Marc Schiffbauer <mschiff <AT> gentoo <DOT> org>
CommitDate: Tue Dec 2 22:01:56 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53927beb
app-backup/borgbackup: add 1.4.3
Signed-off-by: Marc Schiffbauer <mschiff <AT> gentoo.org>
app-backup/borgbackup/Manifest | 1 +
app-backup/borgbackup/borgbackup-1.4.3.ebuild | 66 +++++++++++++++++++++++++++
2 files changed, 67 insertions(+)
diff --git a/app-backup/borgbackup/Manifest b/app-backup/borgbackup/Manifest
index 4f489b07394f..3732a3a87cc1 100644
--- a/app-backup/borgbackup/Manifest
+++ b/app-backup/borgbackup/Manifest
@@ -1,2 +1,3 @@
DIST borgbackup-1.4.1.tar.gz 3817197 BLAKE2B
fbf5cd06bcddd5b90db75ed1b2276d2eba0d17d0545a751acfd40d051053d9d3e1a0ea2f1dd87e6541aeca6199e98ad1885b9d3155696268752069b763b660a4
SHA512
83ce8fcefa4e4099922e1f3894aba41d8d83ccff3e554b4b5ee0f0b9b8b18b18bcbf7f566e36aea4214e0d9d427cb66d63d2e1933b773e3338fd5814fd80e3a4
DIST borgbackup-1.4.2.tar.gz 3932875 BLAKE2B
a3489c46d17cc07a62f5098320a5023e957f7044021d307d879b0c0dfe4bc49ddf10151a2e2e888dbbb2721f412f6a699d7b8b67d1a0e28eda92dfd931b164b6
SHA512
035396661013057614724f55d6b3e3ed35b686887d836b7358e1f95b6c354ec5c4d9592c29cb1d4577e113e3a0558a9054689a2678b62b97d78287ad0295cce0
+DIST borgbackup-1.4.3.tar.gz 4014143 BLAKE2B
9e93ca819e9083a256b8ccd6093b6ee2e69cfabb6a89b16958b9b64da2c1b217d9a1149ca40147817169ab388db33bca9c5ab6308e7064d8b3c92714ce9abcaa
SHA512
500c9da7aeeea6e9aac1efe4760e8d6ef6e7f9c80fc32c3f2e7b7dfb27d54cd0131b7c27248c276b23034fc92cdb2a8611926773f5aa9801eb99139efc9d0dd2
diff --git a/app-backup/borgbackup/borgbackup-1.4.3.ebuild
b/app-backup/borgbackup/borgbackup-1.4.3.ebuild
new file mode 100644
index 000000000000..7c3f9819c966
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.4.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated
encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/";
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+ app-arch/lz4
+ app-arch/zstd
+ dev-libs/openssl:0=
+ >=dev-libs/xxhash-0.8.1
+ virtual/acl
+"
+# borgbackup is *very* picky about which msgpack it work with,
+# check pyproject.toml on bumps.
+RDEPEND="
+ ${DEPEND}
+ <=dev-python/msgpack-1.1.2-r9999[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ dev-python/pyfuse3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/pkgconfig[${PYTHON_USEDEP}]
+ dev-python/setuptools-scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/python-dateutil[${PYTHON_USEDEP}]
+ )
+"
+
+# some tests randomly fail with xdist, bug #936524
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Needs pytest-benchmark fixture
+ benchmark.py::test_
+ )
+
+ # This disables fuse releated tests
+ local -x BORG_FUSE_IMPL="none"
+ epytest --pyargs borg.testsuite
+}
+
+src_install() {
+ distutils-r1_src_install
+ doman docs/man/*
+
+ dobashcomp scripts/shell_completions/bash/borg
+ dozshcomp scripts/shell_completions/zsh/_borg
+ dofishcomp scripts/shell_completions/fish/borg.fish
+}
