commit: 381624db8d9e40ca4804a0095f23d1353e222bd2
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 26 04:20:34 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Nov 26 04:33:38 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=381624db
dev-python/kombu: Bump to 5.6.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/kombu/Manifest | 1 +
dev-python/kombu/kombu-5.6.1.ebuild | 92 +++++++++++++++++++++++++++++++++++++
2 files changed, 93 insertions(+)
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 01d94aeb1315..242b291f4abc 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
DIST kombu-5.6.0.tar.gz 470557 BLAKE2B
ca24998244e53cba0a84270e606ecc7b7b2759f93ef7d4018b92916098243054aa4230883e9bdb956d1166c5ec387da22e7118e018267d343b090ca37ecd67a3
SHA512
a69c835a44a2307803c708ade77ff49d0d016f4d9fa19f2881499cbf4a24b981ed8b6a2e50d5ebb2482508303110cc3d14695dd69d30cd9b00875992605e66ec
+DIST kombu-5.6.1.tar.gz 471548 BLAKE2B
aab4d6a9a9b6d4f9a7c874e3998a4d05d1cce9e5ac02126a85ff3de6b6bde494354cf859facef5220528e929919b3c01c23fd5483a7f33558835df3554f1f535
SHA512
0f62917cf2a9ea8231b1709e63198aa8abe29b270ac70e70de7728e5fd90fab60f9663015965b6a67e0a03bbd6a129ab0fefbbd56775d74485b1684f8694db12
diff --git a/dev-python/kombu/kombu-5.6.1.ebuild
b/dev-python/kombu/kombu-5.6.1.ebuild
new file mode 100644
index 000000000000..dc1629a3fb1d
--- /dev/null
+++ b/dev-python/kombu/kombu-5.6.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+ https://github.com/celery/kombu/
+ https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+ <dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ >=dev-python/tzdata-2025.2[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+ >=dev-python/pycurl-7.43.0.5[${PYTHON_USEDEP}]
+ >=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=( pytest-freezer )
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+ dev-python/sphinx-celery
+
+EPYTEST_DESELECT=(
+ # TODO
+
t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+
t/unit/transport/test_redis.py::test_Channel::test_global_keyprefix_transaction
+ # bad filename assumption?
+
t/unit/asynchronous/aws/test_connection.py::test_AsyncHTTPSConnection::test_request_with_cert_path_https
+)
+EPYTEST_IGNORE=(
+ # obsolete Pyro4
+ t/unit/transport/test_pyro.py
+ # unpackaged azure
+ t/unit/transport/test_azurestoragequeues.py
+ # unpackage google-cloud
+ t/unit/transport/test_gcpubsub.py
+)
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin deps (notably tzdata, sigh)
+ > requirements/default.txt || die
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+ optfeature "Etcd backend" dev-python/python-etcd
+ optfeature "MongoDB backend" dev-python/pymongo
+ optfeature "Redis backend" dev-python/redis
+ optfeature "sqlalchemy backend" dev-python/sqlalchemy
+ optfeature "yaml backend" dev-python/pyyaml
+ optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+ optfeature "brotli compression" "app-arch/brotli[python]"
+ optfeature "zstd compression" dev-python/zstandard
+}
