commit: 844db64a83ce74a996a0e7afff38f498f1ceda8b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 25 08:15:48 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov 25 08:15:48 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=844db64a
dev-python/pdm: Bump to 2.26.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pdm/Manifest | 1 +
dev-python/pdm/pdm-2.26.2.ebuild | 85 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 86 insertions(+)
diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index 21ee2378476f..016218cf53ca 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1 +1,2 @@
DIST pdm-2.26.1.tar.gz 2671172 BLAKE2B
cb0360e4973adf162c5980158633df6e64b3164e4af8b1f741ed613141b6b46b8bf3dce5306991b46a3d1f6b9a7e70da1c9bcbcc4326502578cdbd0aff548502
SHA512
b51f15441ae1b71b4efadb6a74043a717ec1b7247091b665129c38b32b6514392c6b2d274a3667f38d7ba477d666eeeb3696b082dc2ec287ca8857fb51c12854
+DIST pdm-2.26.2.tar.gz 2671330 BLAKE2B
caf784dd2e55a5853b7dd0fa901d3f78cf49146ce1547cce238b6ad7a4180b4bad9d875a19398c596889c82c359141d559982138cdde76c31e2d732a9afe7708
SHA512
231afc9565afd68fb0e4e05895b28a61ea2e704166f3139f56c25a9b73ca26f4ebb3879cf31f764c199acfbb766e0e2a3bffbdc43169c126b250da571afb4752
diff --git a/dev-python/pdm/pdm-2.26.2.ebuild b/dev-python/pdm/pdm-2.26.2.ebuild
new file mode 100644
index 000000000000..371b1e8410cc
--- /dev/null
+++ b/dev-python/pdm/pdm-2.26.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP
standards"
+HOMEPAGE="
+ https://pdm-project.org/
+ https://github.com/pdm-project/pdm/
+ https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+ dev-python/certifi[${PYTHON_USEDEP}]
+ >=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+ <dev-python/findpython-1[${PYTHON_USEDEP}]
+ >=dev-python/findpython-0.7.0[${PYTHON_USEDEP}]
+ dev-python/blinker[${PYTHON_USEDEP}]
+ dev-python/filelock[${PYTHON_USEDEP}]
+ <dev-python/hishel-1[${PYTHON_USEDEP}]
+ >=dev-python/hishel-0.0.32[${PYTHON_USEDEP}]
+ >=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+ dev-python/httpx[${PYTHON_USEDEP}]
+ >=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+ dev-python/installer[${PYTHON_USEDEP}]
+ >=dev-python/packaging-22.1[${PYTHON_USEDEP}]
+ >=dev-python/pbs-installer-2025.10.07[${PYTHON_USEDEP}]
+ dev-python/platformdirs[${PYTHON_USEDEP}]
+ dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+ dev-python/python-dotenv[${PYTHON_USEDEP}]
+ >=dev-python/resolvelib-1.2.0[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ dev-python/shellingham[${PYTHON_USEDEP}]
+ dev-python/tomlkit[${PYTHON_USEDEP}]
+ >=dev-python/truststore-0.10.4[${PYTHON_USEDEP}]
+ >=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+ dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ ${RDEPEND}
+ test? (
+ dev-python/msgpack[${PYTHON_USEDEP}]
+ dev-python/uv
+ )
+"
+
+EPYTEST_PLUGINS=( pytest-{httpserver,httpx,mock,rerunfailures} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin deps
+ sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+ # remove pkgutil namespace magic, as it doesn't work and makes
+ # dev-python/pdm-backend tests test the wrong package
+ rm src/pdm/__init__.py || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+
'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @
file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+ # unhappy about extra packages being installed?
+ # (also fails randomly in venv)
+ tests/cli/test_build.py::test_build_with_no_isolation
+ # TODO: random regression?
+ tests/cli/test_python.py::test_find_python
+ # TODO
+ tests/test_formats.py::test_export_from_pylock_not_empty
+ )
+
+ epytest -m "not network and not integration and not path"
+}
