commit: 8baca4199a9b23a9e2fb4c94990f7d5bb159c10e
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 29 03:04:27 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct 29 03:33:13 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8baca419
dev-python/hishel: Bump to 1.0.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hishel/Manifest | 1 +
dev-python/hishel/hishel-1.0.0.ebuild | 73 +++++++++++++++++++++++++++++++++++
2 files changed, 74 insertions(+)
diff --git a/dev-python/hishel/Manifest b/dev-python/hishel/Manifest
index c85ce969556e..dc329569c847 100644
--- a/dev-python/hishel/Manifest
+++ b/dev-python/hishel/Manifest
@@ -1 +1,2 @@
DIST hishel-0.1.5.gh.tar.gz 1065622 BLAKE2B
926801f579a57cc2b45cb6cd5326459493452d34b32a2725b906307dcc4575b1297b35ffc626e51acc5805216731552d58c672dedb0541f2c771f153daee960d
SHA512
b1f850895b147da616ace381d98ac9b6a15386d7e79d64a57a4e87f9bd0b42009a6ffa15fe1f8e46c57f8bc664c3af97d46e5adb81211e30fae87dab898f7734
+DIST hishel-1.0.0.gh.tar.gz 1094037 BLAKE2B
65ae2cf7f4b891ffc4ee1db1b2cfd816cf27f47dc3a410844e3da943a565e2372b706c6c1500c999cbc482165fea769b174a66e2e111824e28f57dfb8d6a6bbb
SHA512
521058fec2e8e998c94b348260500ee36dfbbd571eb557f3430f3557a314ac7e7fe4f3e68f3a6980e17a232328ce1989de37629134023ac6bdacd83151958d39
diff --git a/dev-python/hishel/hishel-1.0.0.ebuild
b/dev-python/hishel/hishel-1.0.0.ebuild
new file mode 100644
index 000000000000..e93e371f4a64
--- /dev/null
+++ b/dev-python/hishel/hishel-1.0.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="An elegant HTTP Cache implementation for HTTPX and HTTP Core"
+HOMEPAGE="
+ https://github.com/karpetrosyan/hishel/
+ https://pypi.org/project/hishel/
+"
+SRC_URI="
+ https://github.com/karpetrosyan/${PN}/archive/refs/tags/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+ >=dev-python/anyio-4.9.0[${PYTHON_USEDEP}]
+ >=dev-python/anysqlite-0.0.5[${PYTHON_USEDEP}]
+ >=dev-python/httpx-0.28.1[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-1.1.2[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-1.14.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ ${RDEPEND}
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ dev-db/redis
+ >=dev-python/boto3-1.15.3[${PYTHON_USEDEP}]
+ >=dev-python/inline-snapshot-0.28.0[${PYTHON_USEDEP}]
+ >=dev-python/redis-6.2.0[${PYTHON_USEDEP}]
+ >=dev-python/time-machine-2.19.0[${PYTHON_USEDEP}]
+ >=dev-python/trio-0.30.0[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=( anyio )
+distutils_enable_tests pytest
+
+src_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/test_async_httpx.py
+ tests/test_requests.py
+ tests/test_sync_httpx.py
+ )
+
+ local redis_pid="${T}"/redis.pid
+ local redis_port=6379
+
+ einfo "Starting Redis"
+ "${EPREFIX}"/usr/sbin/redis-server - <<- EOF
+ daemonize yes
+ pidfile ${redis_pid}
+ port ${redis_port}
+ bind 127.0.0.1 ::1
+ EOF
+
+ # Run the tests
+ distutils-r1_src_test
+
+ # Clean up afterwards
+ kill "$(<"${redis_pid}")" || die
+}
