commit: c6835734b6d8a649d57eb49b652f2fa8ea3092dc
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 26 03:51:55 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 26 03:51:55 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c6835734
dev-python/pikepdf: Bump to 10.0.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pikepdf/Manifest | 1 +
dev-python/pikepdf/pikepdf-10.0.0.ebuild | 59 ++++++++++++++++++++++++++++++++
2 files changed, 60 insertions(+)
diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index e69377a74d05..39925da727c6 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1,3 +1,4 @@
+DIST pikepdf-10.0.0.tar.gz 4547153 BLAKE2B
1aec2fcb6ac6a68277f434e792484cf817b42bbb966bf0cbb7f9254e91cf2ff84da280e83fffd6d00dcb071f6473c5fb805c75a5cc3f7c5b9ef247c50237b70c
SHA512
94460851b8557b828545799e0571d965ac8f1da761113bea2671b4bb60a9d296f710c8c936c1547826f2e647ba7c3cd3efad17f844363ab5ba2e36975e838210
DIST pikepdf-9.10.1.tar.gz 4545682 BLAKE2B
164647ec13bbba5685c5965a68ff8530f66b7c015dba7394f84b32963fae318aa9c9f1b99733b5c5052e3b90fe52c4470bd92e829a8cfb0e5d12588cc996df0c
SHA512
bfe95eb94b2738769bf1af537d853d7c8396f5d1ff3c155f9958a4646eed35fa98118c50febd8002863feac5075645fa2eb6fcd5be3b726d5f185833d28c5cf3
DIST pikepdf-9.10.2.tar.gz 4545737 BLAKE2B
3ac3c0c39a849b1d4c62f4435bef87cd8cb5b09c3e5cd9f1598cc0c1e1611fc0db0b80e7818c98505c021c61fdfc6ef2d9b6a901b6f4f730efe13a8c6fe37dd7
SHA512
3dc41d4f547cf68f6d05cefbef74f5e18b25a9f5900d2b5352aea50eda253a4c01ac4e1f69384a924d9ff5b042ed7c93ce7d5424e476dd3e8b8b52daeef15229
DIST pikepdf-9.11.0.tar.gz 4546289 BLAKE2B
267a8f834cf9da21a5d8f4b5e4734eaaaa9889f9ae919e6c9f030ffda3a36e951f3a8aedecc8168234264ffd5792ca1eefc2e1833ec8a6b540b0978a5638e8e4
SHA512
b92c1aa285935faccf8f1058aff25bf1ba906d8e6e4cca986f6fed59c2faf9cb9f1c5a3aeebd2899dac7fbe2489af627c76a751963657aa476c16eb1374b34ad
diff --git a/dev-python/pikepdf/pikepdf-10.0.0.ebuild
b/dev-python/pikepdf/pikepdf-10.0.0.ebuild
new file mode 100644
index 000000000000..134964a46f7d
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-10.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+ https://github.com/pikepdf/pikepdf/
+ https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390
~sparc ~x86"
+IUSE="big-endian"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+ >=app-text/qpdf-11.5.0:0=
+"
+RDEPEND="
+ ${DEPEND}
+ dev-python/deprecated[${PYTHON_USEDEP}]
+ >=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ >=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/pybind11-3[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-77.0.3[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+ test? (
+ >=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+ >=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+ >=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+ !big-endian? (
+ >=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+ )
+ media-libs/tiff[zlib]
+ )
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-timeout )
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ sed -e '/-n auto/d' -i pyproject.toml || die
+}
