commit: afe2e60f665b911af2e8210295272b7ecfb1dd13
Author: Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 14 13:14:28 2025 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Aug 14 13:16:36 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=afe2e60f
gnome-base/gnome-settings-daemon: add 48.1
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>
gnome-base/gnome-settings-daemon/Manifest | 1 +
.../gnome-settings-daemon-48.1.ebuild | 144 +++++++++++++++++++++
2 files changed, 145 insertions(+)
diff --git a/gnome-base/gnome-settings-daemon/Manifest
b/gnome-base/gnome-settings-daemon/Manifest
index 61423aab423c..3bedb3e8ede9 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -1,2 +1,3 @@
DIST gnome-settings-daemon-46.0.tar.xz 1480952 BLAKE2B
42f2eb46b255e3e44a045b90b7ad98e15836aa3780f04740861c65417dd58e79996481d397f3f482158286c905245ca13dec0ad52770972856ecfd939d06073a
SHA512
445e9ee4709af7a67ded55733d4041357995fe9746bcf00fa81f52f6dddc2071e7114e9bf836bcf464bc0f04da3b3c08be04c1942963c1910d1a14b4434f6633
DIST gnome-settings-daemon-47.2.tar.xz 1480428 BLAKE2B
e2f1a2e75aa85a354bdc623c75b4dd995c85b102fa8ca114733290316533b11fc9f99bf13b1921fc745d892ce7a00d5b45a81160a889dbc061ca81bd50bef21f
SHA512
fd3e358aa1f6a317dc49436965135dde204bd55fee9c96127d1208aafb60af3667fcc344a1667be1596892987f67ebab3fc7eefaeeefce82e1c65635e36c126f
+DIST gnome-settings-daemon-48.1.tar.xz 1498444 BLAKE2B
e181be3af654cda9739fcb9cc388098ed001da8aa6d0f55357d8839c48db40c9b4c5056bfa44e2df9870941d992bca2c5dd8e3617ffb0ef33ede208067063311
SHA512
b4ce4fe5a2a6b9dcdc3a82f4460488b39adcb56e7345079d9558506146202d234562cfaa522b77d1eb0d468121a5aed5cec42983a78abc2fe0946dd78dc2bc40
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-48.1.ebuild
b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-48.1.ebuild
new file mode 100644
index 000000000000..91e217a3c2b6
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-48.1.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon";
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86
~amd64-linux ~x86-linux"
+
+IUSE="+colord +cups debug elogind input_devices_wacom modemmanager
networkmanager smartcard systemd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="^^ ( elogind systemd )"
+
+COMMON_DEPEND="
+ >=sci-geosciences/geocode-glib-3.10:2
+ >=dev-libs/glib-2.70:2
+ >=gnome-base/gnome-desktop-3.37.1:3=
+ >=gnome-base/gsettings-desktop-schemas-46.0
+ >=x11-libs/gtk+-3.15.3:3[X,wayland?]
+ >=dev-libs/libgweather-4.2.0:4=
+ colord? ( >=x11-misc/colord-1.4.5:= )
+ || (
+ media-libs/libcanberra-gtk3
+ >=media-libs/libcanberra-0.25[gtk3(-)]
+ )
+ >=app-misc/geoclue-2.3.1:2.0
+ >=x11-libs/libnotify-0.7.3
+ >=media-libs/libpulse-16.1[glib]
+ >=sys-auth/polkit-0.114
+ >=sys-power/upower-0.99.12:=
+ x11-libs/libX11
+ >=x11-libs/libXfixes-6.0.0
+ dev-libs/libgudev:=
+ wayland? ( dev-libs/wayland )
+ input_devices_wacom? (
+ >=dev-libs/libwacom-0.7:=
+ >=x11-libs/pango-1.20.0
+ x11-libs/gdk-pixbuf:2
+ )
+ smartcard? ( app-crypt/gcr:4= )
+ cups? ( >=net-print/cups-1.4[dbus] )
+ modemmanager? (
+ >=app-crypt/gcr-3.90.0:4=
+ >=net-misc/modemmanager-1.18:=
+ )
+ networkmanager? ( >=net-misc/networkmanager-1.0 )
+ media-libs/alsa-lib
+ x11-libs/libXi
+ x11-libs/libXext
+ media-libs/fontconfig
+ elogind? ( >=sys-auth/elogind-209 )
+ systemd? ( >=sys-apps/systemd-243 )
+"
+DEPEND="${COMMON_DEPEND}
+ x11-base/xorg-proto
+"
+# logind needed for power and session management, bug #464944
+RDEPEND="${COMMON_DEPEND}
+ gnome-base/dconf
+"
+# rfkill requires linux/rfkill.h, thus linux-headers dep, not os-headers.
+# If this package wants to work on other kernels, we need to make rfkill
conditional instead
+BDEPEND="
+ sys-kernel/linux-headers
+ dev-util/glib-utils
+ dev-util/gdbus-codegen
+ ${PYTHON_DEPS}
+ test? (
+ dev-util/umockdev
+ $(python_gen_any_dep '
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/python-dbusmock[${PYTHON_USEDEP}]
+ ')
+ gnome-base/gnome-session
+ )
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+PATCHES=(
+
"${FILESDIR}"/42.1-build-Make-wacom-optional-and-controllable-via-meson.patch
+ "${FILESDIR}"/${PN}-3.38.1-build-Allow-NM-optional-on-Linux.patch
+)
+
+python_check_deps() {
+ if use test; then
+ python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+ python_has_version
"dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+ fi
+}
+
+pkg_setup() {
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dudev_dir="$(get_udevdir)"
+ $(meson_use systemd)
+ $(meson_use elogind)
+ -Dalsa=true
+ -Dgudev=true
+ -Dgcr3=false
+ $(meson_use colord)
+ $(meson_use cups)
+ $(meson_use networkmanager network_manager)
+ -Drfkill=true
+ $(meson_use smartcard)
+ $(meson_use input_devices_wacom wacom)
+ $(meson_use wayland)
+ $(meson_use modemmanager wwan)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ # Don't auto-suspend by default on AC power
+ insinto /usr/share/glib-2.0/schemas
+ doins
"${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override
+}
+
+src_test() {
+ virtx meson_src_test
+}
+
+pkg_postinst() {
+ udev_reload
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ udev_reload
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
