[gentoo-commits] repo/gentoo:master commit in: sys-apps/gentoo-functions/

[Sam James]

commit:     339e5b31efd923cde32a58d972e29191fbd0ebe7
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  8 05:32:02 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Aug  8 05:32:02 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=339e5b31

sys-apps/gentoo-functions: add 1.7.4

Kerin Millar (6):
      Update a comment in esyslog() in view of POSIX-1.2024
      Simplify the detection of SRANDOM in bash
      Simplify the detection of posixlycorrect mode in yash
      Employ just one test for set -e and -u
      Don't complain about $- for incompatible shells
      Correct a comment typo in srandom()

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-apps/gentoo-functions/Manifest                 |  1 +
 .../gentoo-functions/gentoo-functions-1.7.4.ebuild | 49 ++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/sys-apps/gentoo-functions/Manifest 
b/sys-apps/gentoo-functions/Manifest
index 83e1f52d0011..55fca5596573 100644
--- a/sys-apps/gentoo-functions/Manifest
+++ b/sys-apps/gentoo-functions/Manifest
@@ -1,2 +1,3 @@
 DIST gentoo-functions-0.19.tar.bz2 12079 BLAKE2B 
be0a3a54d4dee1755866047b670a69cd6fec368239123c3f0c08180b79a33c20147bca0e35e568faef6877513551e731bdf0c181aeb0460f6574d2d708219373
 SHA512 
2674d3fe5724cc6d685ae58bf0ee33f4a1bdba2c5e5809cfb193fd0a710d4678c2d9392c2c62d2321cf455f524950266dc1629ab684fe46632d179e539d5a39e
 DIST gentoo-functions-1.7.3.tar.bz2 29623 BLAKE2B 
e37fcaf7ca70eda4507f8b539ad37c989a3a6d28d2a063aa1650f60f8cbb28b00103ffea0f1221fd4e8379d4066bca1fd5aeee30073eed6274cfaaaa277bee84
 SHA512 
4c5d5c9e8b93e366c5483e8777dfdc15afc6764110cc69f751bb5cc1e335dd70e0952017ea55f1be70fcd5120f07708b1601638c97132f53acde8b3f5a4afe34
+DIST gentoo-functions-1.7.4.tar.bz2 29565 BLAKE2B 
dd05aaee9c078ef6b623950c120b7e9aa7056a1e02248a098a9b33e69109fa5a642221a2209a55570590e8101f4ec82e727602dce543977670dd7d49f789429e
 SHA512 
184809eb684465639bc2d404c421e33153ffcac3fe985123e5f5815863c427c9e4f6155713a2c0b69006a4afbefc114211f4a4216f49e726a198938d43fcd395

diff --git a/sys-apps/gentoo-functions/gentoo-functions-1.7.4.ebuild 
b/sys-apps/gentoo-functions/gentoo-functions-1.7.4.ebuild
new file mode 100644
index 000000000000..6517d7f22a6e
--- /dev/null
+++ b/sys-apps/gentoo-functions/gentoo-functions-1.7.4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2014-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Base functions required by all Gentoo systems"
+HOMEPAGE="https://gitweb.gentoo.org/proj/gentoo-functions.git";
+
+if [[ ${PV} == 9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gentoo-functions.git";
+else
+       
SRC_URI="https://gitweb.gentoo.org/proj/gentoo-functions.git/snapshot/${P}.tar.bz2";
+       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc 
~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos 
~x64-macos ~x64-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+src_configure() {
+       local emesonargs=(
+               # Deliberately avoid /usr as consumers assume we're at 
/lib/gentoo.
+               --prefix="${EPREFIX:-/}"
+               --mandir="${EPREFIX}/usr/share/man"
+               $(meson_use test tests)
+       )
+
+       meson_src_configure
+}
+
+src_install() {
+       meson_src_install
+
+       if [[ ${EPREFIX} ]]; then
+               while read -r; do
+                       if [[ ${REPLY} == $'\t'genfun_prefix= ]]; then
+                               printf '\tgenfun_prefix=%q\n' "${EPREFIX}"
+                       else
+                               printf '%s\n' "${REPLY}"
+                       fi || ! break
+               done < "${ED}/lib/gentoo/functions.sh" > "${T}/functions.sh" \
+               && mv -- "${T}/functions.sh" "${ED}/lib/gentoo/functions.sh" \
+               || die
+       fi
+}