commit: 532b1e45356a14fa2a766b0db8ee7efcdcc25a15
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 5 04:09:15 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul 5 04:44:27 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=532b1e45
dev-python/hypothesis: Bump to 6.135.25
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hypothesis/Manifest | 1 +
dev-python/hypothesis/hypothesis-6.135.25.ebuild | 124 +++++++++++++++++++++++
2 files changed, 125 insertions(+)
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index dbafe0af03ae..dde49ccabe1d 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -3,4 +3,5 @@ DIST hypothesis-6.135.16.gh.tar.gz 9580500 BLAKE2B
de250a17a6929aaef171f85277a69
DIST hypothesis-6.135.20.gh.tar.gz 9589950 BLAKE2B
ad3e94e1dc35c9cca9693e3f06e68e0c12ddfed3f5c4d3eac98ef4197d2e3b8ae9c4d19615735189be24811d3c19a13ce77f469605616e03d3ca46738c084548
SHA512
0ef179049c18499f908b63e638c6daaaab8aa42ba54ce0f024d5c1997a14c4e6d95c0cf3930d6d1c52f527885bf2ccb74d346b3032698bb1ab8d0ef880275841
DIST hypothesis-6.135.23.gh.tar.gz 9590903 BLAKE2B
5da2895abeb9cfd2edbdfc4b67e0a9ae30ba0424f4f2f3ae46fa750b6a250b1a74f4525ee8c6e0701b76d1261ea6146674eeec1728c1c5fa8ce1babd3f7989d0
SHA512
bcbe588d076384d0a08ca28d34a3f77137a0ee4f32bab4316b2a4824096d2467dd792e35375403391b3ed455a0a791fe7126c2286b20d29a6008c86e97676019
DIST hypothesis-6.135.24.gh.tar.gz 9591935 BLAKE2B
54f112d9922c21a3541545f23a78bf26d035a522e5b206303e372d7032e6015a4c9ec0ddeb1d22af0e572bdd4842e1f3e26ecba8dd49f36d16a0705cd429994e
SHA512
9ed29e9b7bcaef08949e6f4c531342aee52c13288b155795f6168b572d4d20d749725d016441f4168f437bb8c76799282e1a19625841524dc95bd3391cd3992d
+DIST hypothesis-6.135.25.gh.tar.gz 9592222 BLAKE2B
42538cd2fa63968ea75cc42dfa92f998d50fb92e77726c8eee42e10c94ec69ea5a682e070e3c04bfe49b229cbf03e26d4ab04ac7dabe2c34f81e217ad8491f90
SHA512
bb245d38ac9f2b0aced7890cb6c7cba4ce4b98ccb8f843afe02094a63058aad63f6c7c4ad2dcaa4af753f5823544d394875049a0b56ea2d98f84db39351a7668
DIST hypothesis-6.135.9.gh.tar.gz 9578130 BLAKE2B
fc0619685edd2c06d77d95ee0bb7244f62b0b262621e399e3ff7a1ef13a36c80f6d60c8b333011e9387bf04095f40519b072f1b69407e5b0a83c46d2fd7acc40
SHA512
bc69855f5d68bfd68a4915d2085505d815159d5b0757104f7634cdd3db2a2e9c5a7e8c68826864aeb15aae5b16bdb99cbafdab3e443349c3edfa86c964110bce
diff --git a/dev-python/hypothesis/hypothesis-6.135.25.ebuild
b/dev-python/hypothesis/hypothesis-6.135.25.ebuild
new file mode 100644
index 000000000000..083419e344e9
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.135.25.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" pypy3_11 python3_14 python3_{13,14}t )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+ https://github.com/HypothesisWorks/hypothesis/
+ https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+ https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ >=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+ cli? (
+ $(python_gen_cond_dep '
+ dev-python/black[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ ' "${CLI_COMPAT[@]}")
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ >=dev-python/pytest-8[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=( pytest-rerunfailures )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ # NB: paths need to be relative to pytest.ini,
+ # i.e. start with hypothesis-python/
+ local EPYTEST_DESELECT=()
+ case ${EPYTHON} in
+ python3.13t)
+ EPYTEST_DESELECT+=(
+ # TODO: missing warning
+
'hypothesis-python/tests/cover/test_random_module.py::test_passing_referenced_instance_within_function_scope_warns'
+ )
+ ;;
+ python3.14*)
+ EPYTEST_DESELECT+=(
+
'hypothesis-python/tests/cover/test_compat.py::test_resolve_fwd_refs[Foo-Union]'
+
'hypothesis-python/tests/cover/test_lookup.py::test_builds_suggests_from_type[Union]'
+
hypothesis-python/tests/cover/test_attrs_inference.py::test_attrs_inference_builds
+
hypothesis-python/tests/cover/test_lookup.py::test_bytestring_not_treated_as_generic_sequence
+
hypothesis-python/tests/cover/test_lookup.py::test_issue_4194_regression
+
hypothesis-python/tests/cover/test_lookup.py::test_resolves_forwardrefs_to_builtin_types
+
hypothesis-python/tests/cover/test_lookup.py::test_specialised_collection_types
+
hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_collection_as_generic
+
hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_container_as_generic
+
hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_contextmanager_as_generic
+
hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_iterable_as_generic
+
hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_reversible_as_generic
+
hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_sequence_as_generic
+
hypothesis-python/tests/cover/test_random_module.py::test_evil_prng_registration_nonsense
+
hypothesis-python/tests/cover/test_random_module.py::test_passing_referenced_instance_within_function_scope_warns
+
hypothesis-python/tests/cover/test_random_module.py::test_register_random_within_nested_function_scope
+
hypothesis-python/tests/cover/test_random_module.py::test_registering_a_Random_is_idempotent
+
hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_missing_dot_access_forward_ref
+
hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_missing_forward_ref
+
hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_type_checking_only_forward_ref_wrong_type
+
hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_type_cheking_only_forward_ref
+ )
+ ;;
+ esac
+
+ # subtests are broken by warnings from random plugins
+ local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+ local -x HYPOTHESIS_NO_PLUGINS=1
+
+ epytest -o filterwarnings= --reruns=5 \
+ tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+ local HAD_CLI=
+
+ distutils-r1_src_install
+
+ if [[ ! ${HAD_CLI} ]]; then
+ rm -r "${ED}/usr/bin" || die
+ fi
+}
+
+python_install() {
+ distutils-r1_python_install
+ if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+ HAD_CLI=1
+ else
+ rm -r "${D}$(python_get_scriptdir)" || die
+ fi
+}
+
+pkg_postinst() {
+ optfeature "datetime support" dev-python/pytz
+ optfeature "dateutil support" dev-python/python-dateutil
+ optfeature "numpy support" dev-python/numpy
+ optfeature "django support" dev-python/django dev-python/pytz
+ optfeature "pandas support" dev-python/pandas
+ optfeature "pytest support" dev-python/pytest
+}
