[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-backend/

[Michał Górny]

commit:     28cd82301f67719fead862381827bf4ffd71d8d4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  4 11:10:48 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jul  4 12:36:18 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28cd8230

dev-python/pdm-backend: Bump to 2.4.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-backend/Manifest                 |  1 +
 dev-python/pdm-backend/pdm-backend-2.4.5.ebuild | 75 +++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index fa267cd02e33..041d3b846dae 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.4.4.gh.tar.gz 157998 BLAKE2B 
936289f56709633eb4d78b851b903e0f436f01d9949f96463fbad4448cb1688d8bad61a8a00e63524abf74f696830bb8227b428f78a050a2e3396545611119d3
 SHA512 
b8d6983d2df1028d30c046c9952e6182aed0b099e6d0d0b4cc784179cb3e4c9f518b58a6fe5c7a2d15b150dc134b7dc8c427ea142620e8bb29dd05be1a7efe1a
+DIST pdm-backend-2.4.5.gh.tar.gz 158378 BLAKE2B 
1ff5e5dcee276d7cd68a18f6d5679c1d794479c596b14fbf90d1edd5e28d5478802a4a9961967b0a2e5b0fed8f0851d6915e703a776995982bff3aaba95d236f
 SHA512 
0c106eb9de8ef1bd94cb772d30a420551d0efaa2f96482882e5ab87a1b866988a0e979f93da3295f89de0f6446a506dcdc3781e8bb6e49962127a7d7ec87191c

diff --git a/dev-python/pdm-backend/pdm-backend-2.4.5.ebuild 
b/dev-python/pdm-backend/pdm-backend-2.4.5.ebuild
new file mode 100644
index 000000000000..53e42067cb9c
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.4.5.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{11..14} python3_{13,14}t pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+       https://pypi.org/project/pdm-backend/
+       https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+       https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+       >=dev-python/editables-0.5[${PYTHON_USEDEP}]
+       >=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+       >=dev-python/pyproject-metadata-0.9.0_beta7[${PYTHON_USEDEP}]
+       >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+       $(python_gen_cond_dep '
+               >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+       ' 3.10)
+"
+BDEPEND="
+       ${RDEPEND}
+       test? (
+               dev-python/setuptools[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+       rm -r src/pdm/backend/_vendor || die
+       find -name '*.py' -exec sed \
+               -e 's:from pdm\.backend\._vendor\.:from :' \
+               -e 's:from pdm\.backend\._vendor ::' \
+               -e 's:import pdm\.backend\._vendor\.:import :' \
+               -i {} + || die
+       distutils-r1_src_prepare
+}
+
+src_compile() {
+       # this must not be set during src_test()
+       local -x PDM_BUILD_SCM_VERSION=${PV}
+       distutils-r1_src_compile
+}
+
+src_test() {
+       git config --global user.email "t...@example.com" || die
+       git config --global user.name "Test User" || die
+       distutils-r1_src_test
+}
+
+python_test() {
+       epytest -k "not [hg"
+}