commit: 451ed1a3871127d14f112c017c36f40c6aea3caf
Author: Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 21 21:30:26 2025 +0000
Commit: Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Sat Jun 21 21:34:46 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=451ed1a3
media-gfx/engauge: add 9999
Signed-off-by: Andreas K. Hüttel <dilfridge <AT> gentoo.org>
media-gfx/engauge/engauge-9999.ebuild | 86 +++++++++++++++++++++++++++++++++++
media-gfx/engauge/metadata.xml | 2 +-
2 files changed, 87 insertions(+), 1 deletion(-)
diff --git a/media-gfx/engauge/engauge-9999.ebuild
b/media-gfx/engauge/engauge-9999.ebuild
new file mode 100644
index 000000000000..25a00da40c8d
--- /dev/null
+++ b/media-gfx/engauge/engauge-9999.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+[[ ${PV} == 9999 ]] && inherit git-r3
+inherit desktop qmake-utils xdg
+
+DESCRIPTION="Convert an image file showing a graph or map into numbers"
+HOMEPAGE="https://akhuettel.github.io/engauge-digitizer/";
+
+if [[ ${PV} == 9999 ]]; then
+ EGIT_REPO_URI="https://github.com/akhuettel/engauge-digitizer";
+ S=${WORKDIR}/engauge-${PV}
+else
+
SRC_URI="https://github.com/akhuettel/engauge-digitizer/archive/v${PV}.tar.gz
-> engauge-digitizer-${PV}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+ S=${WORKDIR}/engauge-digitizer-${PV}
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc examples jpeg2k pdf"
+
+RDEPEND="
+ dev-qt/qtbase:6[gui,network,widgets,xml]
+ dev-qt/qttools:6[assistant]
+ dev-libs/log4cpp
+ media-libs/libjpeg-turbo:0=
+ media-libs/libpng:0=
+ sci-libs/fftw:3.0
+ jpeg2k? ( media-libs/openjpeg:2 )
+ pdf? ( app-text/poppler[qt6] )"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/qttools:6[assistant]"
+
+src_prepare() {
+ xdg_environment_reset
+ default
+
+ # Make sure the documentation is looked for in the proper directory
+ sed -e "s:engauge-digitizer/engauge.qhc:${PF}/engauge.qhc:" \
+ -i src/Help/HelpWindow.cpp || die
+
+ # This otherwise overrides user CFLAGS
+ sed -e '/QMAKE_CXXFLAGS_WARN_ON/s/-O1//' \
+ -i engauge.pro || die
+
+ # Neuter the non-pkg-config hackery
+ sed -e '/error.*OPENJPEG_/d' \
+ -e '/LIBS.*OPENJPEG_LIB/d' \
+ -e '/QMAKE_POST_LINK.*OPENJPEG_LIB/d' \
+ -e '/error.*POPPLER_/d' \
+ -e '/LIBS.*POPPLER_LIB/d' \
+ -i engauge.pro || die
+}
+
+src_configure() {
+ eqmake6 \
+ CONFIG+=link_pkgconfig \
+ $(usex jpeg2k "CONFIG+=jpeg2000 PKGCONFIG+=libopenjp2" "") \
+ $(usex pdf "CONFIG+=pdf PKGCONFIG+=poppler-qt6" "") \
+ engauge.pro
+ pushd help >/dev/null || die
+ $(qt6_get_libdir)/qt6/libexec/qhelpgenerator engauge.qhp || die
+ popd >/dev/null || die
+}
+
+src_install() {
+ dobin bin/Engauge
+ doicon src/img/engauge-digitizer.svg
+ make_desktop_entry Engauge "Engauge Digitizer" engauge-digitizer
Graphics
+
+ # Install qt help files
+ dodoc help/engauge.qch
+ docompress -x "${EPREFIX}"/usr/share/doc/${PF}/engauge.qch
+
+ use doc && dodoc -r doc/.
+ if use examples; then
+ dodoc -r samples
+ docompress -x "${EPREFIX}"/usr/share/doc/${PF}/samples
+ fi
+
+ insinto /usr/bin
+ dosym Engauge engauge
+}
diff --git a/media-gfx/engauge/metadata.xml b/media-gfx/engauge/metadata.xml
index 6707022e4a19..0767331791c0 100644
--- a/media-gfx/engauge/metadata.xml
+++ b/media-gfx/engauge/metadata.xml
@@ -6,6 +6,6 @@
<name>Andreas K. Huettel</name>
</maintainer>
<upstream>
- <remote-id type="sourceforge">digitizer</remote-id>
+ <remote-id type="github">akhuettel/engauge-digitizer</remote-id>
</upstream>
</pkgmetadata>
