[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-nm/

[Andreas Sturmlechner]

commit:     95cd041728b7816c6ba580bfdb2b23ab4c90ee2d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 12 21:01:18 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Jun 12 21:44:17 2025 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=95cd0417

kde-plasma/plasma-nm: 6.4.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-nm/plasma-nm-6.4.0.ebuild | 76 +++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/kde-plasma/plasma-nm/plasma-nm-6.4.0.ebuild 
b/kde-plasma/plasma-nm/plasma-nm-6.4.0.ebuild
new file mode 100644
index 0000000000..03646a13d1
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-6.4.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.14.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="openconnect teamd"
+
+DEPEND="
+       >=app-crypt/qca-2.3.7:2[qt6(+)]
+       dev-libs/qcoro[dbus]
+       >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+       >=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+       >=kde-frameworks/kcolorscheme-${KFMIN}:6
+       >=kde-frameworks/kcompletion-${KFMIN}:6
+       >=kde-frameworks/kconfig-${KFMIN}:6
+       >=kde-frameworks/kcoreaddons-${KFMIN}:6
+       >=kde-frameworks/kdbusaddons-${KFMIN}:6
+       >=kde-frameworks/ki18n-${KFMIN}:6
+       >=kde-frameworks/kio-${KFMIN}:6
+       >=kde-frameworks/kitemviews-${KFMIN}:6
+       >=kde-frameworks/knotifications-${KFMIN}:6
+       >=kde-frameworks/kservice-${KFMIN}:6
+       >=kde-frameworks/ksvg-${KFMIN}:6
+       >=kde-frameworks/kwallet-${KFMIN}:6
+       >=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+       >=kde-frameworks/kwindowsystem-${KFMIN}:6
+       >=kde-frameworks/kxmlgui-${KFMIN}:6
+       >=kde-frameworks/modemmanager-qt-${KFMIN}:6
+       >=kde-frameworks/networkmanager-qt-${KFMIN}:6[teamd=]
+       >=kde-frameworks/solid-${KFMIN}:6
+       >=kde-plasma/libplasma-${KDE_CATV}:6
+       net-misc/mobile-broadband-provider-info
+       net-misc/networkmanager[teamd=]
+       openconnect? (
+               >=dev-qt/qtwebengine-${QTMIN}:6
+               net-vpn/networkmanager-openconnect
+               net-vpn/openconnect:=
+       )
+"
+RDEPEND="${DEPEND}
+       >=kde-frameworks/kdeclarative-${KFMIN}:6
+       >=kde-frameworks/kirigami-${KFMIN}:6
+       >=kde-frameworks/kquickcharts-${KFMIN}:6
+"
+BDEPEND="
+       >=kde-frameworks/kcmutils-${KFMIN}:6
+       virtual/pkgconfig
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_OPENCONNECT=$(usex openconnect)
+       )
+
+       ecm_src_configure
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+
+       if ! has_version "kde-frameworks/kcmutils:6"; then
+               elog "${PN} is not terribly useful without 
kde-frameworks/kcmutils:6."
+               elog "However, the networkmanagement KCM can be called from 
either systemsettings"
+               elog "or manually: $ kcmshell6 kcm_networkmanagement"
+       fi
+}