[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtpositioning/

[Ionen Wolkens]

commit:     4e6718ddca35ad60e0676e7b440351e0eaf79ab7
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Sat Jun  7 09:02:59 2025 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sat Jun  7 12:01:18 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4e6718dd

dev-qt/qtpositioning: add 6.10.9999

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 .../qtpositioning/qtpositioning-6.10.9999.ebuild   | 68 ++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/dev-qt/qtpositioning/qtpositioning-6.10.9999.ebuild 
b/dev-qt/qtpositioning/qtpositioning-6.10.9999.ebuild
new file mode 100644
index 000000000000..dbfd92016370
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-6.10.9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Physical position determination library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+       KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="geoclue nmea +qml"
+
+DEPEND="
+       ~dev-qt/qtbase-${PV}:6
+       geoclue? ( ~dev-qt/qtbase-${PV}:6[dbus] )
+       nmea? (
+               ~dev-qt/qtbase-${PV}:6[network]
+               ~dev-qt/qtserialport-${PV}:6
+       )
+       qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
+"
+RDEPEND="
+       ${DEPEND}
+       geoclue? ( app-misc/geoclue:2.0 )
+"
+
+CMAKE_SKIP_TESTS=(
+       # threads test (rarely) fails randomly
+       tst_qgeoareamonitor
+)
+
+src_prepare() {
+       qt6-build_src_prepare
+
+       # unfortunately cmake_use_find_package would break things with qtbase
+       use geoclue ||
+               sed -e 's/TARGET Qt::DBus/FALSE/' \
+                       -i src/plugins/position/CMakeLists.txt || die
+       use nmea ||
+               sed -e 's/TARGET Qt::Network/FALSE/' \
+                       -i src/plugins/position/CMakeLists.txt || die
+}
+
+src_configure() {
+       local mycmakeargs=(
+               $(cmake_use_find_package qml Qt6Qml)
+       )
+
+       qt6-build_src_configure
+}
+
+src_install() {
+       qt6-build_src_install
+
+       if use test; then
+               local delete=( # sigh
+                       
"${D}${QT6_LIBDIR}"/cmake/Qt6Positioning/*DummyPlugin*.cmake
+                       
"${D}${QT6_LIBDIR}"/cmake/Qt6Positioning/*TestPlugin*.cmake
+                       
"${D}${QT6_PLUGINDIR}"/position/libqtposition_satellitesourcetest.so
+                       
"${D}${QT6_PLUGINDIR}"/position/libqtposition_testplugin{,2}.so
+               )
+               # using -f given not tracking which tests may be skipped or not
+               rm -f -- "${delete[@]}" || die
+       fi
+}