commit: 9b53cbf2967654e7b24167106a92708bcbabb819
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 2 03:58:45 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jun 2 04:06:55 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9b53cbf2
dev-python/kombu: Bump to 5.5.4
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/kombu/Manifest | 1 +
dev-python/kombu/kombu-5.5.4.ebuild | 97 +++++++++++++++++++++++++++++++++++++
2 files changed, 98 insertions(+)
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 8e6734586553..0360416e1c57 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
DIST kombu-5.5.3.tar.gz 461784 BLAKE2B
92943d69c61e7920018709f40c2d2656bfcd96ca36c673aca62e686a2b240c9535f6a5953581d51de20c0e6697473153b94c37ce2d0c146632183ed36eaac8ee
SHA512
0cf17dec475b30cf30169f39d4819f205cc437cc5880de254c19bbf65b9320453ab244187f5b83715ef7e4b1861985097d4d1614c040b9268a018afef5938147
+DIST kombu-5.5.4.tar.gz 461992 BLAKE2B
7c81ddd2c151b7abd984c2523e7855785796db23de5c1a43348870019de26079fb9b6475a5174ceea6ca461188cff4a8fe4da76d95345ac611a13d29c3a9848f
SHA512
f3227303aa7ad1a4bd480c601f99f7b4ae2db6d3790defd02b4a9e4ccd6875630a9e6582f65f334a04a5111c456c489395fc4af5b2dd4a557e6aa47616859668
diff --git a/dev-python/kombu/kombu-5.5.4.ebuild
b/dev-python/kombu/kombu-5.5.4.ebuild
new file mode 100644
index 000000000000..8a6ac04effc7
--- /dev/null
+++ b/dev-python/kombu/kombu-5.5.4.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+ https://github.com/celery/kombu/
+ https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+ <dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ >=dev-python/tzdata-2025.2[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ >=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+ dev-python/pycurl[${PYTHON_USEDEP}]
+ >=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+ dev-python/pytest-freezer[${PYTHON_USEDEP}]
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+ dev-python/sphinx-celery
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin deps (notably tzdata, sigh)
+ > requirements/default.txt || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+
t/unit/transport/test_redis.py::test_Channel::test_global_keyprefix_transaction
+ # bad filename assumption?
+
t/unit/asynchronous/aws/test_connection.py::test_AsyncHTTPSConnection::test_request_with_cert_path_https
+ )
+ local EPYTEST_IGNORE=(
+ # obsolete Pyro4
+ t/unit/transport/test_pyro.py
+ # unpackaged azure
+ t/unit/transport/test_azurestoragequeues.py
+ # unpackage google-cloud
+ t/unit/transport/test_gcpubsub.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+ optfeature "Etcd backend" dev-python/python-etcd
+ optfeature "MongoDB backend" dev-python/pymongo
+ optfeature "Redis backend" dev-python/redis
+ optfeature "sqlalchemy backend" dev-python/sqlalchemy
+ optfeature "yaml backend" dev-python/pyyaml
+ optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+ optfeature "brotli compression" "app-arch/brotli[python]"
+ optfeature "zstd compression" dev-python/zstandard
+}
