[gentoo-commits] repo/gentoo:master commit in: sci-libs/libaec/

[Sam James]

commit:     de054f586d0e39f36e93b9e35aeee8b8bc95b43b
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri May 23 05:12:57 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri May 23 05:22:30 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de054f58

sci-libs/libaec: add 1.1.3

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sci-libs/libaec/Manifest            |  1 +
 sci-libs/libaec/libaec-1.1.3.ebuild | 49 +++++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/sci-libs/libaec/Manifest b/sci-libs/libaec/Manifest
index 9aadf362c49e..2b19352d2f00 100644
--- a/sci-libs/libaec/Manifest
+++ b/sci-libs/libaec/Manifest
@@ -1 +1,2 @@
 DIST libaec-1.0.6.tar.gz 2777547 BLAKE2B 
20da3fdf659c9d47ffde442ceaa9f9a831aab70330e27683ed4b62a28fdad02ec9c100413580f04d5a2bbbe86f3fe54b065230393bfb5e7746c522cce71513bc
 SHA512 
f5d118c48225f97b229ac11425b94adff4d3698733bf18767b427e49047f8e08768464bc9cd9f5e6a66ceb44c8ebd9904c4f6f46566e2e66fcaa1049b2ebfcc1
+DIST libaec-1.1.3.tar.gz 2785311 BLAKE2B 
c3add20d7bb861473688972a554d4a3b81593dee55be05319f01bd161753fe84adde576c6868685a6f621a475dfd26d89b42e6579a001487f0b68a1aca8a2208
 SHA512 
6f317d08ad7d003bc6664da147321eb87c924978f32bd28780a8ebf015e251019046b0cb16b78e776cd1957a7701215667f64686efb8e5c6bae7c08528cede56

diff --git a/sci-libs/libaec/libaec-1.1.3.ebuild 
b/sci-libs/libaec/libaec-1.1.3.ebuild
new file mode 100644
index 000000000000..d5737b82f414
--- /dev/null
+++ b/sci-libs/libaec/libaec-1.1.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake dot-a
+
+MY_P="${PN}-v${PV}"
+DESCRIPTION="Adaptive Entropy Coding library"
+HOMEPAGE="https://gitlab.dkrz.de/k202009/libaec";
+SRC_URI="https://gitlab.dkrz.de/k202009/libaec/-/archive/v${PV}/${MY_P}.tar.gz 
-> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD-2"
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="+szip test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="szip? ( !sci-libs/szip )"
+
+src_configure() {
+       lto-guarantee-fat
+
+       local mycmakeargs=(
+               -DBUILD_TESTING=$(usex test)
+               -DCMAKE_INSTALL_LIBDIR=$(get_libdir)
+       )
+
+       cmake_src_configure
+}
+
+src_install() {
+       cmake_src_install
+
+       strip-lto-bytecode
+
+       # avoid conflict with szip (easier than to patch)
+       if ! use szip; then
+               rm "${ED}"/usr/include/szlib.h || die
+               rm "${ED}"/usr/$(get_libdir)/libsz* || die
+               rm "${ED}"/usr/share/doc/${PF}/README.SZIP || die
+       fi
+
+       # Move these cmake files to a proper location
+       dodir "/usr/$(get_libdir)/cmake/${PN}"
+       mv "${ED}/usr/cmake/"* "${ED}/usr/$(get_libdir)/cmake/${PN}" || die
+       rm -r "${ED}/usr/cmake/" || die
+}