commit: 54dde75fdad82eb62f191a5c936660be41e7469b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 20 05:09:42 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Apr 20 05:22:53 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54dde75f
dev-python/pipdeptree: Bump to 2.26.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pipdeptree/Manifest | 1 +
dev-python/pipdeptree/pipdeptree-2.26.1.ebuild | 58 ++++++++++++++++++++++++++
2 files changed, 59 insertions(+)
diff --git a/dev-python/pipdeptree/Manifest b/dev-python/pipdeptree/Manifest
index 0b503ab4127a..a7fcbcd4f365 100644
--- a/dev-python/pipdeptree/Manifest
+++ b/dev-python/pipdeptree/Manifest
@@ -1,2 +1,3 @@
DIST pipdeptree-2.23.4.tar.gz 39945 BLAKE2B
6f1aaf4652b872a28712cf23fb06c26c9e36baf2c5c734b542d418d78081c19f567c730944fba33b43cf6ad612ecd54f37f625a81e88fc8bb68e3e56d76d9088
SHA512
3beeeceb11f842e5f337167b724354b43b01f972f83b0bac5168504483a079e15758206a8e141dc88e4810954630bff1b1cdec3e69aa2f981b9ec2896e40428d
DIST pipdeptree-2.26.0.tar.gz 40786 BLAKE2B
14299501aeff3de4119be0e0b030824750e091159ee88a1f3b0400ef835e66140db69bdefdf37058adaf75bb12b9765b4b70a3bd68056f0152b2eda26dbebb35
SHA512
cacefe7165c37e827592f0364cdf1246d0e7b1bd04c4723ce729c3bd200affae2e2b319bbbd9a8bdc220a43d0dde1a1c197642bc9119148bfcd2664ff11c725c
+DIST pipdeptree-2.26.1.tar.gz 41024 BLAKE2B
93121352931669bb343f156673ebff6cf3f7601da34f027aeaa3764f676a578ed1c5360e1a281c18ce07f870f20f594694cec0da1be8f836568400c9861c0b8a
SHA512
3cb0aa2a3d07a03aa62c0da9ff0d39496e4afe4f9216c2445c36d34b1f05f5bea5030e04d89aa27f5f41cb65092ded4d949a863bc2f223f1fbbe5fdcf379af62
diff --git a/dev-python/pipdeptree/pipdeptree-2.26.1.ebuild
b/dev-python/pipdeptree/pipdeptree-2.26.1.ebuild
new file mode 100644
index 000000000000..317b616d12ca
--- /dev/null
+++ b/dev-python/pipdeptree/pipdeptree-2.26.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="Utility for displaying installed packages in a dependency tree"
+HOMEPAGE="
+ https://github.com/tox-dev/pipdeptree/
+ https://pypi.org/project/pipdeptree/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+ >=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+ >=dev-python/pip-23.1.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/hatch-vcs[${PYTHON_USEDEP}]
+ test? (
+ dev-python/graphviz[${PYTHON_USEDEP}]
+ >=dev-python/pytest-console-scripts-1.4.1[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+ <dev-python/virtualenv-21[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # upstream lower bounds are meaningless
+ sed -i -e 's:>=[0-9.]*,\?::' pyproject.toml || die
+
+ find -name '*.py' -exec \
+ sed -i -e 's:pip[.]_vendor[.]::' {} + || die
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ # tests can fail if other packages are being merged simultaneously
+ epytest -p pytest_mock -p console-scripts -p rerunfailures --reruns=5
+}
+
+pkg_postinst() {
+ optfeature \
+ "visualising the dependency graph with --graph-output" \
+ dev-python/graphviz
+}
