[gentoo-commits] gentoo-x86 commit in games-arcade/berusky: berusky-1.7.1.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    15/03/12 20:32:34

  Modified:             ChangeLog
  Added:                berusky-1.7.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.12                 games-arcade/berusky/ChangeLog

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/berusky/ChangeLog?rev=1.12&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/berusky/ChangeLog?rev=1.12&content-type=text/plain
diff : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/berusky/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/berusky/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog   10 Aug 2014 21:22:03 -0000      1.11
+++ ChangeLog   12 Mar 2015 20:32:34 -0000      1.12
@@ -1,6 +1,12 @@
 # ChangeLog for games-arcade/berusky
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/berusky/ChangeLog,v 1.11 
2014/08/10 21:22:03 slyfox Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/berusky/ChangeLog,v 1.12 
2015/03/12 20:32:34 mr_bones_ Exp $
+
+*berusky-1.7.1 (12 Mar 2015)
+
+  12 Mar 2015; Michael Sterrett <mr_bon...@gentoo.org> +berusky-1.7.1.ebuild,
+  +files/berusky-1.7.1-gentoo.patch:
+  version bump
 
   10 Aug 2014; Sergei Trofimovich <sly...@gentoo.org> berusky-1.4.ebuild:
   QA: drop trailing '.' from DESCRIPTION



1.1                  games-arcade/berusky/berusky-1.7.1.ebuild

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/berusky/berusky-1.7.1.ebuild?rev=1.1&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/berusky/berusky-1.7.1.ebuild?rev=1.1&content-type=text/plain

Index: berusky-1.7.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/berusky/berusky-1.7.1.ebuild,v 
1.1 2015/03/12 20:32:34 mr_bones_ Exp $

EAPI=5
inherit autotools eutils gnome2-utils games

DATAFILE=${PN}-data-1.7
DESCRIPTION="free logic game based on an ancient puzzle named Sokoban"
HOMEPAGE="http://anakreon.cz/?q=node/1";
SRC_URI="http://www.anakreon.cz/download/${P}.tar.gz
        http://www.anakreon.cz/download/${DATAFILE}.tar.gz
        http://dev.gentoo.org/~hasufell/distfiles/${PN}.png";

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="media-libs/libsdl[X,video]
        media-libs/sdl-image[png]
        x11-libs/gtk+:2"
DEPEND="${RDEPEND}
        virtual/pkgconfig"

src_prepare() {
        mv ../${DATAFILE}/{berusky.ini,GameData,Graphics,Levels} . || die
        epatch "${FILESDIR}"/${P}-gentoo.patch
        sed -i \
                -e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
                -e "s:@GENTOO_BINDIR@:${GAMES_BINDIR}:" \
                src/defines.h berusky.ini \
                || die
        sed -i \
                -e "/AC_INIT/s/configure.in/${PN}, ${PV}/" \
                configure.in || die
        mv configure.in configure.ac || die
        eautoreconf
}

src_install() {
        default
        insinto "${GAMES_DATADIR}"/${PN}
        doins -r berusky.ini GameData Graphics Levels
        doicon -s 32 "${DISTDIR}"/${PN}.png
        make_desktop_entry ${PN}
        prepgamesdirs
}

pkg_preinst() {
        games_pkg_preinst
        gnome2_icon_savelist
}

pkg_postinst() {
        games_pkg_postinst
        gnome2_icon_cache_update
}

pkg_postrm() {
        gnome2_icon_cache_update
}