[gentoo-commits] repo/gentoo:master commit in: dev-python/dbus-fast/

[Michał Górny]

commit:     10ae520e6c8ab34c519a4af7efe71a834bfa328b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr  8 04:32:25 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr  8 04:45:04 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=10ae520e

dev-python/dbus-fast: Bump to 2.44.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dbus-fast/Manifest                |  1 +
 dev-python/dbus-fast/dbus-fast-2.44.1.ebuild | 63 ++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-python/dbus-fast/Manifest b/dev-python/dbus-fast/Manifest
index 1763e4914707..be979f3b60e9 100644
--- a/dev-python/dbus-fast/Manifest
+++ b/dev-python/dbus-fast/Manifest
@@ -1 +1,2 @@
 DIST dbus-fast-2.24.4.gh.tar.gz 178320 BLAKE2B 
790935c94b8c5984993bbbc7741cca1ab6c232e8a58266030318c774dcbdd77b3712fbb5ab3b3c6197f86eb8c0be0d8626e9dfcabf50a1a485be8d80334721fe
 SHA512 
e08a1b8c028cf33f7055621b502ffdffb1d9c79875b9f9d05afca401cdc583ae97bb029706002ad0e94e2ce8ccf3a992fe9cc9c023e87f64d04bb581b2e9f263
+DIST dbus-fast-2.44.1.gh.tar.gz 202745 BLAKE2B 
36fb2c1d1243ff376485b8fba783aab4917675d7277d28c71819fdcf0360cffa93c50fa4b71657897e17e0e5dec446e4965c4acc526bbb0528389fdf54a937ab
 SHA512 
8db8d0748b09ffbe3040f3fae8938236dd23a326a0f0995868319c74152db4968ffa6b43f8efd950f8dbc4e850c17ffb7d474bc3f429935680f76a3e96bfd522

diff --git a/dev-python/dbus-fast/dbus-fast-2.44.1.ebuild 
b/dev-python/dbus-fast/dbus-fast-2.44.1.ebuild
new file mode 100644
index 000000000000..3e57e7934e47
--- /dev/null
+++ b/dev-python/dbus-fast/dbus-fast-2.44.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A faster version of dbus-next"
+HOMEPAGE="
+       https://github.com/bluetooth-devices/dbus-fast/
+       https://pypi.org/project/dbus-fast/
+"
+SRC_URI="
+       https://github.com/Bluetooth-Devices/dbus-fast/archive/v${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+BDEPEND="
+       >=dev-python/cython-3[${PYTHON_USEDEP}]
+       >=dev-python/setuptools-65.4.1[${PYTHON_USEDEP}]
+       test? (
+               >=dev-python/pycairo-1.21.0[${PYTHON_USEDEP}]
+               >=dev-python/pygobject-3.50[${PYTHON_USEDEP}]
+               >=dev-python/pytest-asyncio-0.19[${PYTHON_USEDEP}]
+               >=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+src_test() {
+       local dbus_params=(
+               $(dbus-daemon --session --print-address --fork --print-pid)
+       )
+       local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+       virtx distutils-r1_src_test
+
+       kill "${dbus_params[1]}" || die
+}
+
+python_test() {
+       local EPYTEST_DESELECT=(
+               # interface not found on this object: 
org.freedesktop.DBus.Debug.Stats
+               tests/client/test_signals.py::test_signals
+       )
+       local EPYTEST_IGNORE=(
+               tests/benchmarks
+       )
+
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       nonfatal epytest -o addopts= -p asyncio || die
+}