[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-backend/

[Michał Górny]

commit:     03aa9c63d87a8de4030494ac41dc872ee72cc922
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr  7 05:07:53 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr  7 05:30:51 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03aa9c63

dev-python/pdm-backend: Bump to 2.4.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-backend/Manifest                 |  1 +
 dev-python/pdm-backend/pdm-backend-2.4.4.ebuild | 75 +++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index a4bdb8da6c95..3d9b6e37a32e 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.4.3.gh.tar.gz 146089 BLAKE2B 
36f65db90de5b507348a2a8407ae0eec8e1939c6b0fea1181548de910fad2497594e17aee7d478572a32e28260ef15660bddfaec4d921b2975b5a51da031dc1e
 SHA512 
378bc4360140f18dd7f66701da77f4b98ef4bad39c86055f11f4e508b16ebbbbce2188f47dedc05cd43525baf7873fc4565ee98d00d9e65efd9d8fc1820ddc15
+DIST pdm-backend-2.4.4.gh.tar.gz 157998 BLAKE2B 
936289f56709633eb4d78b851b903e0f436f01d9949f96463fbad4448cb1688d8bad61a8a00e63524abf74f696830bb8227b428f78a050a2e3396545611119d3
 SHA512 
b8d6983d2df1028d30c046c9952e6182aed0b099e6d0d0b4cc784179cb3e4c9f518b58a6fe5c7a2d15b150dc134b7dc8c427ea142620e8bb29dd05be1a7efe1a

diff --git a/dev-python/pdm-backend/pdm-backend-2.4.4.ebuild 
b/dev-python/pdm-backend/pdm-backend-2.4.4.ebuild
new file mode 100644
index 000000000000..915b5cbd0da4
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.4.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..13} pypy3 pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+       https://pypi.org/project/pdm-backend/
+       https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+       https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+       >=dev-python/editables-0.5[${PYTHON_USEDEP}]
+       >=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+       >=dev-python/pyproject-metadata-0.9.0_beta7[${PYTHON_USEDEP}]
+       >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+       $(python_gen_cond_dep '
+               >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+       ' 3.10)
+"
+BDEPEND="
+       ${RDEPEND}
+       test? (
+               dev-python/setuptools[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       rm -r src/pdm/backend/_vendor || die
+       find -name '*.py' -exec sed \
+               -e 's:from pdm\.backend\._vendor\.:from :' \
+               -e 's:from pdm\.backend\._vendor ::' \
+               -e 's:import pdm\.backend\._vendor\.:import :' \
+               -i {} + || die
+       distutils-r1_src_prepare
+}
+
+src_compile() {
+       # this must not be set during src_test()
+       local -x PDM_BUILD_SCM_VERSION=${PV}
+       distutils-r1_src_compile
+}
+
+src_test() {
+       git config --global user.email "t...@example.com" || die
+       git config --global user.name "Test User" || die
+       distutils-r1_src_test
+}
+
+python_test() {
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest -k "not [hg"
+}