commit: 62c4c4ff218bf57662ba087891cbbba9601ed4c6
Author: Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 12 15:03:24 2014 +0000
Commit: Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sat Apr 12 15:14:31 2014 +0000
URL:
http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=62c4c4ff
media-gfx/eog-plugins: 3.10.1 → 3.12.0
---
media-gfx/eog-plugins/eog-plugins-3.12.0.ebuild | 64 +++++++++++++++++++++++++
1 file changed, 64 insertions(+)
diff --git a/media-gfx/eog-plugins/eog-plugins-3.12.0.ebuild
b/media-gfx/eog-plugins/eog-plugins-3.12.0.ebuild
new file mode 100644
index 0000000..c1b2f7b
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-3.12.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_2,3_3} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://live.gnome.org/EyeOfGnome/Plugins";
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+exif +flickr map +picasa +python"
+REQUIRED_USE="
+ map? ( exif )
+ python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+ >=dev-libs/glib-2.32:2
+ >=dev-libs/libpeas-0.7.4:=
+ >=media-gfx/eog-3.11.4
+ >=x11-libs/gtk+-3.3.8:3
+ exif? ( >=media-libs/libexif-0.6.16 )
+ flickr? ( media-gfx/postr )
+ map? (
+ media-libs/libchamplain:0.12[gtk]
+ >=media-libs/clutter-1.9.4:1.0
+ >=media-libs/clutter-gtk-1.1.2:1.0 )
+ picasa? ( >=dev-libs/libgdata-0.9.1:= )
+ python? (
+ ${PYTHON_DEPS}
+ dev-libs/libpeas:=[gtk,python,${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ gnome-base/gsettings-desktop-schemas
+ media-gfx/eog[introspection]
+ x11-libs/gtk+:3[introspection]
+ x11-libs/pango[introspection] )
+"
+DEPEND="${RDEPEND}
+ >=dev-util/intltool-0.40
+ sys-devel/gettext
+ virtual/pkgconfig
+"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+ local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+ use exif && plugins="${plugins},exif-display"
+ use flickr && plugins="${plugins},postr"
+ use map && plugins="${plugins},map"
+ use picasa && plugins="${plugins},postasa"
+ use python &&
plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder"
+ gnome2_src_configure \
+ $(use_enable python) \
+ --with-plugins=${plugins}
+}
