commit: 3d5fcfe5a2170c7ac8dee9e4430287e84e78afe3
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 31 20:03:57 2025 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Mon Mar 31 20:14:08 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d5fcfe5
dev-python/hypothesis: add 6.130.6
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/hypothesis/Manifest | 1 +
dev-python/hypothesis/hypothesis-6.130.6.ebuild | 110 ++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 8b9c153107b3..220601ea7422 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,3 +1,4 @@
DIST hypothesis-6.128.2.gh.tar.gz 9522813 BLAKE2B
cc466d24bf45b5a0916f47d6a7ed124cd4e2532b9e79d8c879597fa6fb5fccfed7b410890318689b2cae6fce0357df19b97784725a38ef1408c06fe3696771b5
SHA512
c16a518d1bf59808ba7d95e863ad50fca68a7a58ab761f7b66f43c200ed5841f8ca2753dbb1af66bd7bc2b6210bef697412101812ae069c1ad21f6ac23b40ebd
DIST hypothesis-6.129.4.gh.tar.gz 9528147 BLAKE2B
c85806af24ddd934338f99c9d62a577fb35c8809d71ddf23aea0d613f33e690c70662279e88f4680d48c0c3b51fa10ff99c29fde7cf2d3c094cfaa0aa65b7612
SHA512
aec846f34e3a66da8a79929da681bd41ac7deb4a83934a51ee69bf989ddb8f3f7bd8f612571e625d3334cf786e3841b4e4d05fe4368e930e5975077e0f027a7d
DIST hypothesis-6.130.5.gh.tar.gz 9529886 BLAKE2B
4c9bcb811892e5c1251887e0ebebefd57104c1317e38f0ae358312b2f072c2c4e914c619a8a5505bbde57ac81f8351bbc28a1e957b0942ea10f72541937c74b2
SHA512
603c4723574683410e3d660938326c2ddc1f517311613bcf47a029f62d39e7c5a7cd053041ac6837dd53b4ecc9b4ed19c2374c43a6978837c59bfd8f0c2f9862
+DIST hypothesis-6.130.6.gh.tar.gz 9530097 BLAKE2B
d3f6dd0f43a509cbeb250696029ab32130b180089c2b5b8af924da04b8c64238e7ff076719f145880e590e7996d8480195d2503d64e33fd7ebe0b40d8600de88
SHA512
41254e0756af3e8116818c88996e15c1582945a592e9d7ba9d2fd023a0de62a89b697460b12b99b8560c85988737597d74ae9dc4d8336d4c643ab51cfdcde0eb
diff --git a/dev-python/hypothesis/hypothesis-6.130.6.ebuild
b/dev-python/hypothesis/hypothesis-6.130.6.ebuild
new file mode 100644
index 000000000000..5e0df5815a5e
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.130.6.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" pypy3_11 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+ https://github.com/HypothesisWorks/hypothesis/
+ https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+ https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ >=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ ' 3.9 3.10)
+ cli? (
+ $(python_gen_cond_dep '
+ dev-python/black[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ ' "${CLI_COMPAT[@]}")
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ >=dev-python/pytest-8[${PYTHON_USEDEP}]
+ dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ # subtests are broken by warnings from random plugins
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+ local -x HYPOTHESIS_NO_PLUGINS=1
+
+ # NB: paths need to be relative to pytest.ini,
+ # i.e. start with hypothesis-python/
+ local EPYTEST_DESELECT=()
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ # failing due to warnings from numpy/cython
+
hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+ )
+ ;;
+ python3.13)
+ EPYTEST_DESELECT+=(
+ # TODO
+
'hypothesis-python/tests/cover/test_reflection.py::test_clean_source[case-5]'
+ )
+ ;;
+ esac
+
+ epytest -o filterwarnings= -p rerunfailures --reruns=5 \
+ tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+ local HAD_CLI=
+
+ distutils-r1_src_install
+
+ if [[ ! ${HAD_CLI} ]]; then
+ rm -r "${ED}/usr/bin" || die
+ fi
+}
+
+python_install() {
+ distutils-r1_python_install
+ if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+ HAD_CLI=1
+ else
+ rm -r "${D}$(python_get_scriptdir)" || die
+ fi
+}
+
+pkg_postinst() {
+ optfeature "datetime support" dev-python/pytz
+ optfeature "dateutil support" dev-python/python-dateutil
+ optfeature "numpy support" dev-python/numpy
+ optfeature "django support" dev-python/django dev-python/pytz
+ optfeature "pandas support" dev-python/pandas
+ optfeature "pytest support" dev-python/pytest
+}
