commit: 5975bd5776696c66b09c872fe9464e0d858f19ce
Author: Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 24 09:34:00 2025 +0000
Commit: Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Mar 24 10:29:48 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5975bd57
app-emacs/treemacs: bump to 3.2
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>
app-emacs/treemacs/Manifest | 1 +
app-emacs/treemacs/treemacs-3.2.ebuild | 79 ++++++++++++++++++++++++++++++++++
2 files changed, 80 insertions(+)
diff --git a/app-emacs/treemacs/Manifest b/app-emacs/treemacs/Manifest
index d170b74c93e9..6c6c0eef5fa1 100644
--- a/app-emacs/treemacs/Manifest
+++ b/app-emacs/treemacs/Manifest
@@ -1 +1,2 @@
DIST treemacs-3.1_p20240229.tar.gz 4701534 BLAKE2B
3b3e5dbef181efee4739f96ee0ef0de68f344fa68b890b22c0ec808ec1c3b7afc6cd353124e2c6e5e70c931492ac0c9a3e4cee5c66b5c25ba4cc72b296ade6f0
SHA512
40631b77a71b13b0aed2f703386d98b8444c7630f952ba8d49160ba99abc13b8636169fee8cd23bbc372a7d7ae83b863e11ac891deb8cc5d2e961ccfee9f60da
+DIST treemacs-3.2.gh.tar.gz 4677915 BLAKE2B
2679d6797d6e4f9fdc5cd382df0ce53cf1743482b638f057fef7dc78c5226d37be0f728aac6b6e61a0b69b06bf52907185b00b115479582c49e894d2fc31d879
SHA512
830fa6af4b271439564c3dac289c51d416b3c9e6b2eef70d5bac385bdd1a5b805e1f7ae8de1fa33c9d750e2998f64c4234b565ce2b8f473afcaadc7e7d4f6f75
diff --git a/app-emacs/treemacs/treemacs-3.2.ebuild
b/app-emacs/treemacs/treemacs-3.2.ebuild
new file mode 100644
index 000000000000..69950adf8dc8
--- /dev/null
+++ b/app-emacs/treemacs/treemacs-3.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="no"
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 elisp
+
+DESCRIPTION="Tree style project file explorer"
+HOMEPAGE="https://github.com/Alexander-Miller/treemacs/";
+
+if [[ "${PV}" == *9999* ]] ; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/Alexander-Miller/${PN}";
+else
+ SRC_URI="https://github.com/Alexander-Miller/${PN}/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz"
+
+ KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+ >=app-editors/emacs-${NEED_EMACS}[svg]
+ app-emacs/ace-window
+ app-emacs/cfrs
+ app-emacs/dash
+ app-emacs/ht
+ app-emacs/hydra
+ app-emacs/pfuture
+ app-emacs/s
+"
+BDEPEND="
+ ${RDEPEND}
+"
+
+BYTECOMPFLAGS="-L . -L src/elisp"
+PATCHES=(
+ "${FILESDIR}/${PN}-async-scripts.patch"
+ "${FILESDIR}/${PN}-icons-icon-directory.patch"
+)
+
+DOCS=( Changelog.org Extensions.org README.org )
+SITEFILE="50${PN}-gentoo.el"
+
+elisp-enable-tests buttercup test
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ sed -e "s|@SITEETC@|${SITEETC}/${PN}|g" \
+ -i "src/elisp/${PN}-icons.el" \
+ -i "src/elisp/${PN}-async.el" \
+ || die
+}
+
+python_compile() {
+ python_optimize "${S}/src/scripts"
+}
+
+src_compile() {
+ distutils-r1_src_compile
+
+ elisp-compile ./src/elisp/*.el
+}
+
+src_install() {
+ elisp-install "${PN}" ./src/elisp/*.el{,c}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+
+ insinto "${SITEETC}/${PN}"
+ doins -r ./icons
+ doins -r ./src/scripts
+}
