commit: cc652c3a63ab321e720de340bf86e294943134f3
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 21 01:46:01 2025 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Mar 21 01:54:26 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc652c3a
dev-util/mesa_clc: Version bump to 25.0.2
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-util/mesa_clc/Manifest | 1 +
dev-util/mesa_clc/mesa_clc-25.0.2.ebuild | 95 ++++++++++++++++++++++++++++++++
2 files changed, 96 insertions(+)
diff --git a/dev-util/mesa_clc/Manifest b/dev-util/mesa_clc/Manifest
index 2a7f701a4b97..4a5d90eac050 100644
--- a/dev-util/mesa_clc/Manifest
+++ b/dev-util/mesa_clc/Manifest
@@ -1,2 +1,3 @@
DIST mesa-25.0.0.tar.xz 46643728 BLAKE2B
9aca2416ea4e304d46fda648cb9b8e04caa053458b91893fb874e9a30d8293722c3bed1098c2720b04b0c7278eba3b0387900b56e13b6133a23c0f6be705025c
SHA512
7f5b6674c40b6c8dcab7934512ff754b40a6a8a466422c90236f614d322033d4d465307ddcd983f9f3afb1310e132ec3186a085d261c95493a0c460b2ec59ce8
DIST mesa-25.0.1.tar.xz 46679784 BLAKE2B
9a73a3321c9f1d7d4384779f647c43bcb536b316dcc9a61b8a78a6f4bfd4642366e418155db5c2190b530cebee434554c6c4d2d59f68a87bb4056467fe601825
SHA512
1ecb1b90c5f78de4c61f177888543778285731faccc6f78d266d4b437f7b422a78b705a6e9fc6c9eab62c08f2573db5dd725eaa9cc9e5bedcaa7d8cfe6b47a1f
+DIST mesa-25.0.2.tar.xz 46705776 BLAKE2B
6e387806e880d518a68b3a8d4cb25071e9d50732aee06cc8b88f717c569c2764d658d40a8710ff362820a30133d5fde6b82ea7fb552fd0f690bcdf276a6f5e67
SHA512
2de8e8b514619d9ad5f407f5e1ff04fff8039d66b5f32257c2e8ca3d9f3b190269066aeba0779d6e0b2a2c0739237382fc6a98ea8563ed97801a809c96163386
diff --git a/dev-util/mesa_clc/mesa_clc-25.0.2.ebuild
b/dev-util/mesa_clc/mesa_clc-25.0.2.ebuild
new file mode 100644
index 000000000000..2d0b93cf95fb
--- /dev/null
+++ b/dev-util/mesa_clc/mesa_clc-25.0.2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {18..19} )
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit llvm-r1 meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="mesa_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/";
+
+if [[ ${PV} == 9999 ]]; then
+ S="${WORKDIR}/mesa_clc-${MY_PV}"
+ EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git";
+ inherit git-r3
+else
+ S="${WORKDIR}/mesa-${MY_PV}"
+ SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz";
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+ dev-util/spirv-tools
+ $(llvm_gen_dep '
+ dev-util/spirv-llvm-translator:${LLVM_SLOT}
+ llvm-core/clang:${LLVM_SLOT}=
+ =llvm-core/libclc-${LLVM_SLOT}*
+ llvm-core/llvm:${LLVM_SLOT}=
+ ')
+"
+DEPEND="${RDEPEND}
+ dev-libs/expat
+ >=sys-libs/zlib-1.2.8:=
+ x11-libs/libdrm
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep "
+ >=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]
+ dev-python/packaging[\${PYTHON_USEDEP}]
+ dev-python/pyyaml[\${PYTHON_USEDEP}]
+ ")
+ virtual/pkgconfig
+"
+
+python_check_deps() {
+ python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" &&
+ python_has_version -b "dev-python/packaging[${PYTHON_USEDEP}]" &&
+ python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" || return 1
+}
+
+pkg_setup() {
+ llvm-r1_pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+
+ use debug && EMESON_BUILDTYPE=debug
+
+ local emesonargs=(
+ -Dllvm=enabled
+ -Dshared-llvm=enabled
+ -Dmesa-clc=enabled
+ -Dinstall-mesa-clc=true
+
+ -Dgallium-drivers=''
+ -Dvulkan-drivers=''
+
+ # Set platforms empty to avoid the default "auto" setting. If
+ # platforms is empty meson.build will add surfaceless.
+ -Dplatforms=''
+
+ -Dglx=disabled
+ -Dlibunwind=disabled
+ -Dzstd=disabled
+
+ -Db_ndebug=$(usex debug false true)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ dobin "${BUILD_DIR}"/src/compiler/clc/mesa_clc
+ dobin "${BUILD_DIR}"/src/compiler/spirv/vtn_bindgen
+}
