commit: f7939c5d39c64d30a784f8d34aa41995f0dbd329
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 20 18:17:26 2025 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Mar 20 18:17:38 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f7939c5d
dev-python/pylint: add 3.3.6
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.3.6.ebuild | 92 +++++++++++++++++++++++++++++++++++
2 files changed, 93 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 5cbde6cbce7d..d4071cc8e3fb 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1,2 +1,3 @@
DIST pylint-3.3.4.gh.tar.gz 1455691 BLAKE2B
294cedc1d0ff5cf907ed847958d3067d526d7709df0ca9db2885fbd292b73d08d6b36708b1309a995790045d1eb5c55fe6d73f2bedaa6698d7fbd131dd010479
SHA512
cd99d69e3689986177320369a0b738054f92b194ff4a3f469d006de92181db1c88a068a9955dafc4df297256740f212f608b6c4bb050d25d0dbeb4c6d5466d44
DIST pylint-3.3.5.gh.tar.gz 1456364 BLAKE2B
79b25a97f388b280d8656338ce4108add79cc2ba28f81354439049526191e9660a8557c3c1a7edd4b04cc4aa0aca943ec37d9fe567a8a620359246fd9bd0f76d
SHA512
c4e65ae4301c5cce575f8f9d1e71515cd71d0329de9ed80501d1635783dcc79d99b488cc8e396c3f25b5e54cd0e84b5ed7c689142662c29ef3d64b2942146f83
+DIST pylint-3.3.6.gh.tar.gz 1456483 BLAKE2B
2ae9a4d90897085628e699cc7033e9aee9fe0d8158b30c84ad0fe0997af3341837b292329028cabfcb3da189f311729a97302e95556849eed59abc40b8193412
SHA512
f8059ce5c37bfa49e291a26018a6cbe3ec1256f582e77596f251bffdbcdd2b82b989939f3796c29df75e86872fc7aa0d592dede0fb3ce8360e192bf201265f20
diff --git a/dev-python/pylint/pylint-3.3.6.ebuild
b/dev-python/pylint/pylint-3.3.6.ebuild
new file mode 100644
index 000000000000..67dcd39c0451
--- /dev/null
+++ b/dev-python/pylint/pylint-3.3.6.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+ <dev-python/astroid-3.4[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.3.8[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-7[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/gitpython-3[${PYTHON_USEDEP}]
+ ' 'python*' )
+ >=dev-python/pytest-8.3[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ 'tests/test_functional.py::test_functional[use_yield_from]'
+ 'tests/test_functional.py::test_functional[wrong_import_order]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ if ! has_version "dev-python/gitpython[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/profile/test_profile_against_externals.py
+ tests/testutils/_primer/test_package_to_lint.py
+ tests/testutils/_primer/test_primer.py
+ )
+ fi
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
