[gentoo-commits] repo/gentoo:master commit in: games-arcade/lbreakout/

[Sam James]

commit:     03cc2bbd6adfd3ca95296bc0154b38763ede1685
Author:     NHOrus <jy6x2b32pie9 <AT> yahoo <DOT> com>
AuthorDate: Tue Mar 18 17:57:58 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Mar 19 23:59:07 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03cc2bbd

games-arcade/lbreakout: fix build with modern compilers

Autoreconf corrects bad bundled configure

Closes: https://bugs.gentoo.org/880949
Signed-off-by: NHOrus <jy6x2b32pie9 <AT> yahoo.com>
Closes: https://github.com/gentoo/gentoo/pull/41155
Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-arcade/lbreakout/lbreakout-010315-r2.ebuild | 50 +++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/games-arcade/lbreakout/lbreakout-010315-r2.ebuild 
b/games-arcade/lbreakout/lbreakout-010315-r2.ebuild
new file mode 100644
index 000000000000..87bea61d32c1
--- /dev/null
+++ b/games-arcade/lbreakout/lbreakout-010315-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs autotools
+
+DESCRIPTION="Breakout clone written with the SDL library"
+HOMEPAGE="https://lgames.sourceforge.io/LBreakout/";
+SRC_URI="
+       https://downloads.sourceforge.net/lgames/${P}.tar.gz
+       https://dev.gentoo.org/~ionen/distfiles/${PN}.png";
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+       acct-group/gamestat
+       media-libs/libsdl[sound,video]"
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( lbreakout/manual/. )
+
+src_prepare() {
+       default
+
+       # bug 880949
+       eautoreconf
+
+       # remove /games from datadir, and use /var/games for highscore file
+       sed -e '/^sdir=/s|/games.*||;' \
+               -e "/^hdir=/s|=.*|=${EPREFIX}/var/games|" \
+               -i configure || die
+
+       tc-export CC CXX
+}
+
+src_install() {
+       dodir /var/games #655000
+
+       default
+
+       fowners :gamestat /usr/bin/${PN} /var/games/${PN}.hscr
+       fperms g+s /usr/bin/${PN}
+       fperms 660 /var/games/${PN}.hscr
+
+       doicon "${DISTDIR}"/${PN}.png
+       make_desktop_entry ${PN} LBreakout
+}