[gentoo-commits] repo/gentoo:master commit in: dev-python/python-openstackclient/

[Michał Górny]

commit:     1e15740fe79bb7853b4db15c6763a60d482ab906
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 18 20:02:56 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Mar 18 20:13:10 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e15740f

dev-python/python-openstackclient: Enable py3.13

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../python-openstackclient-7.4.0-r1.ebuild         | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git 
a/dev-python/python-openstackclient/python-openstackclient-7.4.0-r1.ebuild 
b/dev-python/python-openstackclient/python-openstackclient-7.4.0-r1.ebuild
new file mode 100644
index 000000000000..f414f59a1301
--- /dev/null
+++ b/dev-python/python-openstackclient/python-openstackclient-7.4.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A client for the OpenStack APIs"
+HOMEPAGE="
+       https://opendev.org/openstack/python-openstackclient/
+       https://github.com/openstack/python-openstackclient/
+       https://pypi.org/project/python-openstackclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+       >dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+       >=dev-python/cliff-3.5.0[${PYTHON_USEDEP}]
+       >=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
+       >=dev-python/openstacksdk-3.3.0[${PYTHON_USEDEP}]
+       >=dev-python/osc-lib-2.3.0[${PYTHON_USEDEP}]
+       >=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+       >=dev-python/python-keystoneclient-3.22.0[${PYTHON_USEDEP}]
+       >=dev-python/python-cinderclient-3.3.0[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.27.0[${PYTHON_USEDEP}]
+       >=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       >dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+       test? (
+               >=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+               >=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+               >=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+               >=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+               >=dev-python/tempest-17.1.0[${PYTHON_USEDEP}]
+               >=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+               >=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+       # Depends on a specific runner
+       sed -e 's/test_command_has_logger/_&/' \
+               -i openstackclient/tests/unit/common/test_command.py || die
+
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       # functional tests require cloud instance access
+       eunittest -b openstackclient/tests/unit
+}