commit: 3b3efb017627efc3d7d0334999cd0915ac9b7dd1
Author: Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 17 21:27:10 2025 +0000
Commit: Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Mon Mar 17 21:31:02 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3b3efb01
x11-misc/gammastep: 2.0.10
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
x11-misc/gammastep/Manifest | 1 +
x11-misc/gammastep/gammastep-2.0.10.ebuild | 85 ++++++++++++++++++++++++++++++
2 files changed, 86 insertions(+)
diff --git a/x11-misc/gammastep/Manifest b/x11-misc/gammastep/Manifest
index 8271eaf5c96d..89509f0b25c5 100644
--- a/x11-misc/gammastep/Manifest
+++ b/x11-misc/gammastep/Manifest
@@ -1 +1,2 @@
+DIST gammastep-v2.0.10.tar.bz2 540401 BLAKE2B
635b27ad105b0ad2d94add6277fa92e39e0e102f7ad382104bb178cb9f6af1037bb021c4dd7d8b5016f8c053565641169c4ec4c2317b821b44f226ddf7f08dbd
SHA512
5654b19e3022cd3f27cb5119673d831c5378bd966eea6cb42dd994e9a5a8d3978b403e9a8ce411dfc17de5d35d00f033474f17177340ab47f69e0893aa2cf387
DIST gammastep-v2.0.9.tar.bz2 540120 BLAKE2B
cfc29b157ad2dbd3d6bb0ac4bdb26c958ba07cad3e817931c2ee4c2e4d15c157b7c0b8b891869ddcc2cdfc39c1d52afb8437991ae60501afee84500e1f28c694
SHA512
d8b23e5890d6135cef79057408e1b7c1dbc36444dfbfaf7c80a3f36c46df19eaded1829c2cd52365413779cc752d0911a44669b5abce16d7e266b92b15c035fb
diff --git a/x11-misc/gammastep/gammastep-2.0.10.ebuild
b/x11-misc/gammastep/gammastep-2.0.10.ebuild
new file mode 100644
index 000000000000..6a3ac6491ae6
--- /dev/null
+++ b/x11-misc/gammastep/gammastep-2.0.10.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..13} )
+
+inherit autotools systemd xdg-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="https://gitlab.com/chinstrap/gammastep";
+SRC_URI="https://gitlab.com/chinstrap/gammastep/-/archive/v${PV}/gammastep-v${PV}.tar.bz2";
+
+S="${WORKDIR}"/${PN}-v${PV}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="appindicator geoclue gtk nls wayland"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+ x11-libs/libXxf86vm
+ x11-libs/libxcb
+ x11-libs/libdrm
+ appindicator? ( dev-libs/libayatana-appindicator )
+ geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+ gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+ gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+ x11-libs/gtk+:3[introspection]
+ dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+ >=dev-util/intltool-0.50
+ nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ use gtk && python_setup
+
+ econf \
+ $(use_enable nls) \
+ --enable-drm \
+ $(use_enable wayland) \
+ --enable-randr \
+ --enable-vidmode \
+ $(use_enable geoclue geoclue2) \
+ $(use_enable gtk gui) \
+ --enable-apparmor \
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+}
+
+_impl_specific_src_install() {
+ emake DESTDIR="${D}" \
+ PYTHON="${PYTHON}" \
+ pythondir="$(python_get_sitedir)" \
+ -C src/gammastep_indicator install
+}
+
+src_install() {
+ emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+ if use gtk; then
+ python_foreach_impl _impl_specific_src_install
+ python_replicate_script "${D}"/usr/bin/gammastep-indicator
+
+ python_foreach_impl python_optimize
+ fi
+
+ insinto /etc/gammastep/
+ newins gammastep.conf.sample config.ini.example
+}
+
+pkg_postinst() {
+ use gtk && xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ use gtk && xdg_icon_cache_update
+}
