commit: b1af6b3c65977ed64cd0aac9a9f82d7562d9ac07
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 15 15:05:55 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Mar 15 15:10:28 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b1af6b3c
dev-lang/pypy: Remove old
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-lang/pypy/Manifest | 4 -
dev-lang/pypy/pypy-2.7.7.3.17.ebuild | 315 -------------------------------
dev-lang/pypy/pypy-3.10.7.3.17_p4.ebuild | 238 -----------------------
3 files changed, 557 deletions(-)
diff --git a/dev-lang/pypy/Manifest b/dev-lang/pypy/Manifest
index 3db4c06be582..2078b82ce7bb 100644
--- a/dev-lang/pypy/Manifest
+++ b/dev-lang/pypy/Manifest
@@ -1,10 +1,6 @@
-DIST pypy2.7-gentoo-patches-7.3.17.tar.xz 5324 BLAKE2B
866f172a6df6f0e94a98c611b37ae58635623e33a47619a5e44658d3908337a3f9029ff7de6997f760c3f1679fc83bfc6ddfb66852c492a581b3336b5eec3ed2
SHA512
6ce5266d0748f3c18a5546aa2bd8479ecb45923eb7df8a140a195e7f7b44999b9167ffdd44f7fd789ddd3a62cd77cb917863b0144180a1127befce1f290e650a
DIST pypy2.7-gentoo-patches-7.3.19.tar.xz 5328 BLAKE2B
c997c0e7f39a4a6a9ec34811b38fc8f9b90ccae8c958ca420074013d63a4f1b453b6331be79a2df299efe177cc99d91038ae56156d37b5f9b9f8715ccd2cb75d
SHA512
7bac5331fa868c60b376e405df212a29d406f117035fbc1ad8bd6d81212ab2ea4ce5b6b40e8dbbb6303fe941152e37aae17608a2eca9efd16767c8844f6f5fdb
-DIST pypy2.7-v7.3.17-src.tar.bz2 19907140 BLAKE2B
de62ebc4e8102867effdecddca64c19c40458b112a6a56ac0c95247047b9f5437a5da68dffb51c14c21bce463c2ca489c6e6a4f86e8cc597b57df2eca707081e
SHA512
82b2b9dbf0ea32c405ddc53d98a3a7a153f494d286e8719a0c40960168aadc0f49c3b313416488338f7f51c8fdb58120de41b1d47a8c8eda7db6d4ec4273b4eb
DIST pypy2.7-v7.3.19-src.tar.bz2 21011665 BLAKE2B
b8e205927c829753dd3e5aba0868923efff73f62e5338d6200aab2470857fff9cf38763ab8b63a74a39299d4956d4794eedf5d474d083875bbb9cee9ea757e64
SHA512
8ab8d9c0fa94ec96ebfae30b7f97eb8dff6ad4ee17fa688df123927c45f3ffea2c7f5dbb98bd2f8a49f7db6baf0ba3e98fd230df0bdc8602e407fb2bc33144e3
-DIST pypy3.10-gentoo-patches-7.3.17_p4.tar.xz 30520 BLAKE2B
b6ace80e0dc19a3fc24b1e5c97da1d67fc470c07032e86a875f0c994f6d2c64024a171d13b4e22f1531f15cb118a81993469a81dbc83eed03fce73a4b29f02d0
SHA512
586f8836ff3d122ad3fe3ec882057f37d2c509ea5cad98b674e917b1fd6022e0a27cc3639eaf9d3be43a91cb26fac73905067a2852bcda2f587e87e3e83b7be2
DIST pypy3.10-gentoo-patches-7.3.19_p1.tar.xz 6344 BLAKE2B
40ebbf87d0864e2a3957671680b7b9c0bea151fcdef808aef70711c24fdbd94846c15b010a3bd906915ab7a551d46f18264b2bda2c732d68b2594796d29226c8
SHA512
cd9d0ad4b48c21497f227f3b6540b01265df23de8cedaf212fe51dcae830a2812df6df169fdba3db36ccac29fb2d77aa2202f8e9b4bca543bd569db0d53c5736
-DIST pypy3.10-v7.3.17-src.tar.bz2 23350562 BLAKE2B
0a7a091976b352de61057f238fa386f767dd4d2fbcdcc0b4376066c20c2ad35d3818fa6e9e163ab5fd341856802e8ad1e2891decf5948c13cdb26726cd42019e
SHA512
46e30845bbc73cf56f5033a24d3583253ce198522f3a28ae4e789884063ba167d401fc08ae7fc8c7769feed9cd942a8ab38961c8b8794d7fae8f9955479faa96
DIST pypy3.10-v7.3.19-src.tar.bz2 24547353 BLAKE2B
975de34c7e01117c74e184693b6659ba0e3d8d488d724c03737dbd64533452c954e045e45058e1e77b9bee68e01060e74e30d7898d29f1adce417ce4b46579b8
SHA512
8fa24d3556bcf9cd0e2facd697827a5001fcfae9bf7874957843e4751b259f85a8b36166921282d71f39bb468d1706bb669373aebbc52486b683fcc824fb30ad
DIST pypy3.11-gentoo-patches-7.3.19_p4.tar.xz 7008 BLAKE2B
b441decac64d3565cf1d8d5b5e7f3b29f39a462c51f0bee3f480bc31847a1dd02d468241f78c01ec355fa33823bba508cc3eb5c5b97340cc208067d22eb535be
SHA512
f52e3dbde99cfe55d286554deb1826cdf4ce63073f6e4c29d43bd33d9c78a4fcedbd32029ddfd1a854d0bf77524e82dee6cc4367e81f5b23e355af3e302d115a
DIST pypy3.11-v7.3.19-src.tar.bz2 24916380 BLAKE2B
febc61b3a1c5055b5ab92e7f3af2c307605c8510131437b12df27b58a13b29f6fd0a4bf82d101f7f8f441ca93b20cf70dbd540af11578be297ea871d59304ea3
SHA512
ab078e81e5eefe16823350bdc9adcc444e0ef6835ff2234197f9e5cb0903c5208deb6df60722e99aa529ffff703c5dcbc08eaa7f753c2e5c1185afea6358395a
diff --git a/dev-lang/pypy/pypy-2.7.7.3.17.ebuild
b/dev-lang/pypy/pypy-2.7.7.3.17.ebuild
deleted file mode 100644
index c17bbb07a99e..000000000000
--- a/dev-lang/pypy/pypy-2.7.7.3.17.ebuild
+++ /dev/null
@@ -1,315 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit pax-utils toolchain-funcs
-
-PYVER=$(ver_cut 1-2)
-PATCHSET_PV=$(ver_cut 3-)
-PYPY_PV=${PATCHSET_PV%_p*}
-
-MY_P="pypy${PYVER}-v${PYPY_PV/_}"
-PATCHSET="pypy${PYVER}-gentoo-patches-${PATCHSET_PV/_rc/rc}"
-
-DESCRIPTION="A fast, compliant alternative implementation of the Python
(${PYVER}) language"
-HOMEPAGE="
- https://pypy.org/
- https://github.com/pypy/pypy/
-"
-SRC_URI="
- https://downloads.python.org/pypy/${MY_P}-src.tar.bz2
- https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
- https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
-"
-S="${WORKDIR}/${MY_P}-src"
-
-LICENSE="MIT"
-# pypy -c 'import sysconfig; print sysconfig.get_config_var("SOABI")'
-SLOT="${PYVER}/73"
-KEYWORDS="amd64 ~arm64 ~ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="bzip2 full-stdlib gdbm +jit ncurses sqlite tk"
-RESTRICT="test"
-
-RDEPEND="
- || (
- >=dev-python/pypy-exe-bin-${PYPY_PV}:${PYPY_PV}
- >=dev-python/pypy-exe-${PYPY_PV}:${PYPY_PV}[bzip2?,ncurses?]
- )
- dev-libs/openssl:0=
- gdbm? ( sys-libs/gdbm:0= )
- sqlite? ( dev-db/sqlite:3= )
- tk? (
- dev-lang/tk:0=
- dev-tcltk/tix:0=
- )
- !dev-python/pypy
-"
-DEPEND="
- ${RDEPEND}
-"
-
-src_prepare() {
- local PATCHES=(
- "${WORKDIR}/${PATCHSET}"
- )
-
- default
-}
-
-src_configure() {
- tc-export CC
-}
-
-src_compile() {
- # copy over to make sys.prefix happy
- cp -p "${BROOT}/usr/lib/pypy${PYVER}/pypy-c-${PYPY_PV}" pypy-c || die
- cp -p "${BROOT}/usr/lib/pypy${PYVER}/include/${PYPY_PV}"/* include/ ||
die
- # (not installed by pypy)
- rm pypy/module/cpyext/include/_numpypy/numpy/README || die
- mv pypy/module/cpyext/include/* include/ || die
- mv pypy/module/cpyext/parse/*.h include/ || die
- pax-mark m pypy-c
-
- # verify the subslot
- local soabi=$(
- ./pypy-c - <<-EOF
- import sysconfig
- print sysconfig.get_config_var("SOABI")
- EOF
- )
- [[ ${soabi#pypy-} == ${SLOT#*/} ]] || die "update subslot to ${soabi}"
-
- einfo "Generating caches and CFFI modules ..."
-
- if use full-stdlib; then
- # Generate Grammar and PatternGrammar pickles.
- ./pypy-c - <<-EOF || die "Generation of Grammar and
PatternGrammar pickles failed"
- import lib2to3.pygram
- import lib2to3.patcomp
- lib2to3.patcomp.PatternCompiler()
- EOF
-
- # Generate cffi modules
- # Please keep in sync with pypy/tool/build_cffi_imports.py!
- cffi_targets=( pypy_util ssl audioop syslog pwdgrp resource )
- use gdbm && cffi_targets+=( gdbm )
- use ncurses && cffi_targets+=( curses )
- use sqlite && cffi_targets+=( sqlite3 )
- use tk && cffi_targets+=( tkinter/tklib )
-
- local t
- # all modules except tkinter output to .
- # tkinter outputs to the correct dir ...
- cd lib_pypy || die
- for t in "${cffi_targets[@]}"; do
- # tkinter doesn't work via -m
- ../pypy-c "_${t}_build.py" || die "Failed to build CFFI
bindings for ${t}"
- done
-
- # Verify that CFFI module list is up-to-date
- local expected_cksum=-7df4eab0
- local local_cksum=$(
- ../pypy-c - <<-EOF
- import binascii
- import json
- from pypy_tools.build_cffi_imports import
cffi_build_scripts as x
- print("%08x" % (binascii.crc32(json.dumps(x)),))
- EOF
- )
- if [[ ${local_cksum} != ${expected_cksum} ]]; then
- die "Please verify cffi_targets and update checksum to
${local_cksum}"
- fi
-
- # Cleanup temporary objects
- find -name "_cffi_*.[co]" -delete || die
- find -type d -empty -delete || die
- fi
-}
-
-src_test() {
- # (unset)
- local -x PYTHONDONTWRITEBYTECODE=
- local -x COLUMNS=80
-
- local ignored_tests=(
- # network
- --ignore=lib-python/${PYVER}/test/test_urllibnet.py
- --ignore=lib-python/${PYVER}/test/test_urllib2net.py
- # lots of free space
- --ignore=lib-python/${PYVER}/test/test_zipfile64.py
-
- # broken by expat-2.4.5
- --ignore=lib-python/${PYVER}/test/test_minidom.py
- --ignore=lib-python/${PYVER}/test/test_xml_etree.py
- --ignore=lib-python/${PYVER}/test/test_xml_etree_c.py
- )
-
- ./pypy-c ./pypy/test_all.py --pypy=./pypy-c -vv \
- "${ignored_tests[@]}" lib-python || die
-}
-
-src_install() {
- local dest="/usr/lib/pypy${PYVER}"
- einfo "Installing PyPy ..."
- dosym "pypy-c-${PYPY_PV}" "${dest}/pypy-c"
- insinto "${dest}"
- # preserve mtimes to avoid obsoleting caches
- insopts -p
- if use full-stdlib; then
- doins -r include lib_pypy lib-python
-
- # replace copied headers with symlinks
- for x in "${BROOT}/usr/lib/pypy${PYVER}/include/${PYPY_PV}"/*;
do
- dosym "${PYPY_PV}/${x##*/}" "${dest}/include/${x##*/}"
- done
-
- if ! use gdbm; then
- rm -r "${ED}${dest}"/lib_pypy/gdbm.py \
-
"${ED}${dest}"/lib-python/*${PYVER}/test/test_gdbm.py || die
- fi
- if ! use sqlite; then
- rm -r "${ED}${dest}"/lib-python/*${PYVER}/sqlite3 \
- "${ED}${dest}"/lib_pypy/_sqlite3.py \
-
"${ED}${dest}"/lib-python/*${PYVER}/test/test_sqlite.py || die
- fi
- if ! use tk; then
- rm -r
"${ED}${dest}"/lib-python/*${PYVER}/{idlelib,lib-tk} \
- "${ED}${dest}"/lib_pypy/_tkinter \
-
"${ED}${dest}"/lib-python/*${PYVER}/test/test_{tcl,tk,ttk*}.py || die
- fi
- else
- # install only the absolutely minimal subset of modules needed
- # for pypy3 build
- local lib_py_modules=(
- # base modules needed to even start pypy (and import
site)
- codecs.py
- copy_reg.py
- encodings
- genericpath.py
- linecache.py
- os.py
- pkgutil.py
- posixpath.py
- re.py
- runpy.py
- site.py
- sre_compile.py
- sre_constants.py
- sre_parse.py
- stat.py
- string.py
- sysconfig.py
- traceback.py
- warnings.py
- UserDict.py
-
- # needed for python_optimize
- compileall.py
- getopt.py
- py_compile.py
- struct.py
-
- # needed for rpython
- argparse.py
- atexit.py
- base64.py
- bdb.py
- bisect.py
- cmd.py
- code.py
- codeop.py
- collections.py
- colorsys.py
- contextlib.py
- copy.py
- ctypes
- dis.py
- fnmatch.py
- functools.py
- gettext.py
- hashlib.py
- heapq.py
- inspect.py
- io.py
- json
- keyword.py
- locale.py
- logging
- new.py
- opcode.py
- optparse.py
- pdb.py
- pickle.py
- platform.py
- pprint.py
- random.py
- repr.py
- shlex.py
- shutil.py
- StringIO.py
- subprocess.py
- tempfile.py
- textwrap.py
- threading.py
- tokenize.py
- weakref.py
- zipfile.py
- )
-
- local distutils_modules=(
- # needed by site
- __init__.py
- errors.py
- sysconfig.py
- sysconfig_cpython.py
- sysconfig_pypy.py
- )
-
- local lib_pypy_modules=(
- # needed by site
- _sysconfigdata.py
-
- # needed by rpython
- cffi
- _ctypes
- _ffi.py
- _functools.py
- _sha.py
- _sha256.py
- _sha512.py
-
- # NB: we're deliberately skipping _hashlib to avoid
some deps
- )
-
- cd "lib-python/${PYVER}" || die
- insinto "${dest}/lib-python/${PYVER}"
- doins -r "${lib_py_modules[@]}"
- cd - >/dev/null || die
-
- cd "lib-python/${PYVER}/distutils" || die
- insinto "${dest}/lib-python/${PYVER}/distutils"
- doins -r "${distutils_modules[@]}"
- cd - >/dev/null || die
-
- cd lib_pypy || die
- insinto "${dest}/lib_pypy"
- doins -r "${lib_pypy_modules[@]}"
- cd - >/dev/null || die
- fi
-
- dosym "../lib/pypy${PYVER}/pypy-c" /usr/bin/pypy
- dodoc README.rst
-
- local -x PYTHON="${ED}${dest}/pypy-c-${PYPY_PV}"
- # temporarily copy to build tree to facilitate module builds
- cp -p "${BROOT}${dest}/pypy-c-${PYPY_PV}" "${PYTHON}" || die
-
- einfo "Byte-compiling Python standard library..."
- "${PYTHON}" -m compileall \
- -x 'bad_coding|badsyntax|make_ssl_data|lib2to3/tests/data' \
- -q -f -d "${dest}" "${ED}/${dest}" || die
-
- # remove to avoid collisions
- rm "${PYTHON}" || die
-}
diff --git a/dev-lang/pypy/pypy-3.10.7.3.17_p4.ebuild
b/dev-lang/pypy/pypy-3.10.7.3.17_p4.ebuild
deleted file mode 100644
index 798985845580..000000000000
--- a/dev-lang/pypy/pypy-3.10.7.3.17_p4.ebuild
+++ /dev/null
@@ -1,238 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit multiprocessing pax-utils python-utils-r1 toolchain-funcs
-
-PYVER=$(ver_cut 1-2)
-PATCHSET_PV=$(ver_cut 3-)
-PYPY_PV=${PATCHSET_PV%_p*}
-
-MY_P="pypy${PYVER}-v${PYPY_PV/_}"
-PATCHSET="pypy${PYVER}-gentoo-patches-${PATCHSET_PV/_rc/rc}"
-
-DESCRIPTION="A fast, compliant alternative implementation of the Python
(${PYVER}) language"
-HOMEPAGE="
- https://pypy.org/
- https://github.com/pypy/pypy/
-"
-SRC_URI="
- https://downloads.python.org/pypy/${MY_P}-src.tar.bz2
- https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
- https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
-"
-S="${WORKDIR}/${MY_P}-src"
-
-LICENSE="MIT"
-# pypy3 -c 'import sysconfig; print(sysconfig.get_config_var("SOABI"))'
-# also check pypy/interpreter/pycode.py -> pypy_incremental_magic
-SLOT="${PYVER}/pypy310-pp73-384"
-KEYWORDS="amd64 ~arm64 ~ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="+ensurepip gdbm +jit ncurses sqlite +symlink +test-install tk"
-# many tests are failing upstream
-# see https://buildbot.pypy.org/summary?branch=py${PYVER}
-RESTRICT="test"
-
-RDEPEND="
- || (
-
>=dev-python/pypy3_10-exe-${PYPY_PV}:${PYPY_PV}[bzip2(+),ncurses?]
- >=dev-python/pypy3_10-exe-bin-${PYPY_PV}:${PYPY_PV}
- )
- dev-lang/python-exec[python_targets_pypy3(-)]
- dev-libs/openssl:0=
- dev-python/gentoo-common
- ensurepip? ( dev-python/ensurepip-wheels )
- gdbm? ( sys-libs/gdbm:0= )
- sqlite? ( dev-db/sqlite:3= )
- tk? (
- dev-lang/tk:0=
- dev-tcltk/tix:0=
- )
- !dev-python/pypy3_10
- symlink? (
- !<dev-python/pypy3-7.3.17-r100
- )
-"
-DEPEND="
- ${RDEPEND}
-"
-
-src_prepare() {
- local PATCHES=(
- "${WORKDIR}/${PATCHSET}"
- )
-
- default
-}
-
-src_configure() {
- tc-export CC
-}
-
-src_compile() {
- mkdir bin || die
- # switch to the layout expected for cffi module builds
- mkdir "include/pypy${PYVER}" || die
- # copy over to make sys.prefix happy
- cp -p "${BROOT}/usr/bin/pypy${PYVER}-c-${PYPY_PV}" pypy${PYVER}-c || die
- cp -p "${BROOT}/usr/include/pypy${PYVER}/${PYPY_PV}"/*
include/pypy${PYVER}/ || die
- # (not installed by pypy-exe)
- rm pypy/module/cpyext/include/_numpypy/numpy/README || die
- mv pypy/module/cpyext/include/* "include/pypy${PYVER}/" || die
- mv pypy/module/cpyext/parse/*.h "include/pypy${PYVER}/" || die
- pax-mark m "pypy${PYVER}-c"
-
- # verify the subslot
- local soabi=$(
- "./pypy${PYVER}-c" - <<-EOF
- import importlib.util
- import sysconfig
- soabi = sysconfig.get_config_var("SOABI")
- magic = importlib.util._RAW_MAGIC_NUMBER & 0xffff
- print(f"{soabi}-{magic}")
- EOF
- )
- [[ ${soabi} == ${SLOT#*/} ]] || die "update subslot to ${soabi}"
-
- # Add epython.py to the distribution
- echo 'EPYTHON="pypy3"' > lib-python/3/epython.py || die
-
- einfo "Generating caches and CFFI modules ..."
-
- # Generate sysconfig data
- local host_gnu_type=$(sh pypy/tool/release/config.guess)
- local overrides=(
- HOST_GNU_TYPE "${host_gnu_type:-unknown}"
- INCLUDEPY "${EPREFIX}/usr/include/pypy${PYVER}"
- LIBDIR "${EPREFIX}/usr/$(get_libdir)"
- TZPATH "${EPREFIX}/usr/share/zoneinfo"
- WHEEL_PKG_DIR "${EPREFIX}/usr/lib/python/ensurepip"
- )
- "./pypy${PYVER}-c" -m sysconfig --generate-posix-vars "${overrides[@]}"
|| die
- local outdir
- outdir=$(<pybuilddir.txt) || die
- cp "${outdir}"/_sysconfigdata__*.py lib-python/3/ || die
-
- # Generate Grammar and PatternGrammar pickles.
- "./pypy${PYVER}-c" - <<-EOF || die "Generation of Grammar and
PatternGrammar pickles failed"
- import lib2to3.pygram
- import lib2to3.patcomp
- lib2to3.patcomp.PatternCompiler()
- EOF
-
- # Generate cffi modules
- # Please keep in sync with lib_pypy/pypy_tools/build_cffi_imports.py!
- # (NB: we build CFFI modules first to avoid error log when importing
- # build_cffi_imports).
- cffi_targets=(
- pypy_util blake2/_blake2 sha3/_sha3 ssl
- audioop syslog pwdgrp resource lzma posixshmem
- ctypes_test testmultiphase
- )
- use gdbm && cffi_targets+=( gdbm )
- use ncurses && cffi_targets+=( curses )
- use sqlite && cffi_targets+=( sqlite3 )
- use tk && cffi_targets+=( tkinter/tklib )
-
- local t
- # all modules except tkinter output to .
- # tkinter outputs to the correct dir ...
- cd lib_pypy || die
- for t in "${cffi_targets[@]}"; do
- # tkinter doesn't work via -m
- "../pypy${PYVER}-c" "_${t}_build.py" || die "Failed to build
CFFI bindings for ${t}"
- done
- # testcapi does not have a "build" script
- "../pypy${PYVER}-c" -c "import _testcapi" || die
-
- # Verify that CFFI module list is up-to-date
- local expected_cksum=a4138e48
- local local_cksum=$(
- "../pypy${PYVER}-c" - <<-EOF
- import binascii
- import json
- from pypy_tools.build_cffi_imports import
cffi_build_scripts as x
- print("%08x" %
(binascii.crc32(json.dumps(x).encode()),))
- EOF
- )
- if [[ ${local_cksum} != ${expected_cksum} ]]; then
- die "Please verify cffi_targets and update checksum to
${local_cksum}"
- fi
-
- # Cleanup temporary objects
- find \( -name "*_cffi.c" -o -name '*.o' \) -delete || die
- find -type d -empty -delete || die
-}
-
-src_install() {
- local dest="/usr/lib/pypy${PYVER}"
- einfo "Installing PyPy ..."
- dodir /usr/bin
- dosym "pypy${PYVER}-c-${PYPY_PV}" "/usr/bin/pypy${PYVER}"
- insinto "${dest}"
- # preserve mtimes to avoid obsoleting caches
- insopts -p
- doins -r lib-python/3/. lib_pypy/.
- insinto /usr/include
- doins -r "include/pypy${PYVER}"
-
- # replace copied headers with symlinks
- for x in "${BROOT}/usr/include/pypy${PYVER}/${PYPY_PV}"/*; do
- dosym "${PYPY_PV}/${x##*/}" "/usr/include/pypy${PYVER}/${x##*/}"
- done
-
- dodoc README.rst
-
- rm -r "${ED}${dest}"/ensurepip/_bundled || die
- if ! use ensurepip; then
- rm -r "${ED}${dest}"/ensurepip || die
- fi
- if ! use gdbm; then
- rm -r "${ED}${dest}"/_gdbm* || die
- fi
- if ! use test-install; then
- rm -r "${ED}${dest}"/{ctypes,sqlite3,tkinter,unittest}/test \
- "${ED}${dest}"/{distutils,lib2to3}/tests \
- "${ED}${dest}"/idlelib/idle_test || die
- fi
- if ! use sqlite; then
- rm -r "${ED}${dest}"/sqlite3 \
- "${ED}${dest}"/_sqlite3* \
- "${ED}${dest}"/test/test_sqlite.py || die
- fi
- if ! use tk; then
- rm -r "${ED}${dest}"/{idlelib,tkinter} \
- "${ED}${dest}"/_tkinter \
- "${ED}${dest}"/test/test_{tcl,tk,ttk*}.py || die
- fi
- # remove test last since we have some file removals above
- if ! use test-install; then
- rm -r "${ED}${dest}"/test || die
- fi
- dosym ../python/EXTERNALLY-MANAGED "${dest}/EXTERNALLY-MANAGED"
-
- local -x PYTHON="${ED}/usr/bin/pypy${PYVER}-c-${PYPY_PV}"
- # temporarily copy to build tree to facilitate module builds
- cp -p "${BROOT}/usr/bin/pypy${PYVER}-c-${PYPY_PV}" "${PYTHON}" || die
-
- einfo "Byte-compiling Python standard library..."
- # exclude list from CPython Makefile.pre.in
- "${PYTHON}" -m compileall -j "$(makeopts_jobs)" -o 0 -o 1 -o 2 \
- -x 'bad_coding|badsyntax|site-packages|lib2to3/tests/data' \
- --hardlink-dupes -q -f -d "${dest}" "${ED}${dest}" || die
-
- # remove to avoid collisions
- rm "${PYTHON}" || die
-
- if use symlink; then
- dosym pypy${PYVER} /usr/bin/pypy3
-
- # install symlinks for python-exec
- local EPYTHON=pypy3
- local scriptdir=${D}$(python_get_scriptdir)
- mkdir -p "${scriptdir}" || die
- ln -s "../../../bin/pypy3" "${scriptdir}/python3" || die
- ln -s python3 "${scriptdir}/python" || die
- fi
-}
