commit: 2ff38473247919a44e281ed9c791bd332b2cf04c
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 13 17:40:11 2025 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Thu Mar 13 17:45:36 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2ff38473
dev-libs/newt: add 0.52.25
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
dev-libs/newt/Manifest | 1 +
dev-libs/newt/newt-0.52.25.ebuild | 101 ++++++++++++++++++++++++++++++++++++++
2 files changed, 102 insertions(+)
diff --git a/dev-libs/newt/Manifest b/dev-libs/newt/Manifest
index 397932fcbcff..9bd5a3ee96ec 100644
--- a/dev-libs/newt/Manifest
+++ b/dev-libs/newt/Manifest
@@ -1 +1,2 @@
DIST newt-0.52.24.tar.gz 128895 BLAKE2B
fff7b3831f53a33b2d4f009fae0eb5603aef79c50f89e7f7179b80be837db35e44ecc860e4dc85e46195a59a87c12b2feae2ab043bef2fee0ea35a6efeded474
SHA512
999d8109dd3d74d04e813e84dc2e348278016dce7a678a1566197cf8fbc87810257b8a29fa766d29d48dc18bf4e1508b022460f15503fb6d029b3a05528b50be
+DIST newt-0.52.25.tar.gz 128961 BLAKE2B
b6590de2c8c7d51cf737308cfd78751c67d83a20e49a033463635daf7abbc19f5e53641de7bbf1c8b1f3e289f2d06ba145c5ac1cfe9a1b848a111a6a8500ec09
SHA512
5507cf32d35976a084d083cfb0563d0767a80ee280e222c029de6c64248e435aef170df2481999cece2dd1f727d9b353814d298219e0f6fb6c8fac20176fa97a
diff --git a/dev-libs/newt/newt-0.52.25.ebuild
b/dev-libs/newt/newt-0.52.25.ebuild
new file mode 100644
index 000000000000..afe3ada34bcd
--- /dev/null
+++ b/dev-libs/newt/newt-0.52.25.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..13} )
+
+inherit autotools python-r1 toolchain-funcs
+
+MY_PV="r$(ver_rs 1- -)"
+
+DESCRIPTION="Redhat's Newt windowing toolkit development files"
+HOMEPAGE="https://pagure.io/newt";
+SRC_URI="https://github.com/mlichvar/newt/archive/${MY_PV}.tar.gz ->
${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc
~x86"
+IUSE="gpm nls tcl"
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ >=dev-libs/popt-1.6
+ =sys-libs/slang-2*
+ gpm? ( sys-libs/gpm )
+ tcl? ( >=dev-lang/tcl-8.5:0 )
+ "
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-0.52.23-gold.patch
+ "${FILESDIR}"/${PN}-0.52.24-c99-fix.patch
+)
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_prepare() {
+ sed -i Makefile.in \
+ -e 's|-g -o|$(CFLAGS) $(LDFLAGS) -o|g' \
+ -e 's|-shared -o|$(CFLAGS) $(LDFLAGS) &|g' \
+ -e 's|instroot|DESTDIR|g' \
+ -e 's| make | $(MAKE) |g' \
+ -e "s| ar | $(tc-getAR) |g" \
+ || die "sed Makefile.in"
+
+ if [[ -n ${LINGUAS} ]]; then
+ local lang langs
+ for lang in ${LINGUAS}; do
+ test -r po/${lang}.po && langs="${langs} ${lang}.po"
+ done
+ sed -i po/Makefile \
+ -e "/^CATALOGS = /cCATALOGS = ${langs}" \
+ || die "sed po/Makefile"
+ fi
+
+ default
+ eautoreconf
+
+ # can't build out-of-source
+ python_copy_sources
+}
+
+src_configure() {
+ configuring() {
+ econf \
+ PYTHONVERS="${PYTHON}" \
+ $(use_with gpm gpm-support) \
+ $(use_with tcl) \
+ $(use_enable nls)
+ }
+ python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+ building() {
+ emake PYTHONVERS="${EPYTHON}"
+ }
+ python_foreach_impl run_in_build_dir building
+}
+
+src_install() {
+ installit() {
+ emake \
+ DESTDIR="${D}" \
+ PYTHON_SITEDIR="$(python_get_sitedir)" \
+ PYTHONVERS="${EPYTHON}" \
+ install
+ python_optimize
+ }
+ python_foreach_impl run_in_build_dir installit
+ dodoc peanuts.py popcorn.py tutorial.sgml
+ doman whiptail.1
+ einstalldocs
+
+ # don't want static archives
+ rm "${ED}"/usr/$(get_libdir)/libnewt.a || die
+}
