[gentoo-commits] repo/gentoo:master commit in: dev-python/nanobind/

[Michał Górny]

commit:     5d275ee06c4308f481a4463554d54c7044c5bf6e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 22 09:35:42 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Feb 22 09:37:06 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5d275ee0

dev-python/nanobind: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nanobind/Manifest              |  1 -
 dev-python/nanobind/nanobind-2.4.0.ebuild | 70 -------------------------------
 2 files changed, 71 deletions(-)

diff --git a/dev-python/nanobind/Manifest b/dev-python/nanobind/Manifest
index cb9cb99ac33a..924b72796b53 100644
--- a/dev-python/nanobind/Manifest
+++ b/dev-python/nanobind/Manifest
@@ -1,2 +1 @@
-DIST nanobind-2.4.0.gh.tar.gz 890566 BLAKE2B 
7ecdd1cb6734d01f24518189cf404b84b050ba20ee264aab2cd8dd99880b819b1be696decb69263c23b9c21b855caa5d7c4a545a6f282145f0434e6cbd31f616
 SHA512 
b018784f1ea07c6dd76b861a759e373ff78dbf78a278d19aed7bb2725b35fa9fe071ba34db264684ba697f2d8d4d6e64f16693590640ca2877783de981a952ab
 DIST nanobind-2.5.0.gh.tar.gz 900479 BLAKE2B 
9711cde535b6e6717477229f25e2f8abc5d1973ccd307ad1d55613ac0b288815960ece8b279a4dded47dc90e86ad4d44b216e27012120fcc7ffc26ef7711e800
 SHA512 
885668ee4ea9c551ccd60d2e056a90021badfeb7b358aeace184a23f9c2d34cb31a81ebe84db33fd6f15b7983dbb455d9c11f9367de091cb9b56c99d7634f9a0

diff --git a/dev-python/nanobind/nanobind-2.4.0.ebuild 
b/dev-python/nanobind/nanobind-2.4.0.ebuild
deleted file mode 100644
index 241a83e2cd29..000000000000
--- a/dev-python/nanobind/nanobind-2.4.0.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=scikit-build-core
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit cmake distutils-r1
-
-DESCRIPTION="Tiny and efficient C++/Python bindings"
-HOMEPAGE="
-       https://github.com/wjakob/nanobind/
-       https://pypi.org/project/nanobind/
-"
-SRC_URI="
-       https://github.com/wjakob/nanobind/archive/refs/tags/v${PV}.tar.gz
-               -> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~ppc64 ~riscv"
-
-DEPEND="
-       >=dev-cpp/robin-map-1.3.0
-"
-RDEPEND="
-       ${DEPEND}
-"
-BDEPEND="
-       $(python_gen_cond_dep '
-               dev-python/typing-extensions[${PYTHON_USEDEP}]
-       ' 3.10)
-"
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-       # https://github.com/scikit-build/scikit-build-core/issues/912
-       sed -i -e '/scikit-build-core/s:0\.10:0.8:' pyproject.toml || die
-       cmake_src_prepare
-       distutils-r1_src_prepare
-}
-
-src_configure() {
-       # XXX: nanobind installs a CMake config file which by default passes -Os
-       # We currently patch around it in dev-python/pyopencl. In future, we
-       # may want to add some override with Gentoo specific environment vars.
-       DISTUTILS_ARGS=(
-               -DNB_CREATE_INSTALL_RULES=ON
-               -DNB_USE_SUBMODULE_DEPS=OFF
-               -DNB_TEST=OFF
-       )
-}
-
-python_test() {
-       local mycmakeargs=(
-               -DNB_CREATE_INSTALL_RULES=OFF
-               -DNB_USE_SUBMODULE_DEPS=OFF
-               -DNB_TEST=ON
-       )
-       cmake_src_configure
-       cmake_src_compile
-
-       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-       cd "${BUILD_DIR}/tests" || die
-       epytest
-}