commit: 7ae540e55a496ffc817ff9b8de9951a14bcdc558
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 18 06:55:43 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Feb 18 07:35:50 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ae540e5
dev-python/m2crypto: Bump to 0.44.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/m2crypto/Manifest | 1 +
dev-python/m2crypto/m2crypto-0.44.0.ebuild | 70 ++++++++++++++++++++++++++++++
2 files changed, 71 insertions(+)
diff --git a/dev-python/m2crypto/Manifest b/dev-python/m2crypto/Manifest
index 8fff43b1473d..84462629ce9a 100644
--- a/dev-python/m2crypto/Manifest
+++ b/dev-python/m2crypto/Manifest
@@ -1 +1,2 @@
DIST m2crypto-0.43.0.tar.gz 366785 BLAKE2B
611daee57c5605246c0a505604e54ec7e029301194ed75bcb7c02ec04f0246a3dc05e13c8c00f1cc15496495a81c098b203cf69a75ce5a65ea3c7a1c0445e5d3
SHA512
c5232956a88de51bd3a1e02859b7a308eabb4e055cc0c8aac2d8d34a60c60a4a4c7160db4060ec07f559134a04eb41c6ab116a194ec3f7441d342e6d38f9add9
+DIST m2crypto-0.44.0.tar.gz 363805 BLAKE2B
0a61574ebee8a82ff2b00fa595870fe8d7e965be893db1e82bd1796703ecec16d7c476185b4b4db754efee1e698f60f20c783d1da04f77ee604afb9a346a2077
SHA512
8f8e9d88852eb003eaad9242ca43a0218354d9af3a6f0d9666ceba0ef2c840cd0aca0ad8493a222eb1de9dd0253c0204dde5530fd6a59ee1c3f29be83ec23458
diff --git a/dev-python/m2crypto/m2crypto-0.44.0.ebuild
b/dev-python/m2crypto/m2crypto-0.44.0.ebuild
new file mode 100644
index 000000000000..0df21271a435
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.44.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2018-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYPI_PN="M2Crypto"
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="
+ https://gitlab.com/m2crypto/m2crypto/
+ https://pypi.org/project/M2Crypto/
+"
+
+# openssl via src/SWIG/_lib11_compat.i
+LICENSE="MIT openssl"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="abi_mips_n32 abi_mips_n64 abi_mips_o32"
+
+DEPEND="
+ dev-libs/openssl:=
+"
+RDEPEND="
+ ${DEPEND}
+"
+BDEPEND="
+ >=dev-lang/swig-2.0.9
+"
+
+swig_define() {
+ local x
+ for x; do
+ if tc-cpp-is-true "defined(${x})"; then
+ SWIG_FEATURES+=" -D${x}"
+ fi
+ done
+}
+
+src_prepare() {
+ # relies on very exact clock behavior which apparently fails
+ # with inconvenient CONFIG_HZ*
+ sed -e 's:test_server_simple_timeouts:_&:' \
+ -i tests/test_ssl.py || die
+ distutils-r1_src_prepare
+}
+
+python_compile() {
+ # setup.py looks at platform.machine() to determine swig options.
+ # For exotic ABIs, we need to give swig a hint.
+ local -x SWIG_FEATURES=
+
+ # https://bugs.gentoo.org/617946
+ swig_define __ILP32__
+
+ # https://bugs.gentoo.org/674112
+ swig_define __ARM_PCS_VFP
+
+ distutils-r1_python_compile
+}
+
+python_test() {
+ "${EPYTHON}" -m unittest -b -v tests.alltests.suite ||
+ die "Tests failed for ${EPYTHON}"
+}
