commit: ff3672dd4d44c28be80969b2ecdec63026842dbb
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 17 16:39:03 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Feb 17 20:47:05 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff3672dd
dev-python/sphinx: Bump to 8.2.0_rc1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sphinx/Manifest | 1 +
dev-python/sphinx/sphinx-8.2.0_rc1.ebuild | 141 ++++++++++++++++++++++++++++++
2 files changed, 142 insertions(+)
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 2faba27f274e..00b31e5ad7f1 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
DIST sphinx-8.0.2.gh.tar.gz 8264835 BLAKE2B
ed6e321a1e58341609d88993c418ec1a0a580683ed28895077322fdba839d5c158007d65d5349d4d53c5e3b49ae823142cc6eb0203812580ebbb5b95247bf157
SHA512
5e9f38af91d7a80b6a80a80ab26adbebc1c3303996182a58eed9120ed896c5bfde022616e116e8cb8195fe03741e93fd97dcacccf492912ab147c5bfcb79213d
DIST sphinx-8.1.3.gh.tar.gz 8245194 BLAKE2B
43e0b2bc3214e01c55da356144c7e2e27dd8202b5c2dda6f6e1768c4ba4fa968180ff97f41c3b97e3cbeff1dad1199cd19385ae34dc0cb4250af60e157b3bd1f
SHA512
b1d0fe9586b11083103449a04443884d06d2dcab2d0bcf66d07ef97543b5e92da60e3c02e6f8ba9e04a6d7bdd62c75ef9d3f790411753fcda2a67e0fbf6a2d86
+DIST sphinx-8.2.0rc1.gh.tar.gz 8283034 BLAKE2B
7387106d4fc41595dfff84611f7ec2abd6f8cdc3692c8848689c2aa14d6b157b70c19dbeab8fd2a8c6d5b50993e31b37efdecc3dc39894d9b3ecb17b72733d90
SHA512
57bebe1ac19176779ed9d27ad2e981f580ea30872fdb909d47f7474608f7b02b7a531fee8208d1625ae252cb05301daa84a8b241b4d3b431f5a5229be0c35280
diff --git a/dev-python/sphinx/sphinx-8.2.0_rc1.ebuild
b/dev-python/sphinx/sphinx-8.2.0_rc1.ebuild
new file mode 100644
index 000000000000..3411635d690a
--- /dev/null
+++ b/dev-python/sphinx/sphinx-8.2.0_rc1.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+ https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinx/
+ https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+ https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc latex"
+
+RDEPEND="
+ >=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+ >=dev-python/babel-2.13[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.22[${PYTHON_USEDEP}]
+ >=dev-python/docutils-0.20[${PYTHON_USEDEP}]
+ >=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+ >=dev-python/jinja2-3.1[${PYTHON_USEDEP}]
+ >=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+ >=dev-python/roman-numerals-py-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/snowballstemmer-2.2[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-applehelp-1.0.7[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-devhelp-1.0.6[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-htmlhelp-2.0.6[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-jsmath-1.0.1[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-qthelp-1.0.6[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+ latex? (
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )
+"
+BDEPEND="
+ doc? (
+ dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+ media-gfx/graphviz
+ )
+ test? (
+ app-text/dvipng
+ >=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+ >=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+ dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+ dev-texlive/texlive-fontsextra
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ virtual/imagemagick-tools[jpeg,png,svg]
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+ #"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # disable internet access
+ sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+ doc/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ # we can't use distutils_enable_sphinx because it would
+ # introduce a dep on itself
+ use doc && build_sphinx doc
+}
+
+python_test() {
+ mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+ local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+ local EPYTEST_DESELECT=(
+ # less interesting failures
+ tests/test_builders/test_build_latex.py::test_build_latex_doc
+ tests/test_extensions/test_ext_math.py::test_imgmath_png
+ tests/test_extensions/test_ext_math.py::test_imgmath_numfig_html
+ )
+ case ${EPYTHON} in
+ python3.13x)
+ EPYTEST_DESELECT+=(
+
tests/test_extensions/test_ext_autodoc.py::test_autodoc_special_members
+
tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_type_aliases
+
tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_format_fully_qualified
+
tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_none
+
tests/test_extensions/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
+ )
+ ;;
+ pypy3)
+ EPYTEST_DESELECT+=(
+
tests/test_extensions/test_ext_autodoc.py::test_autodoc_exception
+
tests/test_extensions/test_ext_autodoc.py::test_autodoc_ignore_module_all
+
tests/test_extensions/test_ext_autodoc.py::test_autodoc_inherited_members_None
+
tests/test_extensions/test_ext_autodoc.py::test_autodoc_subclass_of_builtin_class
+
tests/test_extensions/test_ext_autodoc.py::test_automethod_for_builtin
+
tests/test_extensions/test_ext_autodoc.py::test_cython
+
tests/test_extensions/test_ext_autodoc.py::test_format_signature
+
tests/test_extensions/test_ext_autodoc.py::test_partialfunction
+
tests/test_extensions/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+
tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+
tests/test_extensions/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+
tests/test_extensions/test_ext_autodoc_autofunction.py::test_builtin_function
+
tests/test_extensions/test_ext_autodoc_autofunction.py::test_methoddescriptor
+
tests/test_extensions/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+
tests/test_extensions/test_ext_autodoc_preserve_defaults.py::test_preserve_defaults_special_constructs
+
tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+
tests/test_extensions/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+
tests/test_util/test_util_inspect.py::test_isattributedescriptor
+
tests/test_util/test_util_inspect.py::test_signature
+
tests/test_util/test_util_typing.py::test_is_invalid_builtin_class
+ )
+ ;;
+ esac
+
+ # note: pytest-xdist causes random test failures
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p rerunfailures --reruns=5
+}
