commit: 06f5fbd43565957ecbcf73f4fcec6d695f2c34d8
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 7 09:40:41 2025 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Feb 7 09:40:41 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=06f5fbd4
dev-vcs/breezy: add 3.3.9
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-vcs/breezy/Manifest | 2 ++
dev-vcs/breezy/breezy-3.3.9.ebuild | 73 ++++++++++++++++++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/dev-vcs/breezy/Manifest b/dev-vcs/breezy/Manifest
index 18bd04ec854a..3b9e3367bf42 100644
--- a/dev-vcs/breezy/Manifest
+++ b/dev-vcs/breezy/Manifest
@@ -2,3 +2,5 @@ DIST breezy-3.3.5-crates.tar.xz 3894068 BLAKE2B
4ea9de19a602d5e5040d3bd4a0196156
DIST breezy-3.3.5.tar.gz 10393262 BLAKE2B
32563b74fb639888265b1a6af7650f73a2e11750be7d7cb62861aafae1c08998bffc666727fcd4ee31dcc741232b4aeb518ef2023bcf1d8138563724b63672f8
SHA512
daff16f4df9b2f89fd6bef335af0b30d2567c8f1e4fa9b02ba2a528f0c56daedc58c83af92297148001fb9eb177115875d02a2969b9847387058edcae0db104b
DIST breezy-3.3.7-crates.tar.xz 4038220 BLAKE2B
47cc506d291ae70422283b405fc4cff006b3587e222f9ff99e4bc9768aca4cab72837d3d40d524a27c54ab8fd8353bb3031e97e936bbedcf5c82772072721ad7
SHA512
21473b953bfdfb90102b749d0089a8926e6ff1cf4cc366709232d6f272856784f4fc7f0d79fe330b85198c288cb587ce08f479d67fa7c5efbf7bcac2da8b663c
DIST breezy-3.3.7.tar.gz 9477114 BLAKE2B
98f2fc865d1b341c9458111c70b9b0f1be0b8cc8ddaf601ac29dd05911f69539f2fbdcbd2a9eab7fbd9b69ebe38f46bb4753af92ed3a5f2bfdd6382e970dce89
SHA512
4f4a775f1e866f39cce9c9766d4304d730ac386f8bab4ed1ee5d6c4052f2e5089ca75445656d9674f7cd26b42ac0a3b6434c7843862692f12159883691cf303b
+DIST breezy-3.3.9-crates.tar.xz 2180380 BLAKE2B
e634b9821f77f54278e9b94fd8725533abe23d5fee79f4c342eadfa2aa077367e9b6ee5a4e7a1577fdf3ff6e2b03af59604dc1a6a37183610cfc13684d6389e3
SHA512
3bb4b33bb79c7d5bc22141e04ef21efa6eff9e7a75e46c8abd7201cc3f8650cfec1c65567b5bd26e4c63c720b26d5a444932c00b929de7f0d5be754f48d1d8d6
+DIST breezy-3.3.9.tar.gz 10398251 BLAKE2B
9358cb7043a0512e67602f008135e7cc4da4fd6c32796fad75be79c3102e84091365ed52064dbdfb75e7165b07328859a4dc0757fa4ec8370f966d95693c0022
SHA512
e5db988c73d6f7626ecb8f688874c39d9b345dfb52897431c2207e744dd060407057548107dec04b71c00f1421370e7c544b6411fded0308cf2dab9a8cf748d3
diff --git a/dev-vcs/breezy/breezy-3.3.9.ebuild
b/dev-vcs/breezy/breezy-3.3.9.ebuild
new file mode 100644
index 000000000000..12e29a6cd0cf
--- /dev/null
+++ b/dev-vcs/breezy/breezy-3.3.9.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES=""
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cargo distutils-r1 optfeature
+
+DESCRIPTION="Distributed Version Control System with a Friendly UI"
+HOMEPAGE="https://www.breezy-vcs.org/ https://github.com/breezy-team/breezy";
+SRC_URI="https://launchpad.net/brz/$(ver_cut 1-2)/${PV}/+download/${P}.tar.gz"
+SRC_URI+="
https://dev.gentoo.org/~arthurzam/distfiles/dev-vcs/${PN}/${P}-crates.tar.xz";
+
+LICENSE="GPL-2+"
+# Dependent crate licenses
+LICENSE+=" Apache-2.0-with-LLVM-exceptions MIT Unicode-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+# I've got tired of all the test failures. It definitely mostly works.
+# We have ~29000 tests successfully passing from ~30000 tests.
+RESTRICT="test"
+
+RDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/configobj[${PYTHON_USEDEP}]
+ dev-python/fastbencode[${PYTHON_USEDEP}]
+ dev-python/patiencediff[${PYTHON_USEDEP}]
+ dev-python/merge3[${PYTHON_USEDEP}]
+ dev-python/dulwich[${PYTHON_USEDEP}]
+ dev-python/urllib3[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/tzlocal[${PYTHON_USEDEP}]
+ ')
+ !dev-vcs/bzr
+"
+BDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/setuptools-gettext[${PYTHON_USEDEP}]
+ dev-python/setuptools-rust[${PYTHON_USEDEP}]
+ ')
+"
+
+QA_FLAGS_IGNORED="
+ usr/lib.*/py.*/site-packages/breezy/.*.so
+ usr/bin/brz
+"
+
+src_prepare() {
+ sed -e 's@man/man1@share/&@' \
+ -e 's@, strip=Strip\.All@@' \
+ -i setup.py || die
+
+ distutils-r1_src_prepare
+}
+
+src_install() {
+ distutils-r1_src_install
+
+ # Symlink original bzr's bin names to new names
+ dosym brz /usr/bin/bzr
+}
+
+pkg_postinst() {
+ optfeature "access branches over sftp" "dev-python/pycryptodome
dev-python/paramiko"
+ optfeature "PGP sign and verify commits" "app-crypt/gpgme[python]"
+}
