commit: 73386c8fff28f38a9221c690dee87f2aeee62193
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 5 21:08:59 2025 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Feb 5 21:54:06 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73386c8f
dev-util/mesa_clc: Version bump to 25.0.0_rc2
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-util/mesa_clc/Manifest | 1 +
dev-util/mesa_clc/mesa_clc-25.0.0_rc2.ebuild | 95 ++++++++++++++++++++++++++++
2 files changed, 96 insertions(+)
diff --git a/dev-util/mesa_clc/Manifest b/dev-util/mesa_clc/Manifest
new file mode 100644
index 000000000000..bc313329523b
--- /dev/null
+++ b/dev-util/mesa_clc/Manifest
@@ -0,0 +1 @@
+DIST mesa-25.0.0-rc2.tar.xz 46570616 BLAKE2B
bd85d30d1d3e674dae38c476ef1df774df1699963d1c105b336da77f5c271d8ab823d24af9763e5a85643e4794fa4dd041de16b27359799fad3aac7c99b94077
SHA512
67eec93fbe24cb3fa26b062539453326b3237bd8c6ac111061142dae69b81fe7da000728d9bc2c0e2ec46f122011cbde9b99141f6333828016efb3eaa87b27f7
diff --git a/dev-util/mesa_clc/mesa_clc-25.0.0_rc2.ebuild
b/dev-util/mesa_clc/mesa_clc-25.0.0_rc2.ebuild
new file mode 100644
index 000000000000..2d0b93cf95fb
--- /dev/null
+++ b/dev-util/mesa_clc/mesa_clc-25.0.0_rc2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {18..19} )
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit llvm-r1 meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="mesa_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/";
+
+if [[ ${PV} == 9999 ]]; then
+ S="${WORKDIR}/mesa_clc-${MY_PV}"
+ EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git";
+ inherit git-r3
+else
+ S="${WORKDIR}/mesa-${MY_PV}"
+ SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz";
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+ dev-util/spirv-tools
+ $(llvm_gen_dep '
+ dev-util/spirv-llvm-translator:${LLVM_SLOT}
+ llvm-core/clang:${LLVM_SLOT}=
+ =llvm-core/libclc-${LLVM_SLOT}*
+ llvm-core/llvm:${LLVM_SLOT}=
+ ')
+"
+DEPEND="${RDEPEND}
+ dev-libs/expat
+ >=sys-libs/zlib-1.2.8:=
+ x11-libs/libdrm
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep "
+ >=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]
+ dev-python/packaging[\${PYTHON_USEDEP}]
+ dev-python/pyyaml[\${PYTHON_USEDEP}]
+ ")
+ virtual/pkgconfig
+"
+
+python_check_deps() {
+ python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" &&
+ python_has_version -b "dev-python/packaging[${PYTHON_USEDEP}]" &&
+ python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" || return 1
+}
+
+pkg_setup() {
+ llvm-r1_pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+
+ use debug && EMESON_BUILDTYPE=debug
+
+ local emesonargs=(
+ -Dllvm=enabled
+ -Dshared-llvm=enabled
+ -Dmesa-clc=enabled
+ -Dinstall-mesa-clc=true
+
+ -Dgallium-drivers=''
+ -Dvulkan-drivers=''
+
+ # Set platforms empty to avoid the default "auto" setting. If
+ # platforms is empty meson.build will add surfaceless.
+ -Dplatforms=''
+
+ -Dglx=disabled
+ -Dlibunwind=disabled
+ -Dzstd=disabled
+
+ -Db_ndebug=$(usex debug false true)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ dobin "${BUILD_DIR}"/src/compiler/clc/mesa_clc
+ dobin "${BUILD_DIR}"/src/compiler/spirv/vtn_bindgen
+}
