commit: 2f12fc488086c5286ba0364d564ebdd300ce8190
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 17 11:28:02 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jan 17 11:28:33 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f12fc48
dev-python/django: Bump to 5.2_alpha1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-5.2_alpha1.ebuild | 99 ++++++++++++++++++++++++++++++
2 files changed, 101 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 2694656a02b2..f62242446e1c 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,5 +4,7 @@ DIST Django-5.0.11.checksum.txt 2583 BLAKE2B
e7cc6ed8c4f3d9398eb892cfb6e4d6b9834
DIST Django-5.0.11.tar.gz 10635979 BLAKE2B
b55d539d541c661ebe0e4e3db21b89de3fb4a32dc1d07d6bae1be6cd22b82bf4c5692eb23ddb2d4425140ecdcab272d6fb5629c1b525b7fdad1469eb40376a8e
SHA512
a43b3245a8e4f1b315ac75128f0d24cf4202471a9dce6791e1fffc88580427c7823c4abfeab6bfee821ff44407728089f563180525eb6bc172bf52858dce867e
DIST Django-5.1.5.checksum.txt 2573 BLAKE2B
af41ffe32d60f10c99b558d32dbcf8658fe6ccadf21168afa6812ec9f40d6a0d2024cde733a26d515d90a025e8814c10ab745679133ed1f13a0ffbed8ce59319
SHA512
70c4af1a339a0b195b3788c10425ef83480274ba3efe5344bfa43d8245d681ed2622f48d62c284ad4bbeb77fb5132308197dfe1d308d027ea650c452e6454d90
DIST Django-5.1.5.tar.gz 10700031 BLAKE2B
8de45f7574e2f74a06916018a12cf6df9c263cf754ff575d12735fb6921729c7d2937235fee57abb95e9f20e6de0282ec3e737a0a2ee9d9e38e70a1ee90fa6e9
SHA512
cc28eb7166d9babdb3f3d61cc87eb9ed038d7115bd7de7da5b9cff33da114c334fd51140d32c597229cd07e400520bc92ebf69611c6a455ac926f3e9eaa5ee88
+DIST Django-5.2a1.checksum.txt 2410 BLAKE2B
34659b6ff74e39fd13e8b1392dcb0411ae88cb88dc0271f3e7f84ad829e2525f1db11c3951b1b1def4ea95a432135996656fd2e894f3afc3c1913913d1033cb6
SHA512
b1e70a6978707b1d90d8810dc349796e969d63299ec8496b5ec1d45d0881ddfa524e2b78fdd07d1e212d74497de011b7d5377dc31e19e74fb532f2cc26f94212
+DIST Django-5.2a1.tar.gz 10814424 BLAKE2B
fffa0f9f31fdd03b1dbf826ec1484d22fbfdeb13724254034726699d303a66d397e847954d15ab2b2975600bcbe4113051a6d9b7c14f2aeeca862ffd06c21d13
SHA512
5513cf718a30bd1bca5973c4fa679ec9af7b7a69cdfd554a5d5ab6706fdab18d5d9de8e1162968fc0d6c3254823577e43d1704482321178edbce434a8b4b8dd9
DIST django-4.2.17-pypy3.patch.xz 5900 BLAKE2B
2a564fc31d8e2f3def5a532d3bca1a4426a496c659192f602d659e0c1a5f5882978baedb384cc3b67fda8c836513ce43aece80db1528c8e8b6e9ca420f7572ce
SHA512
9c9d935aff6db7230a26931b5e7f5f94f3b5ff4fc8f7d4201178571de9d9c7929a0e1e558cc2d9b54b8ee91f85819a5680d24fad6251620515a4a020e3b2d66d
DIST django-5.0-pypy3.patch.xz 6124 BLAKE2B
7eba7cc70b30743cf4e186a2c5b0f27c13f49114a7a80bcaa2b25fdd7a959583c115a302c9bc6da97c32f6401cf8f3616818ba759190d317c5b033a0f0088766
SHA512
c550e2b2c1243d13cd1f4908f4b6df606355d1491e3bf72042e4b4777a4474306ff0f67b1c2eb4ab4d137cc85bde52dcdbd54bec245d2ba2e092545be8a2993b
diff --git a/dev-python/django/django-5.2_alpha1.ebuild
b/dev-python/django/django-5.2_alpha1.ebuild
new file mode 100644
index 000000000000..a54c7d29492c
--- /dev/null
+++ b/dev-python/django/django-5.2_alpha1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
+
+MY_P=${PN^}-${PV/_alpha/a}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ <dev-python/asgiref-4[${PYTHON_USEDEP}]
+ >=dev-python/asgiref-3.8.1[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+ sys-libs/timezone-data
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ >=dev-python/docutils-0.19[${PYTHON_USEDEP}]
+ >=dev-python/jinja2-2.11.0[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ >=dev-python/selenium-4.8.0[${PYTHON_USEDEP}]
+ >=dev-python/tblib-1.5.0[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20240807 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/django-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+ -v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:0
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc
dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+}
